[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-session/

[Andreas Sturmlechner]

commit:     cf455868ccf3cb773955c1b1924a424c39fab582
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 27 18:55:03 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed May 20 23:28:31 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cf455868

lxqt-base/lxqt-session: add version 0.15.0

With this, the 'x11-themes/lxqt-themes' dependency and the related
USE-flag have been removed.  There seems to be no hard requirement
for it in this particular package, and users of 'lxqt-meta' will get
the themes that way already.

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 lxqt-base/lxqt-session/Manifest                   |  1 +
 lxqt-base/lxqt-session/lxqt-session-0.15.0.ebuild | 61 +++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/lxqt-base/lxqt-session/Manifest b/lxqt-base/lxqt-session/Manifest
index 2b023599070..fd0c147f62a 100644
--- a/lxqt-base/lxqt-session/Manifest
+++ b/lxqt-base/lxqt-session/Manifest
@@ -1 +1,2 @@
 DIST lxqt-session-0.14.1.tar.xz 178600 BLAKE2B a4f0f096b994ea409e47d364bbde93bb66bfb4b5fb157ec1acb78a3055584dd31772ca2ed6a6592940e6fb578bbca3d0499f6eaa9775f84ce9703c39b0fc0bf3 SHA512 9274564f3eabe33744bbe8555b1177d8ff6f241f5849bef29f0bb344f506e590e1deab87bf2fdeb867872ebaa0262cda0400f16179951fd66fbcb4d9f7358c4c
+DIST lxqt-session-0.15.0.tar.xz 181900 BLAKE2B 87a96f832497d235de2b86deb9b66f21bae270906c5fd17d5ea3059f6be1527502423cf55bff7b2fecfd9a881c867791dd603ce9aa1bb29b1ae1b337e05ab529 SHA512 96ef9e58ca25303ac0213f1cb5faee5efddb61ac3705484ac55b39db56c9302ff646e317dbc753b213a5e2ea38818b247244a2be5219fbe6db9e419b8c638591

diff --git a/lxqt-base/lxqt-session/lxqt-session-0.15.0.ebuild b/lxqt-base/lxqt-session/lxqt-session-0.15.0.ebuild
new file mode 100644
index 00000000000..0be394a3ce6
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-0.15.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="LXQt Session Manager"
+HOMEPAGE="https://lxqt.github.io/"
+
+MY_PV="$(ver_cut 1-2)*"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+IUSE="+udev"
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.7.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	kde-frameworks/kwindowsystem:5[X]
+	=lxqt-base/liblxqt-${MY_PV}
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	udev? ( virtual/libudev )
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	newenvd - 91lxqt-config-dir <<- _EOF_
+		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
+	_EOF_
+}