[gentoo-commits] proj/gnome:master commit in: x11-terms/gnome-terminal/

[Mart Raudsepp]

commit:     5dacbcbc250d22ffd3cc8ee6dc1710b6320adc64
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 13 07:35:01 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Thu Sep 13 07:35:01 2018 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=5dacbcbc

x11-terms/gnome-terminal-3.26.2: remove, 3.28 available in ::gentoo

Main tree 3.28 also removed VALAC=/bin/true setting, as the non-installed
vala thing was ported away from vala in 3.28 or 3.26.

Package-Manager: Portage-2.3.49, Repoman-2.3.10

 .../gnome-terminal/gnome-terminal-3.26.2.ebuild    | 81 ----------------------
 1 file changed, 81 deletions(-)

diff --git a/x11-terms/gnome-terminal/gnome-terminal-3.26.2.ebuild b/x11-terms/gnome-terminal/gnome-terminal-3.26.2.ebuild
deleted file mode 100644
index 4cee5d9d..00000000
--- a/x11-terms/gnome-terminal/gnome-terminal-3.26.2.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-GNOME2_LA_PUNT="yes"
-
-inherit gnome2 readme.gentoo-r1
-
-DESCRIPTION="The Gnome Terminal"
-HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/"
-
-LICENSE="GPL-3+"
-SLOT="0"
-IUSE="debug +gnome-shell +nautilus vanilla"
-SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~tranquility/distfiles/${PN}/${P}-notify-open-title-transparency.patch.xz )"
-
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
-
-# FIXME: automagic dependency on gtk+[X], just transitive but needs proper control, bug 624960
-RDEPEND="
-	>=dev-libs/glib-2.42:2
-	>=x11-libs/gtk+-3.20:3
-	>=x11-libs/vte-0.50.2:2.91[!vanilla?]
-	>=dev-libs/libpcre2-10
-	>=gnome-base/dconf-0.14
-	>=gnome-base/gsettings-desktop-schemas-0.1.0
-	sys-apps/util-linux
-	gnome-shell? ( gnome-base/gnome-shell )
-	nautilus? ( >=gnome-base/nautilus-3 )
-"
-# itstool/yelp-tools required for help/* with non-en LINGUAS, see bug #549358
-# xmllint required for glib-compile-resources, see bug #549304
-DEPEND="${RDEPEND}
-	app-text/yelp-tools
-	dev-libs/libxml2
-	dev-util/gdbus-codegen
-	>=dev-util/intltool-0.50
-	sys-devel/gettext
-	virtual/pkgconfig
-"
-
-DOC_CONTENTS="To get previous working directory inherited in new opened tab, or
-	notifications of long-running commands finishing, you will need
-	to add the following line to your ~/.bashrc:\n
-	. /etc/profile.d/vte-2.91.sh"
-
-src_prepare() {
-	if ! use vanilla; then
-		# https://bugzilla.gnome.org/show_bug.cgi?id=695371
-		# Fedora patches:
-		# Restore transparency support (with compositing WMs only)
-		# OSC 777 desktop notification support (notifications on tabs for long-running commands completing)
-		# Restore separate menuitems for opening tabs and windows
-		# Restore "Set title" support
-		# http://pkgs.fedoraproject.org/cgit/rpms/gnome-terminal.git/plain/gnome-terminal-notify-open-title-transparency.patch
-		# Depends on vte[-vanilla] for OSC 777 patch in VTE
-		eapply "${WORKDIR}"/${P}-notify-open-title-transparency.patch
-	fi
-	gnome2_src_prepare
-}
-
-src_configure() {
-	gnome2_src_configure \
-		--disable-static \
-		--disable-migration \
-		$(use_enable debug) \
-		$(use_enable gnome-shell search-provider) \
-		$(use_with nautilus nautilus-extension) \
-		VALAC=$(type -P true)
-}
-
-src_install() {
-	DOCS="AUTHORS ChangeLog HACKING NEWS"
-	gnome2_src_install
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	readme.gentoo_print_elog
-}