[gentoo-commits] repo/gentoo:master commit in: dev-libs/totem-pl-parser/

[Gilles Dartiguelongue]

commit:     c319be0d90bbb18ca9cb342c23c7825f915b6acb
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 20 22:28:30 2015 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Mon Dec 21 07:11:56 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c319be0d

dev-libs/totem-pl-parser: version bump to 3.10.6

Package-Manager: portage-2.2.26

 dev-libs/totem-pl-parser/Manifest                  |  1 +
 .../totem-pl-parser/totem-pl-parser-3.10.6.ebuild  | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-libs/totem-pl-parser/Manifest b/dev-libs/totem-pl-parser/Manifest
index 05ecc42..ae676bc 100644
--- a/dev-libs/totem-pl-parser/Manifest
+++ b/dev-libs/totem-pl-parser/Manifest
@@ -1 +1,2 @@
 DIST totem-pl-parser-3.10.5.tar.xz 1594516 SHA256 a746580f61b678029dadaa824a6923445afd944d12c40c5fccb27159799c8137 SHA512 d3b29b8bd265e4e8df2820b309bf78f58faec3ee4314b0453f11a0db754ed3b6c2b223e697498925810df660a89d5d6275959b7104f632054b5984f7d9aad553 WHIRLPOOL 06e38e67212764fca629b592d7dc5c4dfa222ac61076fd73434721f3dd78d8da5f6a716085bccf65e50512aabf5d92ad3d04797ab87275dc4e4ee14df4699964
+DIST totem-pl-parser-3.10.6.tar.xz 1606636 SHA256 98a5d9bed1b1c012aeb2692ded2fd49399593f70f297f43e01fc1c5e13576757 SHA512 366de6ea11eb7ad80de9832eecd814fa3868fb9e3149f314f7056861eff1b6f6943b009b637145984d33f51fddfcb93ec2bd9103b6fcb68732cddcc77fbc4721 WHIRLPOOL 02d5ca378828b41b2bbc8750c15c70bebbeef7283a92e1bca8265623ff276091cddf0acc9740ec7af797a03bbbf1036ad14079f28b1527799838c0cd719e1bd6

diff --git a/dev-libs/totem-pl-parser/totem-pl-parser-3.10.6.ebuild b/dev-libs/totem-pl-parser/totem-pl-parser-3.10.6.ebuild
new file mode 100644
index 0000000..c30f438
--- /dev/null
+++ b/dev-libs/totem-pl-parser/totem-pl-parser-3.10.6.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="Playlist parsing library"
+HOMEPAGE="https://developer.gnome.org/totem-pl-parser/stable/"
+
+LICENSE="LGPL-2+"
+SLOT="0/18"
+IUSE="archive crypt +introspection +quvi test"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+RDEPEND="
+	>=dev-libs/glib-2.31:2
+	dev-libs/gmime:2.6
+	>=net-libs/libsoup-2.43:2.4
+	archive? ( >=app-arch/libarchive-3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+	quvi? ( >=media-libs/libquvi-0.9.1:0= )
+"
+DEPEND="${RDEPEND}
+	!<media-video/totem-2.21
+	>=dev-util/intltool-0.35
+	>=dev-util/gtk-doc-am-1.14
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	test? (
+		gnome-base/gvfs[http]
+		sys-apps/dbus )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+#	>=gnome-base/gnome-common-3.6
+
+src_prepare() {
+	# Disable tests requiring network access, bug #346127
+	# 3rd test fails on upgrade, not once installed
+	sed -e 's:\(g_test_add_func.*/parser/resolution.*\):/*\1*/:' \
+		-e 's:\(g_test_add_func.*/parser/parsing/itms_link.*\):/*\1*/:' \
+		-e 's:\(g_test_add_func.*/parser/parsability.*\):/*\1/:'\
+		-i plparse/tests/parser.c || die "sed failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable archive libarchive) \
+		$(use_enable crypt libgcrypt) \
+		$(use_enable quvi) \
+		$(use_enable introspection)
+}
+
+src_test() {
+	# This is required as told by upstream in bgo#629542
+	GVFS_DISABLE_FUSE=1 dbus-run-session emake check || die "emake check failed"
+}