[gentoo-commits] repo/gentoo:master commit in: media-video/mjpegtools/

[Daniel Pielmeier]

commit:     554a01529009dc297d481505a3620d8167897a5c
Author:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  9 10:37:39 2022 +0000
Commit:     Daniel Pielmeier <billie <AT> gentoo <DOT> org>
CommitDate: Sat Apr  9 10:38:00 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=554a0152

media-video/mjpegtools: Remove old.

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Daniel Pielmeier <billie <AT> gentoo.org>

 media-video/mjpegtools/Manifest                   |   1 -
 media-video/mjpegtools/mjpegtools-2.2.0-r1.ebuild | 112 ----------------------
 2 files changed, 113 deletions(-)

diff --git a/media-video/mjpegtools/Manifest b/media-video/mjpegtools/Manifest
index b1342f697e62..06067cc179f8 100644
--- a/media-video/mjpegtools/Manifest
+++ b/media-video/mjpegtools/Manifest
@@ -1,2 +1 @@
-DIST mjpegtools-2.2.0.tar.bz2 1542088 BLAKE2B 61736ea0782ef098110370ab75feac2d344709a849326acc366cc1dedfabe0aaec797292f09de9d0da8a2ce94506dc2c8749212b49f99ffa8775f347eae94b46 SHA512 d645c0004bf20cab67d2e09cde709f05e32ab755b773c93f75ab65bf6d4ab23d80addf3f8b98e1ce59cc05efc0776b11ca0c71568acb81fab6a0f15e60bce71f
 DIST mjpegtools-2.2.1.tar.gz 2326425 BLAKE2B a6f2698dda6b7c92a1a786f39bfb1989587b2c35a1f94e435247f04a01f405808d464470fddf1eddaee73df75daaef460bd62e901b89b2b2e0b095332492b20b SHA512 4d7f4dcf56a0e6079025bf0221ee632d91c4cc635a8c7eb9ddf3f7b86ad7250415c6dc4fd4113081920bc9c8fdc2552b8a3aaf896bf5a778acfacb15c7ded830

diff --git a/media-video/mjpegtools/mjpegtools-2.2.0-r1.ebuild b/media-video/mjpegtools/mjpegtools-2.2.0-r1.ebuild
deleted file mode 100644
index 0616cbf4c0af..000000000000
--- a/media-video/mjpegtools/mjpegtools-2.2.0-r1.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools flag-o-matic multilib-minimal toolchain-funcs
-
-DESCRIPTION="Tools for MJPEG video"
-HOMEPAGE="http://mjpeg.sourceforge.net/"
-SRC_URI="mirror://sourceforge/mjpeg/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-# Compare with version in SONAME on major bumps (e.g. 2.1 -> 2.2)
-SLOT="1/2.2"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
-IUSE="cpu_flags_x86_mmx dv gtk png quicktime sdl sdlgfx static-libs"
-REQUIRED_USE="sdlgfx? ( sdl )"
-
-BDEPEND="
-	virtual/pkgconfig
-"
-RDEPEND="
-	virtual/jpeg:0=[${MULTILIB_USEDEP}]
-	dv? ( >=media-libs/libdv-1.0.0-r3[${MULTILIB_USEDEP}] )
-	gtk? ( x11-libs/gtk+:2 )
-	png? ( media-libs/libpng:0= )
-	quicktime? ( >=media-libs/libquicktime-1.2.4-r1[${MULTILIB_USEDEP}] )
-	sdl? (
-		>=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]
-		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
-		sdlgfx? ( media-libs/sdl-gfx )
-	)
-"
-DEPEND="
-	${RDEPEND}
-	>=sys-apps/sed-4
-	virtual/awk
-	cpu_flags_x86_mmx? ( dev-lang/nasm )
-"
-
-src_prepare() {
-	default
-
-	eautoreconf
-	sed -i -e '/ARCHFLAGS=/s:=.*:=:' configure
-}
-
-multilib_src_configure() {
-	[[ $(gcc-major-version) -eq 3 ]] && append-flags -mno-sse2
-
-	local myconf=(
-		--enable-compile-warnings
-		$(use_enable cpu_flags_x86_mmx simd-accel)
-		$(use_enable static-libs static)
-		--enable-largefile
-
-		$(use_with quicktime libquicktime)
-		$(use_with dv libdv)
-		$(use_with sdl libsdl)
-		--without-v4l
-		$(use_with sdl x)
-
-		# used by tools only
-		$(multilib_native_use_with gtk)
-		$(multilib_native_use_with png libpng)
-		$(multilib_native_use_with sdlgfx)
-	)
-
-	ECONF_SOURCE=${S} \
-	econf "${myconf[@]}"
-}
-
-multilib_src_compile() {
-	if multilib_is_native_abi; then
-		default
-	else
-		# avoid building programs
-		emake bin_PROGRAMS=
-	fi
-}
-
-multilib_src_test() {
-	# there are no tests at the moment, so it would just build
-	# all programs in non-native ABIs...
-	multilib_is_native_abi && default
-}
-
-multilib_src_install() {
-	if multilib_is_native_abi; then
-		default
-	else
-		emake DESTDIR="${D}" install \
-			bin_PROGRAMS=
-	fi
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	dodoc mjpeg_howto.txt PLANS HINTS docs/FAQ.txt
-
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		elog "mjpegtools installs user contributed scripts which require additional"
-		elog "dependencies not pulled in by the installation."
-		elog "These have to be installed manually."
-		elog "Currently known extra dpendencies are: ffmpeg, mencoder from mplayer,"
-		elog "parts of transcode, mpeg2dec from libmpeg2, sox, toolame, vcdimager, python."
-	fi
-}