[gentoo-commits] gentoo-x86 commit in dev-python/bpython: bpython-0.13.2.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     15/01/30 03:31:37

  Modified:             ChangeLog
  Added:                bpython-0.13.2.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.15/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.46                 dev-python/bpython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bpython/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bpython/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bpython/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/bpython/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	26 Jan 2015 13:18:53 -0000	1.45
+++ ChangeLog	30 Jan 2015 03:31:37 -0000	1.46
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/bpython
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/bpython/ChangeLog,v 1.45 2015/01/26 13:18:53 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/bpython/ChangeLog,v 1.46 2015/01/30 03:31:37 patrick Exp $
+
+*bpython-0.13.2 (30 Jan 2015)
+
+  30 Jan 2015; Patrick Lauer <patrick@g.o> +bpython-0.13.2.ebuild:
+  Bump
 
   26 Jan 2015; Manuel Rüger <mrueg@g.o> metadata.xml:
   Drop unused USE description.



1.1                  dev-python/bpython/bpython-0.13.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bpython/bpython-0.13.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/bpython/bpython-0.13.2.ebuild?rev=1.1&content-type=text/plain

Index: bpython-0.13.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/bpython/bpython-0.13.2.ebuild,v 1.1 2015/01/30 03:31:37 patrick Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
PYTHON_REQ_USE="ncurses"

inherit distutils-r1

DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
HOMEPAGE="http://www.bpython-interpreter.org/ https://bitbucket.org/bobf/bpython/ http://pypi.python.org/pypi/bpython"
SRC_URI="http://www.bpython-interpreter.org/releases/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc gtk test"

RDEPEND="dev-python/pygments[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	gtk? ( dev-python/pygobject:2[$(python_gen_usedep python2_7)]
		dev-python/pygtk[$(python_gen_usedep python2_7)] )
	dev-python/urwid[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( dev-python/mock[${PYTHON_USEDEP}] )"

DOCS=( AUTHORS  CHANGELOG  TODO sample-config sample.theme light.theme )

PATCHES=( "${FILESDIR}"/${PN}-desktop.patch )

# Req'd for clean build by each impl
DISTUTILS_IN_SOURCE_BUILD=1

python_compile_all() {
	if use doc; then
		sphinx-build -b html -c doc/sphinx/source/ \
			doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
	fi
}

python_install() {
	distutils-r1_python_install
	if ! use gtk; then
		rm -f "${D}"usr/bin/bpython-gtk*
		# delete_unneeded_modules() {
		rm -f "${D}$(python_get_sitedir)/bpython/gtk_.py"
	fi
}

python_test() {
	pushd build/lib > /dev/null
	# https://bitbucket.org/bobf/bpython/issue/289/test-failures-in-latest-release-py27-py33
	sed -e s':test_enter:_&:' -i bpython/test/test_repl.py || die

	"${PYTHON}" -m unittest discover || die
	popd > /dev/null
}

python_install_all() {
	use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
	distutils-r1_python_install_all
}