[gentoo-commits] repo/gentoo:master commit in: app-misc/geoclue/

[Matt Turner]

commit:     6ea84944af9f7e07e9c3627dd89ca4473fdf5d00
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue May 10 18:41:17 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue May 10 19:59:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ea84944

app-misc/geoclue: Version bump to 2.6.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-misc/geoclue/Manifest             |  1 +
 app-misc/geoclue/geoclue-2.6.0.ebuild | 81 +++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/app-misc/geoclue/Manifest b/app-misc/geoclue/Manifest
index 499cbb4ad273..36a03fd5334e 100644
--- a/app-misc/geoclue/Manifest
+++ b/app-misc/geoclue/Manifest
@@ -1 +1,2 @@
 DIST geoclue-2.5.7.tar.bz2 85764 BLAKE2B bf0a6e312b7a303ed2cfc33f02cfad0e68e44f60899a327c9eba12f4967d2a3a5922a475f8fefb6f47da328c92dc75706504b41bc2dcd21db3fc5da7c2a50180 SHA512 16ec15afa41910b7d993a9918dd3c068dea3f6c5be922b7ac772493cd6aabb0cad3fe2206b82c1a008781c3f1ddd8f4afd8f70b5d497920bea8ed5e473f0fd1f
+DIST geoclue-2.6.0.tar.bz2 94890 BLAKE2B d579752482e77e6ec6df3cb34f6b1c7ca61ea425f1c29195f1bcd031afe22644aed2f5b3f75e82c20e0e3cf0d415ca858b30351b2ee3835fff0ca25e63fc6395 SHA512 13205ab88cbd9748c155081318ae1909fddedce4250e3ece39a9f379b8cfea91dfe571961e278406ba54f8efd3a1070967479feb8256f50170112b28246b3103

diff --git a/app-misc/geoclue/geoclue-2.6.0.ebuild b/app-misc/geoclue/geoclue-2.6.0.ebuild
new file mode 100644
index 000000000000..d792a58f3b94
--- /dev/null
+++ b/app-misc/geoclue/geoclue-2.6.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-any-r1 systemd vala xdg
+
+DESCRIPTION="A location information D-Bus service"
+HOMEPAGE="https://gitlab.freedesktop.org/geoclue/geoclue/wikis/home"
+SRC_URI="https://gitlab.freedesktop.org/geoclue/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+introspection gtk-doc modemmanager vala zeroconf"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/json-glib-0.14.0
+	>=net-libs/libsoup-2.42.0:2.4
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	modemmanager? ( >=net-misc/modemmanager-1.6 )
+	zeroconf? ( >=net-dns/avahi-0.6.10[dbus] )
+	x11-libs/libnotify
+"
+RDEPEND="${DEPEND}
+	acct-user/geoclue
+	sys-apps/dbus
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		>=dev-util/gtk-doc-1 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dlibgeoclue=true
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc)
+		$(meson_use modemmanager 3g-source)
+		$(meson_use modemmanager cdma-source)
+		$(meson_use modemmanager modem-gps-source)
+		$(meson_use zeroconf nmea-source)
+		-Dcompass=true
+		-Denable-backend=true
+		-Ddemo-agent=true
+		-Dsystemd-system-unit-dir="$(systemd_get_systemunitdir)"
+		-Ddbus-srv-user=geoclue
+
+		-Dmozilla-api-key=f57afde7-113f-4e8f-96d1-62be64a0273c
+	)
+
+	DISTRO="$(awk -F= '/^NAME/ {print $2}' /etc/os-release | tr -d \" )"
+	if [[ $DISTRO != Gentoo ]]; then
+		eerror "The following API key has been allocated for Gentoo only."
+		eerror "If you are a derivative, please request your own key as discussed here:"
+		eerror "https://gitlab.freedesktop.org/geoclue/geoclue/-/issues/136"
+		eerror "See also: https://location.services.mozilla.com/api and"
+		eerror "https://blog.mozilla.org/services/2019/09/03/a-new-policy-for-mozilla-location-service/"
+		die "Please request an API key for your distribution."
+	fi
+
+	meson_src_configure
+}