[gentoo-commits] repo/gentoo:master commit in: net-libs/webkit-gtk/

[Mart Raudsepp]

commit:     927e1ec5f0b9871d5f3347309aad210e326f8056
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 30 03:32:26 2016 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Dec 30 03:32:26 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=927e1ec5

net-libs/webkit-gtk: Remove old

Package-Manager: portage-2.3.3

 net-libs/webkit-gtk/Manifest                 |   1 -
 net-libs/webkit-gtk/webkit-gtk-2.14.1.ebuild | 289 ---------------------------
 2 files changed, 290 deletions(-)

diff --git a/net-libs/webkit-gtk/Manifest b/net-libs/webkit-gtk/Manifest
index 8d0113a..2349e43 100644
--- a/net-libs/webkit-gtk/Manifest
+++ b/net-libs/webkit-gtk/Manifest
@@ -1,4 +1,3 @@
 DIST webkitgtk-2.12.5.tar.xz 11712488 SHA256 6b147854b864a5f115fadb97b2b6200b2f696db015216a34e7298d11c88b1c40 SHA512 ec98e862c2b8799dead6ff3da8299696f6f68675c42e166ca982a83e804cce14d99196f6a14af574cb0b10166fe353dda3f347a734949efa36592f78c4b07a38 WHIRLPOOL 6913ea8acfcbb16dbaaf5575572aec9f299990c8c270ac62cd1978e8af5690dbde1c6474b0323879c8777724e3ad02e5cccae4aea298550862a5b479a6b1a6c2
-DIST webkitgtk-2.14.1.tar.xz 13415796 SHA256 2e2d76c328de65bed6e0e4f096b2720a366654b27fc1af0830ece90bc4b7ceb5 SHA512 7b39c4f75e2fd8e5e833808597444f495ece70e79dbe49f27e4c6cbc486583954eac66b6b4324db83f2c5c92ef9f9e8f3b2c6c8046d5f326e551aecb989efa28 WHIRLPOOL e1c7db917b9a5db92613771aa98f7e29441a783b5b707c83715720291c68b357b0fc977349b6849e8c6d14b920e009fa45b5e6bf14b86c20f5ace263c33588c7
 DIST webkitgtk-2.14.2.tar.xz 13416388 SHA256 2edbcbd5105046aea55af9671c4de8deedb5b0e3567c618034d440a760675556 SHA512 e1e344660c1aa38f2911aab334581b015bdbd6fa3bef6f1cd67560b86f1b183bf91cafb94bd4783f4660ecad94dc662ec4a342d5bb2420f284150adc21f79beb WHIRLPOOL 708eb9f531ab247418556f21c6d4d73f0c698926017cbb17b1ccf342165631e887bba82e08e77ce4eae401246d401bdc3275485a4796d581f1beb02d74860c31
 DIST webkitgtk-2.4.11.tar.xz 9869100 SHA256 588aea051bfbacced27fdfe0335a957dca839ebe36aa548df39c7bbafdb65bf7 SHA512 2e2cf01a52b8593765a0a3c2d7f0ad306121660019eb402226bd2826c7d4666dab4e91ca6ccbd29abe0ad3993549f256ed1ab88de22e9c8516d5f40a4edd6bfb WHIRLPOOL de86c4abfb22aacbf62163d0398158931c9cf6ab628547d3b30e613f0505d67c85c3200f7db96500e7c2b35f640cdaa7f501346fc13f492c9439dff4056849a3

