[gentoo-commits] repo/gentoo:master commit in: media-libs/libkate/

[Pacho Ramos]

commit:     36175d21171b68af965eae9353e737f51bfca7d6
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Mon Jun  5 10:20:59 2017 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Mon Jun  5 10:21:41 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=36175d21

media-libs/libkate: Use wxpython-3.0 (#601184), drop static libs (#514380)

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 media-libs/libkate/libkate-0.4.1-r2.ebuild | 53 ++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/media-libs/libkate/libkate-0.4.1-r2.ebuild b/media-libs/libkate/libkate-0.4.1-r2.ebuild
new file mode 100644
index 00000000000..a7a2d150f1c
--- /dev/null
+++ b/media-libs/libkate/libkate-0.4.1-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit ltprune python-single-r1
+
+DESCRIPTION="Codec for karaoke and text encapsulation for Ogg"
+HOMEPAGE="https://code.google.com/p/libkate/"
+SRC_URI="https://libkate.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+
+IUSE="debug doc wxwidgets"
+REQUIRED_USE="wxwidgets? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	media-libs/libogg:=
+	media-libs/libpng:0=
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	sys-devel/bison
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="${COMMON_DEPEND}
+	wxwidgets? (
+		${PYTHON_DEPS}
+		dev-python/wxpython:3.0[${PYTHON_USEDEP}]
+		media-libs/liboggz )
+"
+
+pkg_setup() {
+	use wxwidgets && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if ! use wxwidgets; then
+		sed -i -e "s/HAVE_PYTHON=yes/HAVE_PYTHON=no/" configure || die
+	fi
+
+	econf --disable-static $(use_enable debug) $(use_enable doc)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+	use wxwidgets && python_fix_shebang "${D}"
+}