[gentoo-commits] gentoo-x86 commit in net-wireless/bluez: bluez-4.77.ebuild metadata.xml ChangeLog bluez-4.71.ebuild bluez-4.72.ebuild bluez-4.66-r1.ebuild

[Pacho Ramos (pacho)]

pacho       10/10/31 11:23:38

  Modified:             metadata.xml ChangeLog
  Added:                bluez-4.77.ebuild
  Removed:              bluez-4.71.ebuild bluez-4.72.ebuild
                        bluez-4.66-r1.ebuild
  Log:
  Version bump and remove old.
  
  (Portage version: 2.1.9.23/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 net-wireless/bluez/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/metadata.xml?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/metadata.xml?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/metadata.xml?r1=1.9&r2=1.10

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/bluez/metadata.xml,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- metadata.xml	24 Sep 2010 21:32:51 -0000	1.9
+++ metadata.xml	31 Oct 2010 11:23:38 -0000	1.10
@@ -18,7 +18,6 @@
 		<flag name='consolekit'>Use <pkg>sys-auth/pambase[consolekit]</pkg> to
 			determine access to bluetooth devices based on whether a user is
 			logged in locally or remotely</flag>
-		<flag name='mcap'>Compile with initial support for MCAP</flag>
 		<flag name='health'>Compile with initial support for HDP</flag>
 		<flag name='maemo6'>Compile with maemo6 plugin</flag>
 		<flag name='old-daemons'>Install old daemons like hidd and sdpd that are



1.56                 net-wireless/bluez/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	7 Oct 2010 20:52:25 -0000	1.55
+++ ChangeLog	31 Oct 2010 11:23:38 -0000	1.56
@@ -1,6 +1,28 @@
 # ChangeLog for net-wireless/bluez
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.55 2010/10/07 20:52:25 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.56 2010/10/31 11:23:38 pacho Exp $
+
+*bluez-4.77 (31 Oct 2010)
+
+  31 Oct 2010; Pacho Ramos <pacho@g.o> -bluez-4.66-r1.ebuild,
+  -bluez-4.71.ebuild, -bluez-4.72.ebuild, +bluez-4.77.ebuild:
+  Remove old and version bump:
+	Fix issue with device name and accessing already freed memory.
+	Fix issue with handling CHLD=0 command for handsfree.
+	Fix issue with manager properties and no adapters.
+	Fix issue with properties and broken service records.
+	Fix issue with A2DP playback and sample rate changes.
+	Update MCAP and HDP support.
+	Fix issue in telephony driver with hanging up held call.
+	Fix issue in telephony driver with notifications when on hold.
+	Fix issue with blocking on setconf confirmation callback.
+	Fix issue with not always signaling new streams as sinks.
+	Fix issue with errors in case of endpoint request timeout.
+	Fix issue with HFP/HSP microphone and speaker gain values.
+	Add source if the device attempt to configure local sink stream.
+	Add PSM option for GATT/ATT over BR/EDR on gatttool.
+	Add support for GATT/ATT Attribute Write Request.
+	Update MCAP and HDP support.
 
 *bluez-4.75 (07 Oct 2010)
 



1.1                  net-wireless/bluez/bluez-4.77.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-4.77.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-4.77.ebuild?rev=1.1&content-type=text/plain

Index: bluez-4.77.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/bluez-4.77.ebuild,v 1.1 2010/10/31 11:23:38 pacho Exp $

EAPI="3"

inherit multilib eutils

DESCRIPTION="Bluetooth Tools and System Daemons for Linux"
HOMEPAGE="http://bluez.sourceforge.net/"
SRC_URI="mirror://kernel/linux/bluetooth/${P}.tar.gz
	http://standards.ieee.org/regauth/oui/oui.txt"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"

IUSE="alsa attrib caps +consolekit cups debug gstreamer maemo6 health old-daemons pcmcia pnat test-programs usb"

CDEPEND="alsa? (
		media-libs/alsa-lib[alsa_pcm_plugins_extplug,alsa_pcm_plugins_ioplug]
	)
	caps? ( >=sys-libs/libcap-ng-0.6.2 )
	gstreamer? (
		>=media-libs/gstreamer-0.10
		>=media-libs/gst-plugins-base-0.10 )
	usb? ( dev-libs/libusb )
	cups? ( net-print/cups )
	>=sys-fs/udev-146[extras]
	>=dev-libs/glib-2.14
	sys-apps/dbus
	media-libs/libsndfile
	>=dev-libs/libnl-1.1
	!net-wireless/bluez-libs
	!net-wireless/bluez-utils"
DEPEND="sys-devel/flex
	>=dev-util/pkgconfig-0.20
	${CDEPEND}"
