[gentoo-commits] proj/gnome:master commit in: gnome-extra/gnome-color-manager/

[Sobhan Mohammadpour]

commit:     9da487c41d90b6cb8bc544fdbc9bc70cbb81a541
Author:     Sobhan Mohammadpour <sobhan <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  9 14:38:46 2018 +0000
Commit:     Sobhan Mohammadpour <sobhan <AT> gentoo <DOT> org>
CommitDate: Fri Feb  9 14:38:46 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=9da487c4

gnome-extra/gnome-color-manager: bump

Package-Manager: Portage-2.3.23, Repoman-2.3.6
Manifest-Sign-Key: 0x7DF238CF0AA182E1

 .../gnome-color-manager-3.26.0.ebuild              | 64 ++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/gnome-extra/gnome-color-manager/gnome-color-manager-3.26.0.ebuild b/gnome-extra/gnome-color-manager/gnome-color-manager-3.26.0.ebuild
new file mode 100644
index 00000000..f317d6a3
--- /dev/null
+++ b/gnome-extra/gnome-color-manager/gnome-color-manager-3.26.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome-meson virtualx
+
+DESCRIPTION="Color profile manager for the GNOME desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-color-manager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="packagekit raw"
+# FIXME: libvte atomagic
+# Need gtk+-3.3.8 for https://bugzilla.gnome.org/show_bug.cgi?id=673331
+RDEPEND="
+	>=dev-libs/glib-2.31.10:2
+	>=media-libs/lcms-2.2:2
+	>=media-libs/libcanberra-0.10[gtk3]
+	media-libs/libexif
+	media-libs/tiff:0=
+
+	>=x11-libs/gtk+-3.3.8:3
+	>=x11-libs/vte-0.25.1:2.91
+	>=x11-misc/colord-1.3.1:0=
+	>=x11-libs/colord-gtk-0.1.20
+
+	x11-libs/vte:2.91
+
+	packagekit? ( app-admin/packagekit-base )
+	raw? ( media-gfx/exiv2:0= )
+"
+# docbook-sgml-{utils,dtd:4.1} needed to generate man pages
+DEPEND="${RDEPEND}
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# Always enable tests since they are check_PROGRAMS anyway
+	# appstream does not want to be relax by default !
+	gnome-meson_src_configure \
+		-Denable-tests=true \
+		$(meson_use raw enable-exiv) \
+		$(meson_use packagekit enable-packagekit)
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	gnome-meson_pkg_postinst
+
+	if ! has_version media-gfx/argyllcms ; then
+		elog "If you want to do display or scanner calibration, you will need to"
+		elog "install media-gfx/argyllcms"
+	fi
+}