[gentoo-commits] repo/gentoo:master commit in: dev-python/irc/

[Louis Sautier]

commit:     cb1b5f86d7a4843cd952455bbad0b07d7f3e4221
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  9 08:39:28 2020 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Sep  9 09:35:54 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb1b5f86

dev-python/irc: bump to 19.0.1, add Python 3.9 support

Package-Manager: Portage-3.0.3, Repoman-2.3.23
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 dev-python/irc/Manifest          |  1 +
 dev-python/irc/irc-19.0.1.ebuild | 59 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/irc/Manifest b/dev-python/irc/Manifest
index 55803bbf7c3..4951ea01d1f 100644
--- a/dev-python/irc/Manifest
+++ b/dev-python/irc/Manifest
@@ -1 +1,2 @@
 DIST irc-18.0.0.tar.gz 91529 BLAKE2B 91e7f9fe38b46f836eb902c8ce4ca04706e673a8a9372c743e9b6be3b400e4d84a0d841b72e2b8444e055a69d37b22d48fcf33c7bd51375dbf0dd4a06b3ed5dd SHA512 a424f1261a09246dd2cfd0b717d4fd9bbeab9754d1f480c870c2e131354db85268bd010ec6b7cf2c59a0c32057bb290ef3ffdcb30cca8c0d833e1497bc89f58e
+DIST irc-19.0.1.tar.gz 118227 BLAKE2B 7cafeaee39545ea2fb2257ca2ea89ccb90ed6d6607be27dac6d72cd9fc2e308a7980cc89ff4e1a491e52b071f3b91f6a56f56c9956d35f10a3bac95f214fee10 SHA512 f472c47c3fb54fd012fe16774cf19d43e07cfbc314347b02a280b6bf1d08eda9cbc13d4e3adf3af5f22b31d41e7160c44dbde9479abed01e0b5224f23ec9a0d7

diff --git a/dev-python/irc/irc-19.0.1.ebuild b/dev-python/irc/irc-19.0.1.ebuild
new file mode 100644
index 00000000000..2d780f0ed7a
--- /dev/null
+++ b/dev-python/irc/irc-19.0.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+# [options.entry_points] is present in setup.cfg but it is empty
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/importlib_metadata[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.1[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs '>=dev-python/jaraco-packaging-3.2' \
+	'>=dev-python/rst-linker-1.9'
+
+python_test() {
+	# Override pytest options to skip flake8
+	pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		dodoc -r scripts
+	fi
+	distutils-r1_python_install_all
+}