[gentoo-commits] repo/gentoo:master commit in: games-emulation/dolphin/files/, games-emulation/dolphin/

[Michał Górny]

commit:     aef1e63af94bd8da749aaef6ad6baf04c683622d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  5 05:31:20 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Sep  5 05:31:37 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aef1e63a

games-emulation/dolphin: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 games-emulation/dolphin/Manifest                   |   1 -
 .../dolphin/dolphin-5.0_p20210506-r3.ebuild        | 196 ---------------------
 .../dolphin/files/dolphin-5.0_p20210506-musl.patch |  24 ---
 3 files changed, 221 deletions(-)

diff --git a/games-emulation/dolphin/Manifest b/games-emulation/dolphin/Manifest
index eaf5b6495ec4..a50d52217ba3 100644
--- a/games-emulation/dolphin/Manifest
+++ b/games-emulation/dolphin/Manifest
@@ -1,3 +1,2 @@
-DIST dolphin-5.0_p20210506.tar.gz 42098693 BLAKE2B bb9e5b5eb344bd944753c0198d5835109399fdfae46e6858833e5f279ff1979d39e0c512bedb96a91a1241fff525c6f945d16ce1a6b6cc22798490d73b853862 SHA512 5d23e9356995011a0e7b07622d58c8dddc5134a4ec83b3d9343b9eca8d0d2c200ea8c9a299c6aa2550ca74d8e28e258531368f7c167fe620053eb2a0f73b1f2f
 DIST dolphin-5.0_p20220520.tar.gz 34880474 BLAKE2B 925cddfe8a5d6febced5721bea6ced7c8d2855619f74ca8940b95dc78ea523b4a1083b9ef6efe3561d833b8e9ecb742cb2adf5a1864c06b629b3ecd9e92cc871 SHA512 4993cb10061b142f6627c96493885a5f9d88857d8949c2e8e8d5df5ba6e19b4f98d199da5e641d3d61294884e1cbbe8191bc5b4445c60bf80723046b2524aad5
 DIST mgba-40d4c430fc36caeb7ea32fd39624947ed487d2f2.tar.gz 12921593 BLAKE2B 8c5cf7b9b53f897f6248ad6bc51efafaa8a9d5df137d42d30f4b042b6d1527049644595938626c8cae1385d329bc45bf42db8dcc4424b963a3899e0df53246eb SHA512 26d7b60cbc7415652bb9ca2a42ccd532856867db57bf6dd91d8204551970109b6b9f4a96c42d643ea96b9d071d6aec924d3c1bb79c251c95183b7fb8536456c9

