[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     06fe3df2686b37aa8e41cdc880787c3a3a67f062
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun May 30 00:16:10 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun May 30 00:16:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=06fe3df2

sys-kernel/gentoo-kernel-bin: bump to 5.10.41 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.41-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 96148c43dc1..4097c8ecfe2 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -39,6 +39,7 @@ DIST gentoo-kernel-5.10.40-1.amd64.xpak 65506415 BLAKE2B 91f5c3f13350c922d40740c
 DIST gentoo-kernel-5.10.40-1.arm64.xpak 59237288 BLAKE2B 21e19596314712a4d535d188744a9b7e7f3b155f767ff4c85dd9aed3dd46867f52bc649b8ea4dd76355b5a462d297d4c20757707ed3a0bca136cb56dd1caa699 SHA512 b352c943d33430b5e04c63ff0d33e80aac2171d6e1048f8a1029730e0a8b08bd7ebaf40d0afe4174b8600cd8c47322304e49c2fb72ab5a19b53d3fdb34ffbcfd
 DIST gentoo-kernel-5.10.40-1.x86.xpak 57236415 BLAKE2B 803f67facaaa6f162f34290c79bd0a33c6121221da09b9f09083df5cd6fbf3aee8517926fd80261352194ebb4b977c27d06b77a06ff01ef0fa7f17573260e186 SHA512 c78f1388bc34658a2c2e261085752a581110bd2650d06e6bef4ee3a4e62fd323c8e33ae74b6a795700ef2e205d872e914ee4358c0d1bfac43f7c209fd305c103
 DIST gentoo-kernel-5.10.41-1.amd64.xpak 65519229 BLAKE2B 1e11591d6aff9976116eff850c9a776e3da59731b6326886c47a47a49e242206a1711c7acef2bf591f26088f1e48a0e5430b55080acf23e94a061da234aacad2 SHA512 a255ae0856d940d051d69eef998b83de172d821f497b9fa752e97775e9dc0836ba5f0dcdfb019038c9799ff4a460e6b2fc30aa48c0f77060446d7f6c75b97e71
+DIST gentoo-kernel-5.10.41-1.arm64.xpak 58996490 BLAKE2B c206bf22c57e3d13a9c61699e21c4beeb8c76df15f314eb18b92150199996bebc34bf950bd52b272ace25c8156e81d4f4d74bf1fbc796b08f5d0eabff195fcd0 SHA512 3ce0edbd214192e7fa63c033191853776e797c42e945d5a2e6ded6ab70c0c67576571a73595cf67975a987af7c091d1c6ae542cb827ddc31ebf854ff04589b7e
 DIST gentoo-kernel-5.10.41-1.x86.xpak 57258381 BLAKE2B e66c7ae5e45d5e2a5258bbc297565c50978c8097e14ce34f8219d021b823bdb776b55f01aa3137fa44cb3016c8cd2459594dfbe8cb0e511f48ce6aa7b566610b SHA512 22d74f1015898f9cb835e435a6b48b017ff3712deaa44c1b250c646ce0853aa71b00e7d027b84d5669113d5b7ca29348970255daa1bad3cd965a0a55ef127a5d
 DIST gentoo-kernel-5.11.22-1.amd64.xpak 65882786 BLAKE2B aa98de82c4f47a586474f6f888a12fa3fb4605bd3dae576a36a9edfd10b669cb586d975dd6dfd4fac0ca3906e56a14250effb44b54ea6646898b12ddeeb6ae28 SHA512 1cd5f40f7ae0500158d05e3da14788a407faef9c471001fa5cb403e6cbbd062130645166cab28f3ad79cb6318dd0fb5961a515952a91de35f34b44483931c5a2
 DIST gentoo-kernel-5.11.22-1.arm64.xpak 59725454 BLAKE2B bffe7733b1ab766ab7afae20c77696ab36bed989dae7fef60e6eba752da8f918240e0d28fdce01d5813775c4013df80ba495e6ed7163838bde2896ffce96fb06 SHA512 8b1e4b0f6ca7294a457574f23557df1cc99dc6be41f3a36f6a871cb8a21d52f0556279afe400301bbdf715d4e07134da845c37318a1e6df9e14e379cf4252f68

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.41-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.41-r1.ebuild
new file mode 100644
index 00000000000..8198cf5ace0
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.41-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}