[gentoo-commits] repo/gentoo:master commit in: media-sound/mpc/

[Andreas Sturmlechner]

commit:     35999aeea8ffc954dfb586fc9109a225adc4fe5d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  9 21:42:28 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Feb  9 21:51:45 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=35999aee

media-sound/mpc: Add USE doc, fix install path

Closes: https://bugs.gentoo.org/670074
Closes: https://bugs.gentoo.org/670262
Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/mpc/mpc-0.31-r1.ebuild | 54 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/media-sound/mpc/mpc-0.31-r1.ebuild b/media-sound/mpc/mpc-0.31-r1.ebuild
new file mode 100644
index 00000000000..63e630daea4
--- /dev/null
+++ b/media-sound/mpc/mpc-0.31-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 meson
+
+DESCRIPTION="Commandline client for Music Player Daemon (media-sound/mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/mpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc iconv test"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+	iconv? ( virtual/libiconv )
+	test? ( dev-libs/check )
+"
+DEPEND="media-libs/libmpdclient"
+RDEPEND="${DEPEND}"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=( "${FILESDIR}/${P}-nodoc.patch" )
+
+src_prepare() {
+	default
+
+	# use correct docdir
+	sed -e "/install_dir:.*contrib/s/meson.project_name()/'${PF}'/" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Diconv=$(usex iconv enabled disabled)
+		-Dtest=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	newbashcomp contrib/mpc-completion.bash mpc
+}