[gentoo-commits] repo/gentoo:master commit in: dev-python/socketpool/

[Patrick McLean]

commit:     ec966ddb7adaefdfb0cd8cdac432332e06c9a386
Author:     Patrick McLean <patrick.mclean <AT> sony <DOT> com>
AuthorDate: Wed Nov 27 18:58:15 2019 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Wed Nov 27 18:58:35 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec966ddb

dev-python/socketpool-0.5.3-r2: revbump, cleanups, py38 and pypy3

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 dev-python/socketpool/socketpool-0.5.3-r2.ebuild | 41 ++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/dev-python/socketpool/socketpool-0.5.3-r2.ebuild b/dev-python/socketpool/socketpool-0.5.3-r2.ebuild
new file mode 100644
index 00000000000..e5d4e8ce43b
--- /dev/null
+++ b/dev-python/socketpool/socketpool-0.5.3-r2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A simple Python socket pool"
+HOMEPAGE="https://github.com/benoitc/socketpool/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="examples test"
+LICENSE="|| ( MIT public-domain )"
+SLOT="0"
+
+RDEPEND="$(python_gen_cond_dep 'dev-python/gevent[${PYTHON_USEDEP}]' 'python2*')"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.5.2-locale.patch )
+
+distutils_enable_tests pytest
+
+python_test() {
+	cp -r examples tests "${BUILD_DIR}" || die
+
+	pushd "${BUILD_DIR}" >/dev/null || die
+	pytest -vv tests || die "Tests fail with ${EPYTHON}"
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	use examples && dodoc -r examples
+
+	# package installs unneeded LICENSE files here
+	rm -r "${ED}"/usr/socketpool || die
+}