[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgudev/

[Mike Gilbert]

commit:     06568cb8c27a54fb22e9907761ad683916b5079b
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 29 21:09:11 2021 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Thu Jul 29 21:14:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=06568cb8

dev-libs/libgudev: wire up tests

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 dev-libs/libgudev/libgudev-236-r1.ebuild | 46 ++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-libs/libgudev/libgudev-236-r1.ebuild b/dev-libs/libgudev/libgudev-236-r1.ebuild
new file mode 100644
index 00000000000..db6775ef55f
--- /dev/null
+++ b/dev-libs/libgudev/libgudev-236-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2015-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson-multilib
+
+DESCRIPTION="GObject bindings for libudev"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgudev"
+SRC_URI="https://download.gnome.org/sources/libgudev/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="introspection static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.38.0:2[${MULTILIB_USEDEP},static-libs?]
+	>=virtual/libudev-199:=[${MULTILIB_USEDEP},static-libs(-)?]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-util/umockdev[${MULTILIB_USEDEP}] )
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	# avoid multilib checksum mismatch
+	sed -i -e 's:@filename@:gudev/gudevenums.h:' gudev/gudevenumtypes.h.template || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature introspection)
+		-Dgtk_doc=false
+		-Ddefault_library=$(usex static-libs both shared)
+		$(meson_feature test tests)
+		-Dvapi=disabled
+	)
+	meson_src_configure
+}