[gentoo-commits] gentoo-x86 commit in media-libs/libpostproc: libpostproc-9999.ebuild libpostproc-10.20140517-r1.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/06/07 21:31:50

  Modified:             libpostproc-9999.ebuild ChangeLog
  Added:                libpostproc-10.20140517-r1.ebuild
  Log:
  Enable multilib support, bug #489820.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.10                 media-libs/libpostproc/libpostproc-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/libpostproc-9999.ebuild?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/libpostproc-9999.ebuild?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/libpostproc-9999.ebuild?r1=1.9&r2=1.10

Index: libpostproc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libpostproc/libpostproc-9999.ebuild,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- libpostproc-9999.ebuild	12 May 2014 17:03:20 -0000	1.9
+++ libpostproc-9999.ebuild	7 Jun 2014 21:31:50 -0000	1.10
@@ -1,8 +1,8 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpostproc/libpostproc-9999.ebuild,v 1.9 2014/05/12 17:03:20 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpostproc/libpostproc-9999.ebuild,v 1.10 2014/06/07 21:31:50 mgorny Exp $
 
-EAPI="4"
+EAPI="5"
 
 SCM=""
 if [ "${PV#9999}" != "${PV}" ] ; then
@@ -10,7 +10,7 @@
 	EGIT_REPO_URI="git://github.com/lu-zero/postproc.git"
 fi
 
-inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+inherit eutils flag-o-matic multilib multilib-minimal toolchain-funcs ${SCM}
 
 DESCRIPTION="Video post processing library"
 HOMEPAGE="https://github.com/lu-zero/postproc"
@@ -36,45 +36,46 @@
 	IUSE="${IUSE} ${i%:*}"
 done
 
-DEPEND=">=virtual/ffmpeg-0.10.2-r2"
+DEPEND=">=virtual/ffmpeg-0.10.2-r2[${MULTILIB_USEDEP}]"
 RDEPEND="${DEPEND}
 	!<media-video/libav-0.8.2-r2
 	!media-video/ffmpeg:0
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20140508-r3
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )
 "
 
-src_configure() {
-	local myconf="${EXTRA_LIBPOSTPROC_CONF}"
+multilib_src_configure() {
+	local myconf=( ${EXTRA_LIBPOSTPROC_CONF} )
 	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
-		[ "${i}" = "native" ] && i="host" # bug #273421
-		myconf="${myconf} --cpu=${i}"
+		[[ "${i}" = "native" ]] && i="host" # bug #273421
+		myconf+=( --cpu=${i} )
 		break
 	done
 
 	if use pic ; then
-		myconf="${myconf} --enable-pic"
+		myconf+=( --enable-pic )
 		# disable asm code if PIC is required
 		# as the provided asm decidedly is not PIC for x86.
-		use x86 && myconf="${myconf} --disable-asm"
+		[[ ${ABI} == x86 ]] && myconf+=( --disable-asm )
 	fi
 
 	# cross compile support
 	if tc-is-cross-compiler ; then
-		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- )
 		case ${CHOST} in
 			*freebsd*)
-				myconf="${myconf} --target-os=freebsd"
+				myconf+=( --target-os=freebsd )
 				;;
 			mingw32*)
-				myconf="${myconf} --target-os=mingw32"
+				myconf+=( --target-os=mingw32 )
 				;;
 			*linux*)
-				myconf="${myconf} --target-os=linux"
+				myconf+=( --target-os=linux )
 				;;
 		esac
 	fi
 
-	cd "${S}"
-	./configure \
+	"${S}"/configure \
 		--prefix="${EPREFIX}/usr" \
 		--libdir="${EPREFIX}/usr/$(get_libdir)" \
 		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
@@ -84,5 +85,5 @@
 		--optflags="${CFLAGS}" \
 		--extra-cflags="${CFLAGS}" \
 		$(use_enable static-libs static) \
