[gentoo-commits] gentoo-x86 commit in media-sound/drumstick: drumstick-1.0.0.ebuild ChangeLog

[Michael Palimaka (kensington)]

kensington    14/12/03 07:54:40

  Modified:             ChangeLog
  Added:                drumstick-1.0.0.ebuild
  Log:
  Version bump wrt bug #530400.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.16                 media-sound/drumstick/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/drumstick/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/drumstick/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/drumstick/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/drumstick/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	17 Oct 2014 17:18:59 -0000	1.15
+++ ChangeLog	3 Dec 2014 07:54:40 -0000	1.16
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/drumstick
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/drumstick/ChangeLog,v 1.15 2014/10/17 17:18:59 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/drumstick/ChangeLog,v 1.16 2014/12/03 07:54:40 kensington Exp $
+
+*drumstick-1.0.0 (03 Dec 2014)
+
+  03 Dec 2014; Michael Palimaka <kensington@g.o> +drumstick-1.0.0.ebuild:
+  Version bump wrt bug #530400.
 
   17 Oct 2014; Michael Palimaka <kensington@g.o> metadata.xml:
   Add to KDE herd.



1.1                  media-sound/drumstick/drumstick-1.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/drumstick/drumstick-1.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/drumstick/drumstick-1.0.0.ebuild?rev=1.1&content-type=text/plain

Index: drumstick-1.0.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/drumstick/drumstick-1.0.0.ebuild,v 1.1 2014/12/03 07:54:40 kensington Exp $

EAPI=5

inherit cmake-utils fdo-mime gnome2-utils

DESCRIPTION="Qt4/C++ wrapper for ALSA sequencer"
HOMEPAGE="http://drumstick.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND="
	dev-qt/qtcore:5
	dev-qt/qtdbus:5
	dev-qt/qtgui:5
	dev-qt/qtnetwork:5
	dev-qt/qtsvg:5
	dev-qt/qtwidgets:5
	media-libs/alsa-lib
	x11-misc/shared-mime-info
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? (
		app-doc/doxygen
		app-text/docbook-xsl-stylesheets
		dev-libs/libxslt
	)
"

DOCS=( AUTHORS ChangeLog NEWS README TODO )

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_find_package doc Doxygen)
	)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile

	use doc && cmake-utils_src_compile doxygen
}

src_install() {
	cmake-utils_src_install

	if use doc ; then
		dodoc -r "${BUILD_DIR}"/doc/html
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}