RDEPEND="${CDEPEND}
	consolekit? ( sys-auth/pambase[consolekit] )
	test-programs? (
		dev-python/dbus-python
		dev-python/pygobject )"

pkg_setup() {
	if ! use consolekit; then
		enewgroup plugdev
	fi
}

src_prepare() {
	if ! use consolekit; then
		# No consolekit for at_console etc, so we grant plugdev the rights
		epatch	"${FILESDIR}/bluez-plugdev.patch"
	fi

	if use cups; then
		epatch "${FILESDIR}/4.60/cups-location.patch"
	fi
}

src_configure() {
	econf \
		$(use_enable caps capng) \
		--enable-network \
		--enable-serial \
		--enable-input \
		--enable-audio \
		--enable-service \
		$(use_enable gstreamer) \
		$(use_enable alsa) \
		$(use_enable usb) \
		--enable-tools \
		--enable-bccmd \
		--enable-dfutool \
		$(use_enable old-daemons hidd) \
		$(use_enable old-daemons pand) \
		$(use_enable old-daemons dund) \
		$(use_enable attrib) \
		$(use_enable health) \
		$(use_enable pnat) \
		$(use_enable maemo6) \
		$(use_enable cups) \
		$(use_enable test-programs test) \
		--enable-udevrules \
		--enable-configfiles \
		$(use_enable pcmcia) \
		$(use_enable debug) \
		--localstatedir=/var \
		--disable-hal
}

src_install() {
	emake DESTDIR="${ED}" install || die "make install failed"

	dodoc AUTHORS ChangeLog README || die

	if use test-programs ; then
		cd "${S}/test"
		dobin simple-agent simple-service monitor-bluetooth || die
		newbin list-devices list-bluetooth-devices || die
		for b in apitest hsmicro hsplay test-* ; do
			newbin "${b}" "bluez-${b}" || die
		done
		insinto /usr/share/doc/${PF}/test-services
		doins service-* || die

		cd "${S}"
	fi

	if use old-daemons; then
		newconfd "${FILESDIR}/4.18/conf.d-hidd" hidd || die
		newinitd "${FILESDIR}/init.d-hidd" hidd || die
		newconfd "${FILESDIR}/conf.d-dund" dund || die
		newinitd "${FILESDIR}/init.d-dund" dund || die
	fi

	insinto /etc/bluetooth
	doins \
		input/input.conf \
		audio/audio.conf \
		network/network.conf \
		serial/serial.conf \
		|| die

	insinto /etc/udev/rules.d/
	newins "${FILESDIR}/${PN}-4.18-udev.rules" 70-bluetooth.rules || die
	exeinto /$(get_libdir)/udev/
	newexe "${FILESDIR}/${PN}-4.18-udev.script" bluetooth.sh || die

	newinitd "${FILESDIR}/bluetooth-init.d" bluetooth || die
	newconfd "${FILESDIR}/4.60/bluetooth-conf.d" bluetooth || die

	# Install oui.txt as requested in bug #283791 and approved by upstream
	insinto /var/lib/misc
	doins "${DISTDIR}/oui.txt" || die
}

pkg_postinst() {
	udevadm control --reload-rules && udevadm trigger --subsystem-match=bluetooth

	if ! has_version "net-dialup/ppp"; then
		elog
		elog "To use dial up networking you must install net-dialup/ppp."
	fi

	if ! has_version "net-wireless/gnome-bluetooth" && ! has_version "net-wireless/kbluetooth"; then
		elog
		elog "For desktop integration you can try net-wireless/gnome-bluetooth"
		elog "for gnome and net-wireless/kbluetooth for kde."
	fi

	if ! use old-daemons; then
		elog
		elog "Use the old-daemons use flag to get the old daemons like hidd or pand"
		elog "installed. Please note that 'bluetooth' init script doesn't stop the old"
		elog "daemons after you update it, so it's recommended to stop all of them using"
		elog "their own init scripts or manually killing them."
	fi

	if use consolekit; then
		elog
		elog "If you want to use rfcomm as a normal user, you need to add the user"
		elog "to the uucp group."
	else
		elog
		elog "Since you have the consolekit use flag disabled, you will only be able to run"
		elog "bluetooth clients as root. If you want to be able to run bluetooth clientes as "
		elog "a regular user, you need to enable the consolekit use flag for this package or"
		elog "to add the user to the plugdev group."
	fi

	if use old-daemons; then
		elog
		elog "dund and hidd init scripts were installed because you have the old-daemons"
		elog "use flag on. They are not started by default via udev so please add them"
		elog "to the required runlevels using rc-update <runlevel> add <dund/hidd>. If"
		elog "you need init scripts for the other daemons, please file requests"
		elog "to https://bugs.gentoo.org."
	fi
}