[gentoo-commits] repo/gentoo:master commit in: net-im/gajim/

[Hanno Böck]

commit:     9a48b2767ef404457addbc0b1fae3d102ef2a8eb
Author:     Hanno Böck <hanno <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 26 09:03:58 2020 +0000
Commit:     Hanno Böck <hanno <AT> gentoo <DOT> org>
CommitDate: Fri Jun 26 09:03:58 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a48b276

net-im/gajim: Version bump.

Update changed upstream dependencies.
Avoid distutils/setuptools warning.

Signed-off-by: Hanno Böck <hanno <AT> gentoo.org>
Package-Manager: Portage-2.3.103, Repoman-2.3.23

 net-im/gajim/Manifest           |  1 +
 net-im/gajim/gajim-1.2.0.ebuild | 85 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index 23f269a95b7..8365086857d 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -1 +1,2 @@
 DIST gajim-1.1.3.tar.bz2 8013585 BLAKE2B 7be25380ecfe76ae5e2a7534665688dcca9ff850c12c7a450e8d1f6caab1820a1022750710df0a8a7ae259c5748f55582b272ad83fbdb0560f18e6ab8642bf78 SHA512 18062832f9b9295c7a844c347d5ece4a6db43126d5b58bbf362fdf2f8e082e2241c46dae6d1cbe66ebf2ef19f65618102c3c21fa0079a96fc21511e6e93420ac
+DIST gajim-1.2.0.tar.gz 9605006 BLAKE2B b68e801fedf89d14e8831a52f952fa3937b8f8ed0423a0289d5c665b50244db8db9d91dd24203e446d691e26843dd75dbf0de2b1b183cc0a8fb178bc7632c500 SHA512 e73802dd1172c1fa38be10e6fb5d605109dacf0491516b15111ccd05389309af217e8af68440a1333b8a636c9ff425dec6d4461296ba47f1bb6dbb3000b02fd0

diff --git a/net-im/gajim/gajim-1.2.0.ebuild b/net-im/gajim/gajim-1.2.0.ebuild
new file mode 100644
index 00000000000..9dd5e08d83c
--- /dev/null
+++ b/net-im/gajim/gajim-1.2.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite,xml"
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="https://gajim.org/"
+SRC_URI="https://gajim.org/downloads/$(ver_cut 1-2)/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+crypt geolocation jingle remote rst +spell upnp +webp"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo(+)]
+	>=x11-libs/gtk+-3.22:3[introspection]"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/precis-i18n[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+		>=dev-python/python-nbxmpp-1.0.0[${PYTHON_USEDEP}]
+		x11-libs/libXScrnSaver
+		app-crypt/libsecret[crypt,introspection]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		>=dev-python/secretstorage-3.1.1[${PYTHON_USEDEP}]
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		crypt? (
+			dev-python/pycryptodome[${PYTHON_USEDEP}]
+			>=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+		geolocation? ( app-misc/geoclue[introspection] )
+		jingle? (
+			net-libs/farstream:0.2[introspection]
+			media-libs/gstreamer:1.0[introspection]
+			media-libs/gst-plugins-base:1.0[introspection]
+			media-libs/gst-plugins-ugly:1.0
+		)
+		remote? (
+			>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+			sys-apps/dbus[X]
+		)
+		rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+		spell? (
+			app-text/gspell[introspection]
+			app-text/hunspell
+		)
+		upnp? ( net-libs/gupnp-igd[introspection] )
+		webp? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	')"
+
+src_install() {
+	distutils-r1_src_install
+
+	# avoid precompressed man pages
+	rm -r "${D}/usr/share/man"
+	doman data/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}