[gentoo-commits] gentoo-x86 commit in media-libs/phonon-vlc: phonon-vlc-9999.ebuild phonon-vlc-0.7.2.ebuild ChangeLog

[Michael Palimaka (kensington)]

kensington    14/06/21 16:37:07

  Modified:             phonon-vlc-9999.ebuild ChangeLog
  Added:                phonon-vlc-0.7.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.15                 media-libs/phonon-vlc/phonon-vlc-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild?r1=1.14&r2=1.15

Index: phonon-vlc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- phonon-vlc-9999.ebuild	18 Nov 2013 20:04:14 -0000	1.14
+++ phonon-vlc-9999.ebuild	21 Jun 2014 16:37:07 -0000	1.15
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild,v 1.14 2013/11/18 20:04:14 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild,v 1.15 2014/06/21 16:37:07 kensington Exp $
 
 EAPI=5
 
@@ -30,19 +30,18 @@
 	>=media-video/vlc-2.0.1:=[dbus,ogg,vorbis]
 	qt4? (
 		dev-qt/qtcore:4
-		dev-qt/qtdbus:4
 		dev-qt/qtgui:4
 	)
 	qt5? (
 		dev-qt/qtcore:5
-		dev-qt/qtdbus:5
 		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
 	)
 "
 DEPEND="${RDEPEND}
 	app-arch/xz-utils
-	qt4? ( >=dev-util/automoc-0.9.87 )
 	virtual/pkgconfig
+	qt4? ( >=dev-util/automoc-0.9.87 )
 "
 
 [[ ${PV} == 9999 ]] || S=${WORKDIR}/${MY_P}



1.44                 media-libs/phonon-vlc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	6 Dec 2013 12:59:26 -0000	1.43
+++ ChangeLog	21 Jun 2014 16:37:07 -0000	1.44
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/phonon-vlc
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/ChangeLog,v 1.43 2013/12/06 12:59:26 johu Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/ChangeLog,v 1.44 2014/06/21 16:37:07 kensington Exp $
+
+*phonon-vlc-0.7.2 (21 Jun 2014)
+
+  21 Jun 2014; Michael Palimaka <kensington@g.o>
+  +phonon-vlc-0.7.2.ebuild, phonon-vlc-9999.ebuild:
+  Version bump.
 
 *phonon-vlc-0.7.1 (06 Dec 2013)
 



1.1                  media-libs/phonon-vlc/phonon-vlc-0.7.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-0.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-0.7.2.ebuild?rev=1.1&content-type=text/plain

Index: phonon-vlc-0.7.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-0.7.2.ebuild,v 1.1 2014/06/21 16:37:07 kensington Exp $

EAPI=5

MY_PN="phonon-backend-vlc"
MY_P="${MY_PN}-${PV}"
EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
[[ ${PV} == 9999 ]] && git_eclass=git-r3
inherit cmake-utils multibuild ${git_eclass}
unset git_eclass

DESCRIPTION="Phonon VLC backend"
HOMEPAGE="https://projects.kde.org/projects/kdesupport/phonon/phonon-vlc"
[[ ${PV} == 9999 ]] || SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/src/${MY_P}.tar.xz"

LICENSE="LGPL-2.1"

# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
[[ ${PV} == 9999 ]] || \
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"

SLOT="0"
IUSE="debug +qt4 qt5"
REQUIRED_USE="|| ( qt4 qt5 )"

RDEPEND="
	>=media-libs/phonon-4.7.0[qt4=,qt5=]
	>=media-video/vlc-2.0.1:=[dbus,ogg,vorbis]
	qt4? (
		dev-qt/qtcore:4
		dev-qt/qtgui:4
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtwidgets:5
	)
"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig
	qt4? ( >=dev-util/automoc-0.9.87 )
"

[[ ${PV} == 9999 ]] || S=${WORKDIR}/${MY_P}

DOCS=( AUTHORS )

pkg_setup() {
	MULTIBUILD_VARIANTS=()
	if use qt4; then
		MULTIBUILD_VARIANTS+=(qt4)
	fi
	if use qt5; then
		MULTIBUILD_VARIANTS+=(qt5)
	fi
}

src_configure() {
	myconfigure() {
		local mycmakeargs=()
		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=OFF)
		fi
		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=ON)
		fi
		cmake-utils_src_configure
	}

	multibuild_foreach_variant myconfigure
}

src_compile() {
	multibuild_foreach_variant cmake-utils_src_compile
}

src_install() {
	multibuild_foreach_variant cmake-utils_src_install
}

src_test() {
	multibuild_foreach_variant cmake-utils_src_test
}

pkg_postinst() {
	elog "For more verbose debug information, export the following variables:"
	elog "PHONON_DEBUG=1"
	elog ""
	elog "To make KDE detect the new backend without reboot, run:"
	elog "kbuildsycoca4 --noincremental"
}