[gentoo-commits] repo/gentoo:master commit in: net-irc/quassel/

[Manuel Rüger]

commit:     4b3cdf84ed7ab64b5bb16a93909f126c2aa94243
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 20 01:02:00 2018 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Tue Nov 20 01:02:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4b3cdf84

net-irc/quassel: Version bump to 0.13.0

Signed-off-by: Manuel Rüger <mrueg <AT> gentoo.org>
Package-Manager: Portage-2.3.52, Repoman-2.3.11

 net-irc/quassel/Manifest              |   1 +
 net-irc/quassel/quassel-0.13.0.ebuild | 189 ++++++++++++++++++++++++++++++++++
 2 files changed, 190 insertions(+)

diff --git a/net-irc/quassel/Manifest b/net-irc/quassel/Manifest
index 8b6989c5b63..d679d5767ab 100644
--- a/net-irc/quassel/Manifest
+++ b/net-irc/quassel/Manifest
@@ -1,2 +1,3 @@
 DIST quassel-0.12.5.tar.bz2 3747392 BLAKE2B 624cd18c2a5e1c480f701072bfeeeb18589cdbd2f2b7ab0d524f32e384ac4feb7328b23b60c3005340d53e4bf3a209f75a5d673a8d5d3f659825f0ef21bd3f9f SHA512 3a0263d7bec9ef4b0d8ef6ea53784f95e0efbadc0f03b49005908411b0b53543ebc66189fb4100c117d87264b648f2a1b01be48c371f926b9f326b1ffc870685
 DIST quassel-0.13-rc2.tar.bz2 4260661 BLAKE2B 083fb6b832dc7297405fb5cb4e36b1d831ff000ef302627f798944bf242c87d4c9a78a797f0997fe1a8db9def23633af27de0c7c571c4051d039431043cb4363 SHA512 3444cf03250a1b0fd26563575e1b3fbabff382b6307e122a933b7f892250222d7277f5aaf0ceb7f53fb0924076d09a328f15e81b0fd7ff7483b54b8d0dac302c
+DIST quassel-0.13.0.tar.bz2 4259301 BLAKE2B 24a138f8727af940934b420a12aae01b1eaf8080f3c7ae40805e858f9cc2b7c9471d831f816a099fccde41134af9e7d19ab4e6bc41e64eff75e91318abe4efc4 SHA512 a0710ccdd01c5a9731ba72f7f8430e435c95f8709a187ddee68dde48eb6dd575a6281a4461a0d2509f7373d7861d9b6c0d29089929a4b8043b0e9334032087bf

