[gentoo-commits] repo/gentoo:master commit in: app-text/zathura/

[Mikle Kolyada]

commit:     7086d3297cb9fd67a86c4705104ec1f0d7051e29
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 16 13:21:54 2019 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Wed Jan 16 13:21:54 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7086d329

app-text/zathura: Version bump (v0.4.3)

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 app-text/zathura/Manifest             |  1 +
 app-text/zathura/zathura-0.4.3.ebuild | 58 +++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/app-text/zathura/Manifest b/app-text/zathura/Manifest
index 6a916bf9d80..f5a399d7908 100644
--- a/app-text/zathura/Manifest
+++ b/app-text/zathura/Manifest
@@ -1 +1,2 @@
 DIST zathura-0.4.1.tar.xz 148592 BLAKE2B c6fc495ce6413057dc86be95272e8178f32649c68f95052b2db00526b7805b1f6772c628902409af66ba88983171b5456f4cd26c77fcbe32023bf99d1081a55d SHA512 370e7fa12a3a3a2a973870a99f7b2b910c808d6932c1de9093630d7e8bd7d97feb4b7df713e9ac33c7927849b63174a899ce6eaa60db89b1c47d6e13ef181ad6
+DIST zathura-0.4.3.tar.xz 145796 BLAKE2B fe360d6ea2a11138324784beec8e8ebe0eaa83e4e682785a50265bbd0a77be0dcab4cd523923462398faaf918a4d304de148d64972dc9b6cb96578476e0ae6eb SHA512 427948025c20b2badb00921d03ec83e26806fd90d0d50cdcf0f3bcf645cd7206695faa3b5a7698d3d70b9bd60e8e68c920cf1e7f29855dd11a1a8ce6a7f8160b

diff --git a/app-text/zathura/zathura-0.4.3.ebuild b/app-text/zathura/zathura-0.4.3.ebuild
new file mode 100644
index 00000000000..498fcc32ef9
--- /dev/null
+++ b/app-text/zathura/zathura-0.4.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson virtualx
+
+DESCRIPTION="A highly customizable and functional document viewer"
+HOMEPAGE="http://pwmt.org/projects/zathura/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://pwmt.org/projects/zathura/download/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="ZLIB"
+SLOT="0"
+IUSE="doc +magic seccomp sqlite synctex test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND=">=dev-libs/girara-0.3.2
+	>=dev-libs/glib-2.50:2
+	>=sys-devel/gettext-0.19.8
+	x11-libs/cairo[X]
+	>=x11-libs/gtk+-3.22:3
+	magic? ( sys-apps/file )
+	seccomp? ( sys-libs/libseccomp )
+	sqlite? ( >=dev-db/sqlite-3.5.9:3 )
+	synctex? ( app-text/texlive-core )"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="doc? ( dev-python/sphinx )
+	test? ( dev-libs/appstream-glib
+		dev-libs/check )
+	virtual/pkgconfig"
+
+src_configure() {
+	local emesonargs=(
+		--libdir=/usr/$(get_libdir)
+		-Dconvert-icon=disabled
+		-Dmagic=$(usex magic enabled disabled)
+		-Dmanpages=$(usex doc enabled disabled)
+		-Dseccomp=$(usex seccomp enabled disabled)
+		-Dsqlite=$(usex sqlite enabled disabled)
+		-Dsynctex=$(usex synctex enabled disabled)
+		)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}