[gentoo-commits] repo/gentoo:master commit in: media-video/recordmydesktop/

[Mikle Kolyada]

commit:     536483377db440b5276dfd474a9528d539448c43
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Mon Oct  8 10:51:36 2018 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Mon Oct  8 10:52:28 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53648337

media-video/recordmydesktop: rework ebuild a bit

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

 .../recordmydesktop-0.3.8.1-r6.ebuild              | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/media-video/recordmydesktop/recordmydesktop-0.3.8.1-r6.ebuild b/media-video/recordmydesktop/recordmydesktop-0.3.8.1-r6.ebuild
new file mode 100644
index 00000000000..940e02981cd
--- /dev/null
+++ b/media-video/recordmydesktop/recordmydesktop-0.3.8.1-r6.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="A desktop session recorder producing Ogg video/audio files"
+HOMEPAGE="http://recordmydesktop.sourceforge.net/"
+SRC_URI="mirror://sourceforge/recordmydesktop/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 x86"
+IUSE="alsa jack"
+
+RDEPEND="x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXdamage
+	media-libs/libvorbis
+	media-libs/libogg
+	media-libs/libtheora[encode]
+	x11-libs/libICE
+	x11-libs/libSM
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+src_prepare() {
+	default
+	sed -i \
+		-e 's:shmstr.h:shmproto.h:g' \
+		src/rmd_{getzpixmap.c,update_image.c} || die
+
+	# fix weird Framerates with new libtheora
+	eapply "${FILESDIR}/${PV}-fix_new_theora.patch"
+
+	# fix check for jack support
+	eapply "${FILESDIR}/${PV}-fix-libjack-check.patch"
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-dependency-tracking \
+		$(use_enable !alsa oss) \
+		$(use_enable jack)
+}