diff --git a/net-irc/quassel/quassel-0.13.0.ebuild b/net-irc/quassel/quassel-0.13.0.ebuild
new file mode 100644
index 00000000000..f6ff727068b
--- /dev/null
+++ b/net-irc/quassel/quassel-0.13.0.ebuild
@@ -0,0 +1,189 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils pax-utils systemd user
+
+if [[ ${PV} != *9999* ]]; then
+	MY_P=${PN}-${PV/_/-}
+	SRC_URI="http://quassel-irc.org/pub/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~sparc-solaris"
+	S="${WORKDIR}/${MY_P}"
+else
+	EGIT_REPO_URI=( "https://github.com/${PN}/${PN}" "git://git.${PN}-irc.org/${PN}" )
+	inherit git-r3
+fi
+
+DESCRIPTION="Qt/KDE IRC client supporting a remote daemon for 24/7 connectivity"
+HOMEPAGE="http://quassel-irc.org/"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="bundled-icons crypt +dbus debug kde ldap monolithic oxygen postgres +server
+snorenotify +ssl syslog urlpreview X"
+
+SERVER_RDEPEND="
+	dev-qt/qtscript:5
+	crypt? ( app-crypt/qca:2[qt5(+),ssl] )
+	ldap? ( net-nds/openldap )
+	postgres? ( dev-qt/qtsql:5[postgres] )
+	!postgres? ( dev-qt/qtsql:5[sqlite] dev-db/sqlite:3[threadsafe(+),-secure-delete] )
+	syslog? ( virtual/logger )
+"
+
+GUI_RDEPEND="
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtwidgets:5
+	!bundled-icons? (
+		kde-frameworks/breeze-icons:5
+		oxygen? ( kde-frameworks/oxygen-icons:5 )
+	)
+	dbus? (
+		>=dev-libs/libdbusmenu-qt-0.9.3_pre20140619[qt5(+)]
+		dev-qt/qtdbus:5
+	)
+	kde? (
+		kde-frameworks/kconfigwidgets:5
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/knotifyconfig:5
+		kde-frameworks/ktextwidgets:5
+		kde-frameworks/kwidgetsaddons:5
+		kde-frameworks/kxmlgui:5
+		kde-frameworks/sonnet:5
+	)
+	snorenotify? ( >=x11-libs/snorenotify-0.7.0 )
+	urlpreview? ( dev-qt/qtwebengine:5[widgets] )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl?]
+	sys-libs/zlib
+	monolithic? (
+		${SERVER_RDEPEND}
+		${GUI_RDEPEND}
+	)
+	!monolithic? (
+		server? ( ${SERVER_RDEPEND} )
+		X? ( ${GUI_RDEPEND} )
+	)
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules
+"
+
+DOCS=( AUTHORS ChangeLog README.md )
+
+REQUIRED_USE="
+	|| ( X server monolithic )
+	crypt? ( || ( server monolithic ) )
+	kde? ( || ( X monolithic ) dbus )
+	ldap? ( || ( server monolithic ) )
+	postgres? ( || ( server monolithic ) )
+	snorenotify? ( || ( X monolithic ) )
+	syslog? ( || ( server monolithic ) )
+"
+
+pkg_setup() {
+	if use server; then
+		QUASSEL_DIR=/var/lib/${PN}
+		QUASSEL_USER=${PN}
+		# create quassel:quassel user
+		enewgroup "${QUASSEL_USER}"
+		enewuser "${QUASSEL_USER}" -1 -1 "${QUASSEL_DIR}" "${QUASSEL_USER}"
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_QT4=OFF
+		-DUSE_QT5=ON
+		-DUSE_CCACHE=OFF
+		-DCMAKE_SKIP_RPATH=ON
+		-DEMBED_DATA=OFF
+		-DWITH_WEBKIT=OFF
+		-DWITH_BUNDLED_ICONS=$(usex bundled-icons)
+		$(cmake-utils_use_find_package dbus dbusmenu-qt5)
+		$(cmake-utils_use_find_package dbus Qt5DBus)
+		-DWITH_KDE=$(usex kde)
+		-DWITH_LDAP=$(usex ldap)
+		-DWANT_MONO=$(usex monolithic)
+		-DWITH_OXYGEN_ICONS=$(usex oxygen)
+		-DWANT_CORE=$(usex server)
+		$(cmake-utils_use_find_package snorenotify LibsnoreQt5)
+		-DWITH_WEBENGINE=$(usex urlpreview)
+		-DWANT_QTCLIENT=$(usex X)
+	)
+
+	if use server || use monolithic; then
+		mycmakeargs+=(  $(cmake-utils_use_find_package crypt QCA2-QT5) )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use server ; then
+		# needs PAX marking wrt bug#346255
+		pax-mark m "${ED}/usr/bin/quasselcore"
+
+		# prepare folders in /var/
+		keepdir "${QUASSEL_DIR}"
+		fowners "${QUASSEL_USER}":"${QUASSEL_USER}" "${QUASSEL_DIR}"
+
+		# init scripts & systemd unit
+		newinitd "${FILESDIR}"/quasselcore.init-r1 quasselcore
+		newconfd "${FILESDIR}"/quasselcore.conf-r1 quasselcore
+		systemd_dounit "${FILESDIR}"/quasselcore.service
+
+		# logrotate
+		insinto /etc/logrotate.d
+		newins "${FILESDIR}/quassel.logrotate" quassel
+	fi
+}
+
+pkg_postinst() {
+	if use monolithic && use ssl ; then
+		elog "Information on how to enable SSL support for client/core connections"
+		elog "is available at http://bugs.quassel-irc.org/projects/quassel-irc/wiki/Client-Core_SSL_support."
+	fi
+
+	if use server; then
+		einfo "If you want to generate SSL certificate remember to run:"
+		einfo "	emerge --config =${CATEGORY}/${PF}"
+	fi
+
+	if use server || use monolithic ; then
+		einfo "Quassel can use net-misc/oidentd package if installed on your system."
+		einfo "Consider installing it if you want to run quassel within identd daemon."
+	fi
+
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
+
+pkg_config() {
+	if use server && use ssl; then
+		# generate the pem file only when it does not already exist
+		if [ ! -f "${QUASSEL_DIR}/quasselCert.pem" ]; then
+			einfo "Generating QUASSEL SSL certificate to: \"${QUASSEL_DIR}/quasselCert.pem\""
+			openssl req -x509 -nodes -days 365 -newkey rsa:2048 \
+				-keyout "${QUASSEL_DIR}/quasselCert.pem" \
+				-out "${QUASSEL_DIR}/quasselCert.pem"
+			# permissions for the key
+			chown ${QUASSEL_USER}:${QUASSEL_USER} "${QUASSEL_DIR}/quasselCert.pem"
+			chmod 400 "${QUASSEL_DIR}/quasselCert.pem"
+		else
+			einfo "Certificate \"${QUASSEL_DIR}/quasselCert.pem\" already exists."
+			einfo "Remove it if you want to create new one."
+		fi
+	fi
+}