[gentoo-commits] gentoo-x86 commit in dev-util/monodevelop: monodevelop-2.2.2.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     10/05/04 06:46:40

  Modified:             ChangeLog
  Added:                monodevelop-2.2.2.ebuild
  Log:
  Bump for #317679
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.78                 dev-util/monodevelop/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	7 Mar 2010 08:34:56 -0000	1.77
+++ ChangeLog	4 May 2010 06:46:40 -0000	1.78
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/monodevelop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v 1.77 2010/03/07 08:34:56 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v 1.78 2010/05/04 06:46:40 patrick Exp $
+
+*monodevelop-2.2.2 (04 May 2010)
+
+  04 May 2010; Patrick Lauer <patrick@g.o> +monodevelop-2.2.2.ebuild:
+  Bump for #317679
 
   07 Mar 2010; Peter Alfredsen <loki_val@g.o>
   monodevelop-2.2.1.ebuild:



1.1                  dev-util/monodevelop/monodevelop-2.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/monodevelop-2.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/monodevelop/monodevelop-2.2.2.ebuild?rev=1.1&content-type=text/plain

Index: monodevelop-2.2.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/monodevelop-2.2.2.ebuild,v 1.1 2010/05/04 06:46:40 patrick Exp $

EAPI=2

inherit fdo-mime mono multilib gnome2-utils versionator

DESCRIPTION="Integrated Development Environment for .NET"
HOMEPAGE="http://www.monodevelop.com/"
SRC_URI="http://ftp.novell.com/pub/mono/sources/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+subversion"

RDEPEND="sys-apps/dbus[X]
	>=dev-lang/mono-2.4
	>=virtual/monodoc-2.0
	||	(
		>=dev-dotnet/mono-addins-0.4[gtk]
		~dev-dotnet/mono-addins-0.3.1
	)
	>=dev-dotnet/gtk-sharp-2.12.9
	>=dev-dotnet/glade-sharp-2.12.9
	>=dev-dotnet/gnome-sharp-2.24.0
	>=dev-dotnet/gnomevfs-sharp-2.24.0
	>=dev-dotnet/gconf-sharp-2.24.0
	||	(
		net-libs/xulrunner
		www-client/mozilla-firefox
		www-client/firefox-bin
		www-client/seamonkey
	)
	>=dev-dotnet/xsp-2
	subversion? ( dev-util/subversion )
	dev-util/ctags
	!<dev-util/monodevelop-boo-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-java-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-database-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-debugger-gdb-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-debugger-mdb-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-vala-$(get_version_component_range 1-2)"

DEPEND="${RDEPEND}
	sys-devel/gettext
	x11-misc/shared-mime-info
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.19"

MAKEOPTS="${MAKEOPTS} -j1"

src_configure() {
	econf	--disable-update-mimedb				\
		--disable-update-desktopdb			\
		--enable-monoextensions				\
		--enable-versioncontrol				\
		--enable-gnomeplatform				\
		$(use_enable subversion)			\
		|| die "configure failed"
}

src_compile() {
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc ChangeLog README || die "dodoc failed"
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_mime_database_update
	fdo-mime_desktop_database_update
	elog "These optional plugins currently exist:"
	elog " - dev-util/monodevelop-boo"
	elog " - dev-util/monodevelop-java"
	elog " - dev-util/monodevelop-database"
	elog " - dev-util/monodevelop-debugger-gdb"
	elog " - dev-util/monodevelop-debugger-mdb"
	elog " - dev-util/monodevelop-vala"
	elog "To enable their (self-explanatory) functionality, just emerge them."
	elog "Read more here:"
	elog "http://monodevelop.com/"
}