[gentoo-commits] proj/kde:master commit in: kde-apps/lokalize/

[Andreas Sturmlechner]

commit:     4acd90b9963d4edff8c213cc99cd3e395a47e883
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Oct  6 07:06:12 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Oct  6 07:06:12 2020 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=4acd90b9

kde-apps/lokalize: 20.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/lokalize/lokalize-20.08.2.ebuild | 74 +++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/kde-apps/lokalize/lokalize-20.08.2.ebuild b/kde-apps/lokalize/lokalize-20.08.2.ebuild
new file mode 100644
index 0000000000..75ad7f645d
--- /dev/null
+++ b/kde-apps/lokalize/lokalize-20.08.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+PYTHON_COMPAT=( python3_{7,8} )
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit python-single-r1 ecm kde.org optfeature
+
+DESCRIPTION="KDE Applications 5 translation tool"
+HOMEPAGE="https://kde.org/applications/office/org.kde.lokalize
+https://l10n.kde.org/tools/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT+=" test" # tests are broken, bug 739734
+
+DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.2.8:=
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kross-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/translate-toolkit[${PYTHON_MULTI_USEDEP}]
+	')
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_install() {
+	ecm_src_install
+	python_fix_shebang "${ED}/usr/share/${PN}"
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "Autofetch kde.org translations in new project wizard" dev-vcs/subversion
+		optfeature "msgmerge tool" "kde-apps/kross-interpreters:${SLOT}[python]"
+		optfeature "Spell and grammar checking" app-text/languagetool
+	fi
+	ecm_pkg_postinst
+}