[gentoo-commits] gentoo-x86 commit in media-sound/rosegarden: ChangeLog rosegarden-11.11.42.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/04/06 08:40:00

  Modified:             ChangeLog
  Added:                rosegarden-11.11.42.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha99/cvs/Linux x86_64)

Revision  Changes    Path
1.95                 media-sound/rosegarden/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	5 Apr 2012 21:08:16 -0000	1.94
+++ ChangeLog	6 Apr 2012 08:40:00 -0000	1.95
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/rosegarden
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.94 2012/04/05 21:08:16 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.95 2012/04/06 08:40:00 ssuominen Exp $
+
+*rosegarden-11.11.42 (06 Apr 2012)
+
+  06 Apr 2012; Samuli Suominen <ssuominen@g.o>
+  +rosegarden-11.11.42.ebuild:
+  Version bump.
 
   05 Apr 2012; Pawel Hajdan jr <phajdan.jr@g.o>
   rosegarden-11.11.11.ebuild:



1.1                  media-sound/rosegarden/rosegarden-11.11.42.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/rosegarden-11.11.42.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/rosegarden/rosegarden-11.11.42.ebuild?rev=1.1&content-type=text/plain

Index: rosegarden-11.11.42.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/rosegarden-11.11.42.ebuild,v 1.1 2012/04/06 08:40:00 ssuominen Exp $

EAPI=4
inherit autotools fdo-mime gnome2-utils multilib

DESCRIPTION="MIDI and audio sequencer and notation editor"
HOMEPAGE="http://www.rosegardenmusic.com/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug lirc"

RDEPEND="x11-libs/qt-gui:4
	media-libs/ladspa-sdk
	x11-libs/libSM
	media-sound/jack-audio-connection-kit
	media-libs/alsa-lib
	>=media-libs/dssi-1.0.0
	media-libs/liblo
	media-libs/liblrdf
	sci-libs/fftw:3.0
	media-libs/libsamplerate[sndfile]
	lirc? ( app-misc/lirc )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-misc/makedepend"

src_prepare() {
	if ! use lirc; then
		sed -i \
			-e '/AC_CHECK_HEADER/s:lirc_client.h:dIsAbLe&:' \
			-e '/AC_CHECK_LIB/s:lirc_init:dIsAbLe&:' \
			configure.ac || die
	fi

	eautoreconf
}

src_configure() {
	export USER_CXXFLAGS="${CXXFLAGS}"

	local myconf
	use debug && myconf="--enable-debug"

	econf \
		--with-qtdir=/usr \
		--with-qtlibdir=/usr/$(get_libdir)/qt4 \
		${myconf}
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}