-		${myconf} || die
+		"${myconf[@]}" || die
 }



1.25                 media-libs/libpostproc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libpostproc/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	17 May 2014 09:24:48 -0000	1.24
+++ ChangeLog	7 Jun 2014 21:31:50 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libpostproc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpostproc/ChangeLog,v 1.24 2014/05/17 09:24:48 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpostproc/ChangeLog,v 1.25 2014/06/07 21:31:50 mgorny Exp $
+
+*libpostproc-10.20140517-r1 (07 Jun 2014)
+
+  07 Jun 2014; Michał Górny <mgorny@g.o>
+  +libpostproc-10.20140517-r1.ebuild, libpostproc-9999.ebuild:
+  Enable multilib support, bug #489820.
 
 *libpostproc-10.20140517 (17 May 2014)
 



1.1                  media-libs/libpostproc/libpostproc-10.20140517-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/libpostproc-10.20140517-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpostproc/libpostproc-10.20140517-r1.ebuild?rev=1.1&content-type=text/plain

Index: libpostproc-10.20140517-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libpostproc/libpostproc-10.20140517-r1.ebuild,v 1.1 2014/06/07 21:31:50 mgorny Exp $

EAPI="5"

SCM=""
if [ "${PV#9999}" != "${PV}" ] ; then
	SCM="git-2"
	EGIT_REPO_URI="git://github.com/lu-zero/postproc.git"
fi

inherit eutils flag-o-matic multilib multilib-minimal toolchain-funcs ${SCM}

DESCRIPTION="Video post processing library"
HOMEPAGE="https://github.com/lu-zero/postproc"
if [ "${PV#9999}" != "${PV}" ] ; then
	SRC_URI=""
elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
	SRC_URI="mirror://gentoo/${P}.tar.xz"
else # Release
	SRC_URI="http://dev.gentoo.org/~lu_zero/distfiles/${P}.tar.xz"
fi

LICENSE="GPL-2"
SLOT="0"
if [ "${PV#9999}" = "${PV}" ] ; then
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
fi
IUSE="pic static-libs"

# String for CPU features in the useflag[:configure_option] form
# if :configure_option isn't set, it will use 'useflag' as configure option
CPU_FEATURES="3dnow:amd3dnow altivec mmx mmxext"
for i in ${CPU_FEATURES}; do
	IUSE="${IUSE} ${i%:*}"
done

DEPEND=">=virtual/ffmpeg-0.10.2-r2[${MULTILIB_USEDEP}]"
RDEPEND="${DEPEND}
	!<media-video/libav-0.8.2-r2
	!media-video/ffmpeg:0
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20140508-r3
		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )
"

multilib_src_configure() {
	local myconf=( ${EXTRA_LIBPOSTPROC_CONF} )
	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
		[[ "${i}" = "native" ]] && i="host" # bug #273421
		myconf+=( --cpu=${i} )
		break
	done

	if use pic ; then
		myconf+=( --enable-pic )
		# disable asm code if PIC is required
		# as the provided asm decidedly is not PIC for x86.
		[[ ${ABI} == x86 ]] && myconf+=( --disable-asm )
	fi

	# cross compile support
	if tc-is-cross-compiler ; then
		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- )
		case ${CHOST} in
			*freebsd*)
				myconf+=( --target-os=freebsd )
				;;
			mingw32*)
				myconf+=( --target-os=mingw32 )
				;;
			*linux*)
				myconf+=( --target-os=linux )
				;;
		esac
	fi

	"${S}"/configure \
		--prefix="${EPREFIX}/usr" \
		--libdir="${EPREFIX}/usr/$(get_libdir)" \
		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
		--enable-shared \
		--cc="$(tc-getCC)" \
		--ar="$(tc-getAR)" \
		--optflags="${CFLAGS}" \
		--extra-cflags="${CFLAGS}" \
		$(use_enable static-libs static) \
		"${myconf[@]}" || die
}