diff --git a/games-emulation/dolphin/dolphin-5.0_p20210506-r3.ebuild b/games-emulation/dolphin/dolphin-5.0_p20210506-r3.ebuild
deleted file mode 100644
index 6ff4a8dd29b9..000000000000
--- a/games-emulation/dolphin/dolphin-5.0_p20210506-r3.ebuild
+++ /dev/null
@@ -1,196 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake desktop xdg-utils pax-utils
-
-if [[ ${PV} == *9999 ]]
-then
-	EGIT_REPO_URI="https://github.com/dolphin-emu/dolphin"
-	inherit git-r3
-else
-	EGIT_COMMIT=eb5cd9be78c76b9ccbab9e5fbd1721ef6876cd68
-	SRC_URI="
-		https://github.com/dolphin-emu/dolphin/archive/${EGIT_COMMIT}.tar.gz
-			-> ${P}.tar.gz"
-	S=${WORKDIR}/${PN}-${EGIT_COMMIT}
-	KEYWORDS="amd64 ~arm64"
-fi
-
-DESCRIPTION="Gamecube and Wii game emulator"
-HOMEPAGE="https://dolphin-emu.org/"
-
-LICENSE="GPL-2+ Apache-2.0 BSD BSD-2 ISC LGPL-2.1+ MIT ZLIB"
-SLOT="0"
-IUSE="alsa bluetooth discord-presence doc +evdev ffmpeg +gui log
-	profile pulseaudio systemd upnp vulkan"
-
-RDEPEND="
-	dev-libs/hidapi:0=
-	<dev-libs/libfmt-8.1:0=
-	dev-libs/lzo:2=
-	dev-libs/pugixml:0=
-	media-libs/libpng:0=
-	media-libs/libsfml
-	media-libs/mesa[egl(+)]
-	net-libs/enet:1.3
-	net-libs/mbedtls:0=
-	net-misc/curl:0=
-	sys-libs/readline:0=
-	sys-libs/zlib:0=
-	x11-libs/libXext
-	x11-libs/libXi
-	x11-libs/libXrandr
-	virtual/libusb:1
-	virtual/opengl
-	alsa? ( media-libs/alsa-lib )
-	bluetooth? ( net-wireless/bluez )
-	evdev? (
-		dev-libs/libevdev
-		virtual/udev
-	)
-	ffmpeg? ( media-video/ffmpeg:= )
-	gui? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-	)
-	profile? ( dev-util/oprofile )
-	pulseaudio? ( media-sound/pulseaudio )
-	systemd? ( sys-apps/systemd:0= )
-	upnp? ( net-libs/miniupnpc )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-# vulkan-loader required for vulkan backend which can be selected
-# at runtime.
-RDEPEND="${RDEPEND}
-	vulkan? ( media-libs/vulkan-loader )"
-
-PATCHES=("${FILESDIR}"/${P}-musl.patch)
-
-# [directory]=license
-declare -A KEEP_BUNDLED=(
-	[Bochs_disasm]=LGPL-2.1+
-	[FreeSurround]=GPL-2+
-
-	# vulkan's API is not backwards-compatible:
-	# new release dropped VK_PRESENT_MODE_RANGE_SIZE_KHR
-	# but dolphin still relies on it, bug #729832
-	[Vulkan]=Apache-2.0
-
-	[cpp-optparse]=MIT
-	# no support for for using system library
-	[glslang]=BSD
-	[imgui]=MIT
-
-	# not packaged, tiny header library
-	[rangeset]=ZLIB
-
-	# FIXME: xxhash can't be found by cmake
-	[xxhash]=BSD-2
-	# no support for for using system library
-	[minizip]=ZLIB
-	# soundtouch uses shorts, not floats
-	[soundtouch]=LGPL-2.1+
-	[cubeb]=ISC
-	[discord-rpc]=MIT
-	# Their build set up solely relies on the build in gtest.
-	[gtest]= # (build-time only)
-	# gentoo's version requires exception support.
-	# dolphin disables exceptions and fails the build.
-	[picojson]=BSD-2
-	# No code to detect shared library.
-	[zstd]=BSD
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	local s remove=()
-	for s in Externals/*; do
-		[[ -f ${s} ]] && continue
-		if ! has "${s#Externals/}" "${!KEEP_BUNDLED[@]}"; then
-			remove+=( "${s}" )
-		fi
-	done
-
-	einfo "removing sources: ${remove[*]}"
-	rm -r "${remove[@]}" || die
-
-	# About 50% compile-time speedup
-	if ! use vulkan; then
-		sed -i -e '/Externals\/glslang/d' CMakeLists.txt || die
-	fi
-
-	# Remove dirty suffix: needed for netplay
-	sed -i -e 's/--dirty/&=""/' CMakeLists.txt || die
-
-	# Force Qt5 rather than automagic until support is properly handled here
-	sed -i -e '/NAMES Qt6 COMP/d' Source/Core/DolphinQt/CMakeLists.txt || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		# Use ccache only when user did set FEATURES=ccache (or similar)
-		# not when ccache binary is present in system (automagic).
-		-DCCACHE_BIN=CCACHE_BIN-NOTFOUND
-		-DENABLE_ALSA=$(usex alsa)
-		-DENABLE_BLUEZ=$(usex bluetooth)
-		-DENABLE_EVDEV=$(usex evdev)
-		-DENCODE_FRAMEDUMPS=$(usex ffmpeg)
-		-DENABLE_LLVM=OFF
-		# just adds -flto, user can do that via flags
-		-DENABLE_LTO=OFF
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
-		-DENABLE_QT=$(usex gui)
-		-DENABLE_SDL=OFF # not supported: #666558
-		-DENABLE_VULKAN=$(usex vulkan)
-		-DFASTLOG=$(usex log)
-		-DOPROFILING=$(usex profile)
-		-DUSE_DISCORD_PRESENCE=$(usex discord-presence)
-		-DUSE_SHARED_ENET=ON
-		-DUSE_UPNP=$(usex upnp)
-
-		# Undo cmake.eclass's defaults.
-		# All dolphin's libraries are private
-		# and rely on circular dependency resolution.
-		-DBUILD_SHARED_LIBS=OFF
-
-		# Avoid warning spam around unset variables.
-		-Wno-dev
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	cmake_build unittests
-}
-
-src_install() {
-	cmake_src_install
-
-	dodoc Readme.md
-	if use doc; then
-		dodoc -r docs/ActionReplay docs/DSP docs/WiiMote
-	fi
-
-	doicon -s 48 Data/dolphin-emu.png
-	doicon -s scalable Data/dolphin-emu.svg
-	doicon Data/dolphin-emu.svg
-}
-
-pkg_postinst() {
-	# Add pax markings for hardened systems
-	pax-mark -m "${EPREFIX}"/usr/games/bin/"${PN}"-emu
-	xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}

diff --git a/games-emulation/dolphin/files/dolphin-5.0_p20210506-musl.patch b/games-emulation/dolphin/files/dolphin-5.0_p20210506-musl.patch
deleted file mode 100644
index 51570151c112..000000000000
--- a/games-emulation/dolphin/files/dolphin-5.0_p20210506-musl.patch
+++ /dev/null
@@ -1,24 +0,0 @@
-https://bugs.gentoo.org/799281
-https://github.com/dolphin-emu/dolphin/commit/7a1922fd8f0f6686188d179732c9757faf2d1b4f.patch
-
-From 7a1922fd8f0f6686188d179732c9757faf2d1b4f Mon Sep 17 00:00:00 2001
-From: thyrc <thyrc@××××××××××××××××××××.com>
-Date: Mon, 14 Jun 2021 10:18:34 +0200
-Subject: [PATCH] Fix includes for musl libc
-
----
- Source/Core/Core/MemoryWatcher.cpp | 1 +
- 1 file changed, 1 insertion(+)
-
-diff --git a/Source/Core/Core/MemoryWatcher.cpp b/Source/Core/Core/MemoryWatcher.cpp
-index 491ecd83150a..13843e2021ca 100644
---- a/Source/Core/Core/MemoryWatcher.cpp
-+++ b/Source/Core/Core/MemoryWatcher.cpp
-@@ -2,6 +2,7 @@
- // Licensed under GPLv2+
- // Refer to the license.txt file included.
- 
-+#include <cstring>
- #include <fstream>
- #include <iostream>
- #include <sstream>