[gentoo-commits] gentoo-x86 commit in dev-python/pypy-bin: pypy-bin-2.0.2.ebuild pypy-bin-2.0.2-r1.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/03/30 20:57:45

  Modified:             pypy-bin-2.0.2.ebuild ChangeLog
  Added:                pypy-bin-2.0.2-r1.ebuild
  Log:
  Backport the :0 slot switch to pypy-2.0.2 since we have binpackages for this version. Update deps.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.8                  dev-python/pypy-bin/pypy-bin-2.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2.ebuild?r1=1.7&r2=1.8

Index: pypy-bin-2.0.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- pypy-bin-2.0.2.ebuild	21 Feb 2014 21:25:51 -0000	1.7
+++ pypy-bin-2.0.2.ebuild	30 Mar 2014 20:57:45 -0000	1.8
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2.ebuild,v 1.7 2014/02/21 21:25:51 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2.ebuild,v 1.8 2014/03/30 20:57:45 mgorny Exp $
 
 EAPI=5
 
@@ -55,22 +55,19 @@
 RDEPEND="
 	~app-arch/bzip2-1.0.6
 	~dev-libs/expat-2.1.0
-	|| ( ~dev-libs/libffi-3.0.13
-		~dev-libs/libffi-3.0.12
-		~dev-libs/libffi-3.0.11 )
-	|| ( ~dev-libs/openssl-1.0.1f
-		~dev-libs/openssl-1.0.1e
-		~dev-libs/openssl-1.0.1d
-		~dev-libs/openssl-1.0.1c )
-	|| ( ~sys-libs/glibc-2.17
-		~sys-libs/glibc-2.16.0
-		~sys-libs/glibc-2.15 )
+	( <dev-libs/libffi-3.0.14
+		>=dev-libs/libffi-3.0.11 )
+	( <dev-libs/openssl-1.0.1g
+		>=dev-libs/openssl-1.0.1c )
+	( <sys-libs/glibc-2.20
+		>=sys-libs/glibc-2.15 )
 	~sys-libs/ncurses-5.9
-	|| ( ~sys-libs/zlib-1.2.8
-		~sys-libs/zlib-1.2.7 )
+	( <sys-libs/zlib-1.2.9
+		>=sys-libs/zlib-1.2.7 )
 	sqlite? ( dev-db/sqlite:3 )
 	!dev-python/pypy:${SLOT}"
-DEPEND="doc? ( dev-python/sphinx )
+DEPEND="app-arch/xz-utils
+	doc? ( dev-python/sphinx )
 	test? ( ${RDEPEND} )"
 PDEPEND="app-admin/python-updater"
 



1.9                  dev-python/pypy-bin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	21 Feb 2014 21:25:51 -0000	1.8
+++ ChangeLog	30 Mar 2014 20:57:45 -0000	1.9
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/pypy-bin
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/ChangeLog,v 1.8 2014/02/21 21:25:51 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/ChangeLog,v 1.9 2014/03/30 20:57:45 mgorny Exp $
+
+*pypy-bin-2.0.2-r1 (30 Mar 2014)
+
+  30 Mar 2014; Michał Górny <mgorny@g.o> +pypy-bin-2.0.2-r1.ebuild,
+  pypy-bin-2.0.2.ebuild:
+  Backport the :0 slot switch to pypy-2.0.2 since we have binpackages for this
+  version. Update deps.
 
   21 Feb 2014; Michał Górny <mgorny@g.o> pypy-bin-2.0.2.ebuild:
   Bump openssl dep since the old version was cleaned.



1.1                  dev-python/pypy-bin/pypy-bin-2.0.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: pypy-bin-2.0.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy-bin/pypy-bin-2.0.2-r1.ebuild,v 1.1 2014/03/30 20:57:45 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 pypy2_0 )
inherit eutils multilib pax-utils python-any-r1 versionator

BINHOST="http://dev.gentoo.org/~mgorny/dist/${PN}"

DESCRIPTION="A fast, compliant alternative implementation of the Python language (binary package)"
HOMEPAGE="http://pypy.org/"
SRC_URI="mirror://bitbucket/pypy/pypy/downloads/pypy-${PV}-src.tar.bz2
	amd64? (
		jit? ( shadowstack? (
			${BINHOST}/${P}-amd64+bzip2+jit+ncurses+shadowstack.tar.xz
		) )
		jit? ( !shadowstack? (
			${BINHOST}/${P}-amd64+bzip2+jit+ncurses.tar.xz
		) )
		!jit? ( !shadowstack? (
			${BINHOST}/${P}-amd64+bzip2+ncurses.tar.xz
		) )
	)
	x86? (
		sse2? (
			jit? ( shadowstack? (
				${BINHOST}/${P}-x86+bzip2+jit+ncurses+shadowstack+sse2.tar.xz
			) )
			jit? ( !shadowstack? (
				${BINHOST}/${P}-x86+bzip2+jit+ncurses+sse2.tar.xz
			) )
			!jit? ( !shadowstack? (
				${BINHOST}/${P}-x86+bzip2+ncurses+sse2.tar.xz
			) )
		)
		!sse2? (
			!jit? ( !shadowstack? (
				${BINHOST}/${P}-x86+bzip2+ncurses.tar.xz
			) )
		)
	)"

