[gentoo-commits] gentoo-x86 commit in x11-terms/rxvt: ChangeLog rxvt-2.7.10-r4.ebuild

[Christian Hoffmann (hoffie)]

hoffie      08/05/03 12:55:04

  Modified:             ChangeLog
  Added:                rxvt-2.7.10-r4.ebuild
  Log:
  revbump to include a patch to fix CVE-2008-1142 (do not default to :0 if DISPLAY is unset), bug 217819; stable on amd64
  (Portage version: 2.1.5_rc6, RepoMan options: --force)

Revision  Changes    Path
1.58                 x11-terms/rxvt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/rxvt/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	25 Dec 2007 17:17:15 -0000	1.57
+++ ChangeLog	3 May 2008 12:55:03 -0000	1.58
@@ -1,6 +1,14 @@
 # ChangeLog for x11-terms/rxvt
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt/ChangeLog,v 1.57 2007/12/25 17:17:15 phreak Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt/ChangeLog,v 1.58 2008/05/03 12:55:03 hoffie Exp $
+
+*rxvt-2.7.10-r4 (03 May 2008)
+
+  03 May 2008; Christian Hoffmann <hoffie@g.o>
+  +files/rxvt-2.7.10-CVE-2008-1142-DISPLAY.patch, +rxvt-2.7.10-r4.ebuild:
+  revbump to include a patch to fix CVE-2008-1142 (do not default to :0 if
+  DISPLAY is unset), bug 217819; ebuild cleanups (quoting, bindnow); stable
+  on amd64
 
   25 Dec 2007; Christian Heim <phreak@g.o> metadata.xml:
   Removing usata from metadata.xml as per #22931. Assigning to maintainer-needed.



1.1                  x11-terms/rxvt/rxvt-2.7.10-r4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt/rxvt-2.7.10-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/rxvt/rxvt-2.7.10-r4.ebuild?rev=1.1&content-type=text/plain

Index: rxvt-2.7.10-r4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/rxvt/rxvt-2.7.10-r4.ebuild,v 1.1 2008/05/03 12:55:03 hoffie Exp $

inherit eutils flag-o-matic libtool

DESCRIPTION="rxvt -- nice small x11 terminal"
HOMEPAGE="http://rxvt.sourceforge.net/
	http://www.giga.it.okayama-u.ac.jp/~ishihara/opensource/"
SRC_URI="mirror://sourceforge/rxvt/${P}.tar.gz
	http://www.giga.it.okayama-u.ac.jp/~ishihara/opensource/${P}-xim-fix.patch.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="motif cjk xgetdefault linuxkeys"

RDEPEND="virtual/libc
	x11-libs/libX11
	x11-libs/libXpm
	x11-libs/libXext
	motif? ( x11-libs/openmotif )"
DEPEND="${RDEPEND}
	x11-proto/xproto"

src_unpack() {
	unpack "${P}.tar.gz"
	cd "${S}"

	epatch "${FILESDIR}"/${P}-line-scroll.patch
	epatch "${FILESDIR}"/${P}-asneeded.patch
	use motif && epatch "${FILESDIR}"/${P}-azz4.diff
	if use cjk ; then
		epatch "${DISTDIR}"/${P}-xim-fix.patch.gz
		if use linguas_ja ; then
			epatch "${FILESDIR}"/${P}-rk.patch
		fi
	fi

	epatch "${FILESDIR}"/${P}-CVE-2008-1142-DISPLAY.patch
	elibtoolize
}

src_compile() {

	local term
	if [ -n "${RXVT_TERM}" ] ; then
		term="${RXVT_TERM}"
	else
		term="rxvt"
	fi

	# bug #22325
	use linuxkeys && append-flags -DLINUX_KEYS

	econf \
		--enable-everything \
		--enable-rxvt-scroll \
		--enable-next-scroll \
		--enable-xterm-scroll \
		--enable-transparency \
		--enable-xpm-background \
		--enable-utmp \
		--enable-wtmp \
		--enable-mousewheel \
		--enable-slipwheeling \
		--enable-smart-resize \
		--enable-256-color \
		--enable-menubar \
		$(use_enable cjk languages) \
		--enable-xim \
		--enable-shared \
		--enable-keepscrolling \
		--with-term=${term} \
		$(use_enable xgetdefault) || die

	emake || die
}

src_install() {

	einstall mandir="${D}"/usr/share/man/man1 || die

	cd "${S}"/doc
	dodoc README* *.txt BUGS FAQ
	dohtml *.html
}

pkg_postinst() {

	einfo
	einfo "If you want to change default TERM variable other than rxvt,"
	einfo "set RXVT_TERM environment variable and then emerge rxvt."
	einfo "Especially, if you use rxvt under monochrome X you might need to run"
	einfo "\t RXVT_TERM=rxvt-basic emerge rxvt"
	einfo "otherwise curses based program will not work."
	einfo
}



-- 
gentoo-commits@l.g.o mailing list