[gentoo-commits] repo/gentoo:master commit in: dev-libs/libutf8proc/

[Benda XU]

commit:     a0674c6c067a4039eee2783cf6e0a1a61ce143b6
Author:     Benda Xu <heroxbd <AT> gentoo <DOT> org>
AuthorDate: Sun Sep  4 01:42:57 2022 +0000
Commit:     Benda XU <heroxbd <AT> gentoo <DOT> org>
CommitDate: Sun Sep  4 01:44:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a0674c6c

dev-libs/libutf8proc: fix regression on Prefix.

The cleanup of commit 5640fe7f introduced a regression on pkg-config.
The make "prefix" variable should start with ${EPREFIX}, so that
libutf8proc.pc have prefix=EPREFIX/usr.

Otherwise libutf8proc.pc will contain prefix=/usr and inject a
-I/usr/include into the cflags, because non-EPREFIX /usr/include is
not a system include directory on Gentoo Prefix.  This will result in
drawing in host headers and error out.

Reference: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5640fe7f3dd581cb33d57eda6b4eb932b201d15e
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Benda Xu <heroxbd <AT> gentoo.org>

 dev-libs/libutf8proc/libutf8proc-2.7.0-r1.ebuild | 58 ++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/dev-libs/libutf8proc/libutf8proc-2.7.0-r1.ebuild b/dev-libs/libutf8proc/libutf8proc-2.7.0-r1.ebuild
new file mode 100644
index 000000000000..2e009ba02e2d
--- /dev/null
+++ b/dev-libs/libutf8proc/libutf8proc-2.7.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+USE_RUBY="ruby25 ruby26 ruby27"
+
+inherit ruby-single toolchain-funcs
+
+DESCRIPTION="A clean C Library for processing UTF-8 Unicode data"
+HOMEPAGE="https://github.com/JuliaStrings/utf8proc"
+SRC_URI="https://github.com/JuliaStrings/${PN#lib}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	cjk? ( https://dev.gentoo.org/~hattya/distfiles/${PN}-EastAsianWidth-14.0.0.xz )"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="cjk static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? (
+		=app-i18n/unicode-data-14.0*
+		${RUBY_DEPS}
+	)"
+S="${WORKDIR}/${P#lib}"
+
+QA_PKGCONFIG_VERSION="$(ver_cut 1).5.0"
+
+src_prepare() {
+	if use cjk; then
+		einfo "Modifying East Asian Ambiguous (A) as wide ..."
+		cp "${WORKDIR}"/${PN}-EastAsianWidth-14.0.0 ${PN#lib}_data.c || die
+	fi
+
+	default
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		prefix="${EPREFIX}/usr" \
+		libdir='$(prefix)'"/$(get_libdir)"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		prefix="${EPREFIX}/usr" \
+		libdir='$(prefix)'"/$(get_libdir)" \
+		install
+	use static-libs || find "${ED}" -name '*.a' -delete || die
+}
+
+src_test() {
+	cp "${EPREFIX}"/usr/share/unicode-data/{DerivedCoreProperties,{Normalization,auxiliary/GraphemeBreak}Test}.txt data || die
+
+	emake CC="$(tc-getCC)" check
+}