[gentoo-commits] gentoo-x86 commit in app-arch/libarchive: ChangeLog libarchive-2.8.5.ebuild

[Brian Harring (ferringb)]

ferringb    11/09/06 03:17:49

  Modified:             ChangeLog
  Added:                libarchive-2.8.5.ebuild
  Log:
  verbump to 2.8.5
  
  (Portage version: 2.1.10.6/cvs/Linux x86_64)

Revision  Changes    Path
1.96                 app-arch/libarchive/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/libarchive/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	7 May 2011 16:51:11 -0000	1.95
+++ ChangeLog	6 Sep 2011 03:17:49 -0000	1.96
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/libarchive
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.95 2011/05/07 16:51:11 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.96 2011/09/06 03:17:49 ferringb Exp $
+
+*libarchive-2.8.5 (06 Sep 2011)
+
+  06 Sep 2011; Brian Harring <ferringb@g.o> +libarchive-2.8.5.ebuild:
+  bugfix release primarily
 
   07 May 2011; Raúl Porcel <armin76@g.o> libarchive-2.8.4-r1.ebuild:
   ia64/sh/sparc stable wrt #357771



1.1                  app-arch/libarchive/libarchive-2.8.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/libarchive/libarchive-2.8.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/libarchive/libarchive-2.8.5.ebuild?rev=1.1&content-type=text/plain

Index: libarchive-2.8.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.8.5.ebuild,v 1.1 2011/09/06 03:17:49 ferringb Exp $

EAPI="2"

inherit toolchain-funcs flag-o-matic

DESCRIPTION="BSD tar command"
HOMEPAGE="http://code.google.com/p/libarchive/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz
	http://people.freebsd.org/~kientzle/libarchive/src/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="static static-libs acl xattr kernel_linux +bzip2 +lzma +zlib expat"

COMPRESS_LIBS_DEPEND="lzma? ( app-arch/xz-utils )
		bzip2? ( app-arch/bzip2 )
		zlib? ( sys-libs/zlib )"

RDEPEND="!dev-libs/libarchive
	dev-libs/openssl
	!expat? ( dev-libs/libxml2 )
	expat? ( dev-libs/expat )
	acl? ( virtual/acl )
	xattr? ( kernel_linux? ( sys-apps/attr ) )
	!static? ( ${COMPRESS_LIBS_DEPEND} )"
DEPEND="${RDEPEND}
	${COMPRESS_LIBS_DEPEND}
	kernel_linux? ( sys-fs/e2fsprogs
		virtual/os-headers )"

src_configure() {
	local myconf

	if ! use static ; then
		myconf="--enable-bsdtar=shared --enable-bsdcpio=shared"
	fi

	# force static libs for static binaries
	if use static && ! use static-libs; then
		myconf="${myconf} --enable-static"
	fi

	# Check for need of this in 2.7.1 and later, on 2.7.0, -Werror was
	# added to the final release, but since it's done in the
	# Makefile.am we can just work it around this way.
	append-flags -Wno-error

	# We disable lzmadec because we support the newer liblzma from xz-utils
	# and not liblzmadec with this version.
	econf --bindir=/bin \
		--enable-bsdtar --enable-bsdcpio \
		$(use_enable acl) $(use_enable xattr) \
		$(use_with zlib) \
		$(use_with bzip2 bz2lib) $(use_with lzma) \
		$(use_enable static-libs static) \
		$(use_with expat expat) \
		$(use_with !expat xml2) \
		--without-lzmadec \
		${myconf} \
		--disable-dependency-tracking
}

src_test() {
	# Replace the default src_test so that it builds tests in parallel
	emake check || die "tests failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."

	# remove useless .a and .la files (only for non static compilation)
	use static-libs || find "${D}" \( -name '*.a' -or -name '*.la' \) -delete

	# Create tar symlink for FreeBSD
	if [[ ${CHOST} == *-freebsd* ]]; then
		dosym bsdtar /bin/tar
		dosym bsdtar.1 /usr/share/man/man1/tar.1
		# We may wish to switch to symlink bsdcpio to cpio too one day
	fi

	dodoc NEWS README
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
	gen_usr_ldscript libarchive.so
}