[gentoo-commits] gentoo-x86 commit in dev-util/ctags: ChangeLog ctags-5.8-r1.ebuild

[Tim Harder (radhermit)]

radhermit    14/09/26 20:11:29

  Modified:             ChangeLog
  Added:                ctags-5.8-r1.ebuild
  Log:
  Make app-admin/eselect-ctags an rdep (bug #519834 by Nick Bowler).
  
  (Portage version: 2.2.13/cvs/Linux x86_64, signed Manifest commit with key 4F064CA3)

Revision  Changes    Path
1.86                 dev-util/ctags/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ctags/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ctags/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ctags/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/ctags/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	6 Jun 2014 05:59:37 -0000	1.85
+++ ChangeLog	26 Sep 2014 20:11:29 -0000	1.86
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/ctags
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/ctags/ChangeLog,v 1.85 2014/06/06 05:59:37 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/ctags/ChangeLog,v 1.86 2014/09/26 20:11:29 radhermit Exp $
+
+*ctags-5.8-r1 (26 Sep 2014)
+
+  26 Sep 2014; Tim Harder <radhermit@g.o> +ctags-5.8-r1.ebuild:
+  Make app-admin/eselect-ctags an rdep (bug #519834 by Nick Bowler).
 
   06 Jun 2014; Mike Frysinger <vapier@g.o> ctags-5.8.ebuild:
   Add arm64 love.



1.1                  dev-util/ctags/ctags-5.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ctags/ctags-5.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/ctags/ctags-5.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: ctags-5.8-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/ctags/ctags-5.8-r1.ebuild,v 1.1 2014/09/26 20:11:29 radhermit Exp $

EAPI="5"

inherit eutils

DESCRIPTION="Exuberant Ctags creates tags files for code browsing in editors"
HOMEPAGE="http://ctags.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	ada? ( mirror://sourceforge/gnuada/ctags-ada-mode-4.3.11.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="ada"

RDEPEND="app-admin/eselect-ctags"

src_prepare() {
	epatch "${FILESDIR}/${PN}-5.6-ebuilds.patch"
	# Upstream fix for python variables starting with def
	epatch "${FILESDIR}/${P}-python-vars-starting-with-def.patch"

	# Bug #273697
	epatch "${FILESDIR}/${P}-f95-pointers.patch"

	# enabling Ada support
	if use ada ; then
		cp "${WORKDIR}/${PN}-ada-mode-4.3.11/ada.c" "${S}" || die
		epatch "${FILESDIR}/${P}-ada.patch"
	fi
}

src_configure() {
	econf \
		--with-posix-regex \
		--without-readlib \
		--disable-etags \
		--enable-tmpdir=/tmp
}

src_install() {
	emake prefix="${D}"/usr mandir="${D}"/usr/share/man install

	# namepace collision with X/Emacs-provided /usr/bin/ctags -- we
	# rename ctags to exuberant-ctags (Mandrake does this also).
	mv "${D}"/usr/bin/{ctags,exuberant-ctags} || die
	mv "${D}"/usr/share/man/man1/{ctags,exuberant-ctags}.1 || die

	dodoc FAQ NEWS README
	dohtml EXTENDING.html ctags.html
}

pkg_postinst() {
	eselect ctags update
	elog "You can set the version to be started by /usr/bin/ctags through"
	elog "the ctags eselect module. \"man ctags.eselect\" for details."
}

pkg_postrm() {
	eselect ctags update
}