[gentoo-commits] gentoo-x86 commit in net-firewall/fwknop: fwknop-2.6.1.ebuild metadata.xml ChangeLog

[Tom Wijsman (tomwij)]

tomwij      14/04/27 10:50:49

  Added:                fwknop-2.6.1.ebuild metadata.xml ChangeLog
  Log:
  New ebuild for net-firewall/fwknop, a Single Packet Authorization and Port Knocking application; fixes bug #178546, proxied commit for Coacher (itumaykin) who will maintain this package.
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.1                  net-firewall/fwknop/fwknop-2.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/fwknop-2.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/fwknop-2.6.1.ebuild?rev=1.1&content-type=text/plain

Index: fwknop-2.6.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/fwknop-2.6.1.ebuild,v 1.1 2014/04/27 10:50:49 tomwij Exp $

EAPI=5

# does work with python 2.7, doesn't work with python 3.3 on my machine
# more feedback is welcome
PYTHON_COMPAT=( python2_7 )
DISTUTILS_OPTIONAL=1
inherit autotools distutils-r1 eutils systemd

DESCRIPTION="Single Packet Authorization and Port Knocking application"
HOMEPAGE="http://www.cipherdyne.org/fwknop/"
SRC_URI="http://www.cipherdyne.org/${PN}/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="client extras gdbm gpg python server"

RDEPEND="python? ( ${PYTHON_DEPS} )
	gpg? (
		dev-libs/libassuan
		dev-libs/libgpg-error
	)
"
DEPEND="${RDEPEND}
	gdbm? ( sys-libs/gdbm )
	gpg? ( app-crypt/gpgme )
	server? (
		net-libs/libpcap
		net-firewall/iptables
	)
"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

DOCS=( ChangeLog README )

src_prepare() {
	# Remove extra run/ subdir from localstatedir paths
	#
	# fwknopd's default location for digest-cache and pidfile is
	# localstatedir/run/fwknop (see server/fwknopd_common.h).
	# Such files (cache, pidfile) should be placed in /run/fwknop instead.
	# fwknopd's default apparmor policy also assumes that these files are in
	# /run/fwknop, i.e. localstatedir is /var and /var/run is a symlink to /run.
	# Relying on /var/run -> /run symlink is not the best practice.
	# This is why simply binding localstatedir to /var is not enough.
	# Instead we strip hardcoded run/ subdir from localstatedir paths
	# ans set localstatedir to /run below.
	epatch "${FILESDIR}/fwknop-2.6.0-remove-extra-run-from-paths.patch"

	# Install example configs with .example suffix
	if use server; then
		sed -i 's/conf;/conf.example;/g' "${S}"/Makefile.am || die
	fi
	eautoreconf

	use python && distutils-r1_src_prepare
}

src_configure() {
	econf \
		--localstatedir=/run \
		--enable-digest-cache \
		$(use_enable client) \
		$(use_enable !gdbm file-cache) \
		$(use_enable server) \
		$(use_with gpg gpgme)
}

src_compile() {
	default

	if use python; then
		cd "${S}"/python || die
		distutils-r1_src_compile
	fi
}

src_install() {
	default

	if use server; then
		newinitd "${FILESDIR}/fwknopd.init" fwknopd
		newconfd "${FILESDIR}/fwknopd.confd" fwknopd
		systemd_newtmpfilesd "${FILESDIR}/fwknopd.tmpfiles.conf" fwknopd.conf
	fi

	use extras && dodoc "${S}/extras/apparmor/usr.sbin.fwknopd"

	if use python; then
		# Unset DOCS since distutils-r1.eclass interferes
		DOCS=()
		cd "${S}"/python || die
		distutils-r1_src_install
	fi
}



1.1                  net-firewall/fwknop/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>proxy-maintainers</herd>
	<maintainer>
		<email>itumaykin@×××××.com</email>
		<name>Coacher</name>
	</maintainer>
	<use>
		<flag name="client">Build fwknop client</flag>
		<flag name="gdbm">Replace file digest-cache with gdbm</flag>
		<flag name="gpg">Enable GPG support via <pkg>app-crypt/gpgme</pkg></flag>
		<flag name="server">Build fwknopd server</flag>
		<flag name="extras">Install example apparmor policy</flag>
	</use>
</pkgmetadata>



1.1                  net-firewall/fwknop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-firewall/fwknop
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v 1.1 2014/04/27 10:50:49 tomwij Exp $

*fwknop-2.6.1 (27 Apr 2014)

  27 Apr 2014; Tom Wijsman <TomWij@g.o>
  +files/fwknop-2.6.0-remove-extra-run-from-paths.patch, +files/fwknopd.confd,
  +files/fwknopd.init, +files/fwknopd.tmpfiles.conf, +fwknop-2.6.1.ebuild,
  +metadata.xml:
  New ebuild for net-firewall/fwknop, a Single Packet Authorization and Port
  Knocking application; fixes bug #178546, proxied commit for Coacher
  (itumaykin) who will maintain this package.