# Supported variants
REQUIRED_USE="!jit? ( !shadowstack )
	x86? ( !sse2? ( !jit !shadowstack ) )"

LICENSE="MIT"
SLOT="0/$(get_version_component_range 1-2 ${PV})"
KEYWORDS="~amd64 ~x86"
IUSE="doc +jit shadowstack sqlite sse2 test"

# yep, world would be easier if people started filling subslots...
RDEPEND="
	~app-arch/bzip2-1.0.6
	~dev-libs/expat-2.1.0
	( <dev-libs/libffi-3.0.14
		>=dev-libs/libffi-3.0.11 )
	( <dev-libs/openssl-1.0.1g
		>=dev-libs/openssl-1.0.1c )
	( <sys-libs/glibc-2.20
		>=sys-libs/glibc-2.15 )
	~sys-libs/ncurses-5.9
	( <sys-libs/zlib-1.2.9
		>=sys-libs/zlib-1.2.7 )
	sqlite? ( dev-db/sqlite:3 )
	!dev-python/pypy:${SLOT}"
DEPEND="app-arch/xz-utils
	doc? ( dev-python/sphinx )
	test? ( ${RDEPEND} )"
PDEPEND="app-admin/python-updater"

S=${WORKDIR}/pypy-${PV}-src

pkg_setup() {
	use doc && python-any-r1_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}/1.9-scripts-location.patch"
	epatch "${FILESDIR}/1.9-distutils.unixccompiler.UnixCCompiler.runtime_library_dir_option.patch"
	epatch "${FILESDIR}/2.0.2-distutils-fix_handling_of_executables_and_flags.patch"

	epatch_user
}

src_compile() {
	# Tadaam! PyPy compiled!
	mv "${WORKDIR}"/${P}*/pypy-c . || die
	mv "${WORKDIR}"/${P}*/include/*.h include/ || die
	mv pypy/module/cpyext/include/*.h include/ || die

	use doc && emake -C pypy/doc/ html
	#needed even without jit :( also needed in both compile and install phases
	pax-mark m pypy-c
}

src_test() {
	# (unset)
	local -x PYTHONDONTWRITEBYTECODE

	./pypy-c ./pypy/test_all.py --pypy=./pypy-c lib-python || die
}

src_install() {
	einfo "Installing PyPy ..."
	insinto "/usr/$(get_libdir)/pypy"
	doins -r include lib_pypy lib-python pypy-c
	fperms a+x ${INSDESTTREE}/pypy-c
	#needed even without jit :(
	pax-mark m "${ED%/}${INSDESTTREE}/pypy-c"
	dosym ../$(get_libdir)/pypy/pypy-c /usr/bin/pypy
	dodoc README.rst

	if ! use sqlite; then
		rm -r "${ED%/}${INSDESTTREE}"/lib-python/*2.7/sqlite3 || die
		rm "${ED%/}${INSDESTTREE}"/lib_pypy/_sqlite3.py || die
	fi

	# Install docs
	use doc && dohtml -r pypy/doc/_build/html/

	einfo "Generating caches and byte-compiling ..."

	python_export pypy EPYTHON PYTHON PYTHON_SITEDIR
	local PYTHON=${ED%/}${INSDESTTREE}/pypy-c

	echo "EPYTHON='${EPYTHON}'" > epython.py
	python_domodule epython.py

	# Note: call portage helpers before this line.
	# PYTHONPATH confuses them and will result in random failures.

	local -x PYTHONPATH="${ED%/}${INSDESTTREE}/lib_pypy:${ED%/}${INSDESTTREE}/lib-python/2.7"

	# Generate Grammar and PatternGrammar pickles.
	"${PYTHON}" -c "import lib2to3.pygram, lib2to3.patcomp; lib2to3.patcomp.PatternCompiler()" \
		|| die "Generation of Grammar and PatternGrammar pickles failed"

	# Generate cffi cache
	"${PYTHON}" -c "import _curses" || die "Failed to import _curses"
	if use sqlite; then
		"${PYTHON}" -c "import _sqlite3" || die "Failed to import _sqlite3"
	fi

	# compile the installed modules
	python_optimize "${ED%/}${INSDESTTREE}"
}