[gentoo-commits] gentoo-x86 commit in games-roguelike/stone-soup: stone-soup-0.11.1.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    12/11/22 17:25:29

  Modified:             ChangeLog
  Added:                stone-soup-0.11.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.4                  games-roguelike/stone-soup/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	5 Oct 2012 14:13:29 -0000	1.3
+++ ChangeLog	22 Nov 2012 17:25:29 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for games-roguelike/stone-soup
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/ChangeLog,v 1.3 2012/10/05 14:13:29 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/ChangeLog,v 1.4 2012/11/22 17:25:29 hasufell Exp $
+
+*stone-soup-0.11.1 (22 Nov 2012)
+
+  22 Nov 2012; Julian Ospald <hasufell@g.o> +stone-soup-0.11.1.ebuild,
+  +files/stone-soup-0.11.1-build.patch:
+  version bump
 
 *stone-soup-0.11.0 (05 Oct 2012)
 



1.1                  games-roguelike/stone-soup/stone-soup-0.11.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/stone-soup-0.11.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/stone-soup/stone-soup-0.11.1.ebuild?rev=1.1&content-type=text/plain

Index: stone-soup-0.11.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/stone-soup/stone-soup-0.11.1.ebuild,v 1.1 2012/11/22 17:25:29 hasufell Exp $

## TODO
# add sound support (no build switch, no sound files)

EAPI=4
VIRTUALX_REQUIRED="manual"
inherit eutils gnome2-utils virtualx games

MY_P="stone_soup-${PV}"
DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
HOMEPAGE="http://crawl.develz.org/wordpress/"
SRC_URI="mirror://sourceforge/crawl-ref/Stone%20Soup/${PV}/${MY_P}-nodeps.tar.xz
	http://dev.gentoo.org/~hasufell/distfiles/${PN}.png
	http://dev.gentoo.org/~hasufell/distfiles/${PN}.svg"

# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
# Public Domain|CC0: most of tiles
# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0-Universal MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +lua +tiles"
# test is broken
# see https://crawl.develz.org/mantis/view.php?id=6121
#RESTRICT="!debug? ( test )"
RESTRICT="test"

RDEPEND="
	dev-db/sqlite:3
	sys-libs/zlib
	tiles? (
		media-libs/freetype:2
		media-libs/libpng:0
		media-libs/libsdl[X,opengl,video]
		media-libs/sdl-image[png]
		)
	!tiles? ( sys-libs/ncurses )
	lua? ( >=dev-lang/lua-5.1.0 )"
DEPEND="${RDEPEND}
	dev-lang/perl
	sys-devel/flex
	virtual/yacc
	tiles? (
		sys-libs/ncurses
		virtual/pkgconfig
		test? ( ${VIRTUALX_DEPEND} )
		)"

S=${WORKDIR}/${MY_P}/source

src_prepare() {
	epatch "${FILESDIR}"/${P}-build.patch

#	if use test ; then
#		cp -av "${WORKDIR}/${MY_P}" "${WORKDIR}/${MY_P}_test" \
#			|| die "setting up test-dir failed"
#	fi
}

src_compile() {
	S_TEST=${WORKDIR}/${MY_P}_test/source

	# leave DATADIR at the top
	myemakeargs=(
		DATADIR="${GAMES_DATADIR}/${PN}"
		V=1
		prefix="${GAMES_PREFIX}"
		SAVEDIR="~/.crawl"
		$(usex debug "FULLDEBUG=y DEBUG=y" "")
		$(usex lua "" "NO_LUA_BINDINGS=y")
		$(usex tiles "TILES=y" "")
	)

	emake ${myemakeargs[@]}

	# for test to work we need to compile with unset DATADIR
#	if use test ; then
#		emake ${myemakeargs[@]:1} -C "${S_TEST}"
#	fi
}

src_install() {
	emake ${myemakeargs[@]} DESTDIR="${D}" install

	# don't relocate docs, needed at runtime
	rm -rf "${D}${GAMES_DATADIR}"/${PN}/docs/license
	dodoc "${WORKDIR}"/${MY_P}/README.{txt,pdf}

	# icons and menu for graphical build
	if use tiles ; then
		doicon -s 48 "${DISTDIR}"/${PN}.png
		doicon -s scalable "${DISTDIR}"/${PN}.svg
		make_desktop_entry crawl
	fi

	prepgamesdirs
}

src_test() {
	$(usex tiles "X" "")emake ${myemakeargs[@]:1} -C "${S_TEST}" test
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update

	echo
	elog "Your old config folder under '~/.crawl' is not compatible"
	elog "with the new version. Remove it."
	echo
}

pkg_postrm() {
	gnome2_icon_cache_update
}