diff --git a/net-libs/webkit-gtk/webkit-gtk-2.14.1.ebuild b/net-libs/webkit-gtk/webkit-gtk-2.14.1.ebuild
deleted file mode 100644
index 0a5fc10..00000000
--- a/net-libs/webkit-gtk/webkit-gtk-2.14.1.ebuild
+++ /dev/null
@@ -1,289 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=6
-CMAKE_MAKEFILE_GENERATOR="ninja"
-PYTHON_COMPAT=( python2_7 )
-USE_RUBY="ruby20 ruby21 ruby22 ruby23"
-
-inherit check-reqs cmake-utils eutils flag-o-matic gnome2 pax-utils python-any-r1 ruby-single toolchain-funcs versionator virtualx
-
-MY_P="webkitgtk-${PV}"
-DESCRIPTION="Open source web browser engine"
-HOMEPAGE="http://www.webkitgtk.org/"
-SRC_URI="http://www.webkitgtk.org/releases/${MY_P}.tar.xz"
-
-LICENSE="LGPL-2+ BSD"
-SLOT="4/37" # soname version of libwebkit2gtk-4.0
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
-
-IUSE="aqua coverage doc +egl +geolocation gles2 gnome-keyring +gstreamer +introspection +jit libnotify nsplugin +opengl spell wayland +webgl X"
-
-# webgl needs gstreamer, bug #560612
-REQUIRED_USE="
-	geolocation? ( introspection )
-	gles2? ( egl )
-	introspection? ( gstreamer )
-	nsplugin? ( X )
-	webgl? ( ^^ ( gles2 opengl ) )
-	!webgl? ( ?? ( gles2 opengl ) )
-	webgl? ( gstreamer )
-	wayland? ( egl )
-	|| ( aqua wayland X )
-"
-
-# Tests fail to link for inexplicable reasons
-# https://bugs.webkit.org/show_bug.cgi?id=148210
-RESTRICT="test"
-
-# use sqlite, svg by default
-# Aqua support in gtk3 is untested
-# Dependencies found at Source/cmake/OptionsGTK.cmake
-RDEPEND="
-	dev-db/sqlite:3=
-	>=dev-libs/glib-2.36:2
-	dev-libs/hyphen
-	>=dev-libs/icu-3.8.1-r1:=
-	>=dev-libs/libxml2-2.8:2
-	>=dev-libs/libxslt-1.1.7
-	>=media-libs/fontconfig-2.8:1.0
-	>=media-libs/freetype-2.4.2:2
-	>=media-libs/harfbuzz-0.9.18:=[icu(+)]
-	>=media-libs/libpng-1.4:0=
-	media-libs/libwebp:=
-	>=net-libs/gnutls-3
-	>=net-libs/libsoup-2.42:2.4[introspection?]
-	>=x11-libs/cairo-1.10.2:=
-	>=x11-libs/gtk+-3.14:3[introspection?]
-	>=x11-libs/pango-1.30.0
-	virtual/jpeg:0=
-
-	aqua? ( >=x11-libs/gtk+-3.14:3[aqua] )
-	egl? ( media-libs/mesa[egl] )
-	geolocation? ( >=app-misc/geoclue-2.1.5:2.0 )
-	gles2? ( media-libs/mesa[gles2] )
-	gnome-keyring? ( app-crypt/libsecret )
-	gstreamer? (
-		>=media-libs/gstreamer-1.2:1.0
-		>=media-libs/gst-plugins-base-1.2:1.0
-		>=media-libs/gst-plugins-bad-1.8:1.0[opengl?] )
-	introspection? ( >=dev-libs/gobject-introspection-1.32.0:= )
-	libnotify? ( x11-libs/libnotify )
-	nsplugin? ( >=x11-libs/gtk+-2.24.10:2 )
-	opengl? ( virtual/opengl
-		x11-libs/cairo[opengl] )
-	spell? ( >=app-text/enchant-0.22:= )
-	wayland? ( >=x11-libs/gtk+-3.14:3[wayland] )
-	webgl? (
-		x11-libs/cairo[opengl]
-		x11-libs/libXcomposite
-		x11-libs/libXdamage )
-	X? (
-		x11-libs/cairo[X]
-		>=x11-libs/gtk+-3.14:3[X]
-		x11-libs/libX11
-		x11-libs/libXcomposite
-		x11-libs/libXrender
-		x11-libs/libXt )
-"
-
-# paxctl needed for bug #407085
-# Need real bison, not yacc
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	${RUBY_DEPS}
-	>=dev-lang/perl-5.10
-	>=app-accessibility/at-spi2-core-2.5.3
-	>=dev-libs/atk-2.8.0
-	>=dev-util/gtk-doc-am-1.10
-	>=dev-util/gperf-3.0.1
-	>=sys-devel/bison-2.4.3
-	>=sys-devel/flex-2.5.34
-	|| ( >=sys-devel/gcc-4.9 >=sys-devel/clang-3.3 )
-	sys-devel/gettext
-	virtual/pkgconfig
-
-	doc? ( >=dev-util/gtk-doc-1.10 )
-	geolocation? ( dev-util/gdbus-codegen )
-	introspection? ( jit? ( sys-apps/paxctl ) )
-	test? (
-		dev-lang/python:2.7
-		dev-python/pygobject:3[python_targets_python2_7]
-		x11-themes/hicolor-icon-theme
-		jit? ( sys-apps/paxctl ) )
-"
-
-S="${WORKDIR}/${MY_P}"
-
-CHECKREQS_DISK_BUILD="18G" # and even this might not be enough, bug #417307
-
-pkg_pretend() {
-	if [[ ${MERGE_TYPE} != "binary" ]] ; then
-		if is-flagq "-g*" && ! is-flagq "-g*0" ; then
-			einfo "Checking for sufficient disk space to build ${PN} with debugging CFLAGS"
-			check-reqs_pkg_pretend
-		fi
-
-		if ! test-flag-CXX -std=c++11 ; then
-			die "You need at least GCC 4.9.x or Clang >= 3.3 for C++11-specific compiler flags"
-		fi
-
-		if tc-is-gcc && [[ $(gcc-version) < 4.9 ]] ; then
-			die 'The active compiler needs to be gcc 4.9 (or newer)'
-		fi
-	fi
-}
-
-pkg_setup() {
-	if [[ ${MERGE_TYPE} != "binary" ]] && is-flagq "-g*" && ! is-flagq "-g*0" ; then
-		check-reqs_pkg_setup
-	fi
-
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	# https://bugs.gentoo.org/show_bug.cgi?id=555504
-	eapply "${FILESDIR}"/${PN}-2.8.5-fix-ia64-build.patch
-
-	# https://bugs.gentoo.org/show_bug.cgi?id=564352
-	eapply "${FILESDIR}"/${PN}-2.8.5-fix-alpha-build.patch
-
-	# https://bugs.webkit.org/show_bug.cgi?id=148379
-	eapply "${FILESDIR}"/${PN}-2.8.5-webkit2gtkinjectedbundle-j1.patch
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# Respect CC, otherwise fails on prefix #395875
-	tc-export CC
-
-	# Arches without JIT support also need this to really disable it in all places
-	use jit || append-cppflags -DENABLE_JIT=0 -DENABLE_YARR_JIT=0 -DENABLE_ASSEMBLER=0
-
-	# It does not compile on alpha without this in LDFLAGS
-	# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=648761
-	use alpha && append-ldflags "-Wl,--no-relax"
-
-	# ld segfaults on ia64 with LDFLAGS --as-needed, bug #555504
-	use ia64 && append-ldflags "-Wl,--no-as-needed"
-
-	# Sigbuses on SPARC with mcpu and co., bug #???
-	use sparc && filter-flags "-mvis"
-
-	# https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
-	use ppc64 && append-flags "-mminimal-toc"
-
-	# Try to use less memory, bug #469942 (see Fedora .spec for reference)
-	# --no-keep-memory doesn't work on ia64, bug #502492
-	if ! use ia64; then
-		append-ldflags "-Wl,--no-keep-memory"
-	fi
-
-	# We try to use gold when possible for this package
-#	if ! tc-ld-is-gold ; then
-#		append-ldflags "-Wl,--reduce-memory-overheads"
-#	fi
-
-	# older glibc needs this for INTPTR_MAX, bug #533976
-	if has_version "<sys-libs/glibc-2.18" ; then
-		append-cppflags "-D__STDC_LIMIT_MACROS"
-	fi
-
-	# Multiple rendering bugs on youtube, github, etc without this, bug #547224
-	append-flags $(test-flags -fno-strict-aliasing)
-
-	local ruby_interpreter=""
-
-	if has_version "virtual/rubygems[ruby_targets_ruby23]"; then
-		ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby23)"
-	elif has_version "virtual/rubygems[ruby_targets_ruby22]"; then
-		ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby22)"
-	elif has_version "virtual/rubygems[ruby_targets_ruby21]"; then
-		ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby21)"
-	else
-		ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ruby20)"
-	fi
-
-	# TODO: Check Web Audio support
-	# should somehow let user select between them?
-	#
-	# FTL_JIT requires llvm
-	#
-	# opengl needs to be explicetly handled, bug #576634
-
-	local opengl_enabled
-	if use opengl || use gles2; then
-		opengl_enabled=ON
-	else
-		opengl_enabled=OFF
-	fi
-
-	# support for webgl (aka 2d-canvas accelerating)
-	local canvas_enabled
-	if use webgl && ! use gles2 ; then
-		canvas_enabled=ON
-	else
-		canvas_enabled=OFF
-	fi
-
-	local mycmakeargs=(
-		-DENABLE_QUARTZ_TARGET=$(usex aqua)
-		-DENABLE_API_TESTS=$(usex test)
-		-DENABLE_GTKDOC=$(usex doc)
-		-DENABLE_GEOLOCATION=$(usex geolocation)
-		$(cmake-utils_use_find_package gles2 OpenGLES2)
-		-DENABLE_GLES2=$(usex gles2)
-		-DENABLE_CREDENTIAL_STORAGE=$(usex gnome-keyring)
-		-DENABLE_VIDEO=$(usex gstreamer)
-		-DENABLE_WEB_AUDIO=$(usex gstreamer)
-		-DENABLE_INTROSPECTION=$(usex introspection)
-		-DENABLE_JIT=$(usex jit)
-		-DUSE_LIBNOTIFY=$(usex libnotify)
-		-DENABLE_PLUGIN_PROCESS_GTK2=$(usex nsplugin)
-		-DENABLE_SPELLCHECK=$(usex spell)
-		-DENABLE_WAYLAND_TARGET=$(usex wayland)
-		-DENABLE_WEBGL=$(usex webgl)
-		$(cmake-utils_use_find_package egl EGL)
-		$(cmake-utils_use_find_package opengl OpenGL)
-		-DENABLE_X11_TARGET=$(usex X)
-		-DENABLE_OPENGL=${opengl_enabled}
-		-DENABLE_ACCELERATED_2D_CANVAS=${canvas_enabled}
-		-DCMAKE_BUILD_TYPE=Release
-		-DPORT=GTK
-		${ruby_interpreter}
-	)
-
-	# Allow it to use GOLD when possible as it has all the magic to
-	# detect when to use it and using gold for this concrete package has
-	# multiple advantages and is also the upstream default, bug #585788
-#	if tc-ld-is-gold ; then
-#		mycmakeargs+=( -DUSE_LD_GOLD=ON )
-#	else
-#		mycmakeargs+=( -DUSE_LD_GOLD=OFF )
-#	fi
-
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	cmake-utils_src_compile
-}
-
-src_test() {
-	# Prevents test failures on PaX systems
-	use jit && pax-mark m $(list-paxables Programs/*[Tt]ests/*) # Programs/unittests/.libs/test*
-
-	cmake-utils_src_test
-}
-
-src_install() {
-	cmake-utils_src_install
-
-	# Prevents crashes on PaX systems, bug #522808
-	use jit && pax-mark m "${ED}usr/bin/jsc" "${ED}usr/libexec/webkit2gtk-4.0/WebKitWebProcess"
-	pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/WebKitPluginProcess"
-	use nsplugin && pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/WebKitPluginProcess"2
-}