[gentoo-commits] gentoo-x86 commit in sys-cluster/moosefs: moosefs-1.6.20.ebuild ChangeLog metadata.xml

[Alexys Jacob (ultrabug)]

ultrabug    11/07/05 07:45:36

  Added:                moosefs-1.6.20.ebuild ChangeLog metadata.xml
  Log:
  New ebuild sys-cluster/moosefs, related to bug #338004.
  
  (Portage version: 2.1.10.3/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-cluster/moosefs/moosefs-1.6.20.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/moosefs-1.6.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/moosefs-1.6.20.ebuild?rev=1.1&content-type=text/plain

Index: moosefs-1.6.20.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/moosefs/moosefs-1.6.20.ebuild,v 1.1 2011/07/05 07:45:36 ultrabug Exp $

EAPI=4

inherit eutils

MY_P="mfs-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="A filesystem for highly reliable petabyte storage"
HOMEPAGE="http://www.moosefs.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cgi +fuse static-libs"

RDEPEND="
	cgi? ( dev-lang/python )
	fuse? ( >=sys-fs/fuse-2.6 )"
DEPEND="${RDEPEND}"

pkg_setup() {
	enewgroup mfs
	enewuser mfs -1 -1 -1 mfs
}

src_prepare() {
	# rename dist config files
	sed -i 's@\.cfg\.dist@\.cfg@g' mfsdata/Makefile.in || die
}

src_configure() {
	local myopts=""
	use fuse || myopts="--disable-mfsmount"
	econf \
		--sysconfdir=/etc/mfs \
		--with-default-user=mfs \
		--with-default-group=mfs \
		$(use_enable cgi mfscgi) \
		$(use_enable cgi mfscgiserv) \
		$(use_enable static-libs static) \
		${myopts}
}

src_install() {
	emake DESTDIR="${D}" install

	newinitd "${FILESDIR}/mfs.initd" mfs
	newconfd "${FILESDIR}/mfs.confd" mfs

	chown -R mfs:mfs "${D}/var/lib/mfs" || die
	chmod 750 "${D}/var/lib/mfs" || die
}



1.1                  sys-cluster/moosefs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-cluster/moosefs
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/moosefs/ChangeLog,v 1.1 2011/07/05 07:45:36 ultrabug Exp $

*moosefs-1.6.20 (05 Jul 2011)

  05 Jul 2011; Ultrabug <ultrabug@g.o> +moosefs-1.6.20.ebuild,
  +files/mfs.confd, +files/mfs.initd, +metadata.xml:
  Initial import. Thanks to Mike Kazantsev for his initial work on bug #338004.




1.1                  sys-cluster/moosefs/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/moosefs/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>cluster</herd>
	<longdescription>MooseFS is a fault tolerant, network distributed file system.
	It spreads data over several physical servers which are visible to the user as one resource.
	For standard file operations MooseFS acts as other Unix-alike file systems
	</longdescription>
	<use>
		<flag name="cgi">Install CGI server and scripts.</flag>
		<flag name="fuse">Install the mfsmount utility.</flag>
	</use>
</pkgmetadata>