[gentoo-commits] gentoo-x86 commit in x11-wm/compiz: ChangeLog metadata.xml compiz-0.7.8.ebuild

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    08/10/31 16:48:40

  Modified:             ChangeLog metadata.xml
  Added:                compiz-0.7.8.ebuild
  Log:
  Fixed the metadata.xml.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64)

Revision  Changes    Path
1.28                 x11-wm/compiz/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	29 Aug 2008 02:06:46 -0000	1.27
+++ ChangeLog	31 Oct 2008 16:48:40 -0000	1.28
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/compiz
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.27 2008/08/29 02:06:46 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.28 2008/10/31 16:48:40 jmbsvicetto Exp $
+
+*compiz-0.7.8 (27 Oct 2008)
+
+  27 Oct 2008; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  metadata.xml, +compiz-0.7.8.ebuild:
+  Added compiz-0.7.8 to the tree
 
   29 Aug 2008; Diego Pettenò <flameeyes@g.o> compiz-0.6.2-r1.ebuild:
   Add some missing build-time dependencies (closes bug #204863), disable



1.2                  x11-wm/compiz/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	16 Sep 2006 14:21:20 -0000	1.1
+++ metadata.xml	31 Oct 2008 16:48:40 -0000	1.2
@@ -1,6 +1,13 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>no-herd</herd>
-<maintainer><email>hanno@g.o</email></maintainer>
+<use>
+	<flag name="fuse">Enables support for the filesystem in userspace plugin through <pkg>sys-fs/fuse</pkg>.</flag>
+	<flag name="kde4">Compile the kde4 window decorator and add support for <pkg>kde-base/kdebase-startkde:4.1</pkg>.</flag>
+	<flag name="annotate">Build the annotate plugin</flag>
+</use>
+<herd>desktop-effects</herd>
+<longdescription>
+compiz is a compositing window manager that uses 3D graphics acceleration via OpenGL.
+</longdescription>
 </pkgmetadata>



1.1                  x11-wm/compiz/compiz-0.7.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.7.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.7.8.ebuild?rev=1.1&content-type=text/plain

Index: compiz-0.7.8.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.7.8.ebuild,v 1.1 2008/10/31 16:48:40 jmbsvicetto Exp $

EAPI="2"

inherit autotools eutils gnome2-utils multilib

DESCRIPTION="3D composite and windowmanager"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://xorg.freedesktop.org/archive/individual/app/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1 MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+cairo dbus fuse gnome gtk kde kde4 +svg"
RESTRICT="mirror"

DEPEND="
	dev-libs/glib:2
	dev-libs/libxml2
	dev-libs/libxslt
	>=media-libs/glitz-0.5.6
	media-libs/libpng
	>=media-libs/mesa-6.5.1-r1
	>=x11-base/xorg-server-1.1.1-r1
	x11-libs/libX11[xcb]
	x11-libs/libxcb
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXinerama
	x11-libs/libXrandr
	x11-libs/libICE
	x11-libs/libSM
	>=x11-libs/libXrender-0.8.4
	>=x11-libs/startup-notification-0.7
	cairo? (
			x11-libs/cairo[X]
	)
	dbus? ( >=sys-apps/dbus-1.0 )
	fuse? ( sys-fs/fuse )
	gnome? (
		>=gnome-base/gnome-control-center-2.16.1:2
		gnome-base/gnome-desktop
		gnome-base/gconf:2
	)
	gtk? (
		>=x11-libs/gtk+-2.8.0:2
		>=x11-libs/libwnck-2.18.3
		x11-libs/pango
	)
	kde? (
		|| ( kde-base/kwin:3.5
			kde-base/kdebase:3.5
		)
		dev-libs/dbus-qt3-old
	)
	kde4? (
		|| (
			kde-base/kwin:4.1
			kde-base/kwin:4
			kde-base/kwin:kde-svn
		)
	)
	svg? (
		>=gnome-base/librsvg-2.14.0:2
		>=x11-libs/cairo-1.0
	)
"

RDEPEND="${DEPEND}
	x11-apps/mesa-progs
	x11-apps/xvinfo"

DEPEND="${DEPEND}
	dev-util/pkgconfig
	x11-proto/damageproto
	x11-proto/xineramaproto"

src_prepare() {

	use gnome || {
		epatch "${FILESDIR}"/${PN}-no-gconf.patch
		ln -s "${ROOT}"/usr/share/aclocal/gconf-2.m4 acinclude.m4

		# required to apply the above patch
		intltoolize --copy --force || die "intltoolize failed"
		eautoreconf || die "eautoreconf failed"
	}
}

src_configure() {
	econf \
		--disable-gnome-keybindings \
		--enable-librsvg \
		--with-default-plugins \
		$(use_enable cairo annotate) \
		$(use_enable dbus) \
		$(use_enable dbus dbus-glib) \
		$(use_enable fuse) \
		$(use_enable gnome) \
		$(use_enable gnome gconf) \
		$(use_enable gnome metacity) \
		$(use_enable gtk) \
		$(use_enable kde) \
		$(use_enable kde4) \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# Install compiz-manager
	dobin "${FILESDIR}/compiz-manager" || die "dobin failed"

	# Add the full-path to lspci
	sed -i "s#lspci#/usr/sbin/lspci#" "${D}/usr/bin/compiz-manager"

	# Create gentoo's config file
	dodir /etc/xdg/compiz

	cat <<- EOF > "${D}/etc/xdg/compiz/compiz-manager"
	COMPIZ_BIN_PATH="/usr/bin/"
	PLUGIN_PATH="/usr/$(get_libdir)/compiz/"
	LIBGL_NVIDIA="/usr/$(get_libdir)/opengl/xorg-x11/libGL.so.1.2"
	LIBGL_FGLRX="/usr/$(get_libdir)/opengl/xorg-x11/libGL.so.1.2"
	KWIN="$(type -p kwin)"
	METACITY="$(type -p metacity)"
	SKIP_CHECKS="yes"
	EOF

	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
}

pkg_postinst() {
	use gnome && gnome2_gconf_install
}

pkg_prerm() {
	use gnome && gnome2_gconf_uninstall
}