[gentoo-commits] gentoo-x86 commit in dev-python/sqlalchemy: sqlalchemy-0.9.8.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/10/30 03:56:32

  Modified:             ChangeLog
  Added:                sqlalchemy-0.9.8.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.137                dev-python/sqlalchemy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/ChangeLog?rev=1.137&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/ChangeLog?rev=1.137&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/ChangeLog?r1=1.136&r2=1.137

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v
retrieving revision 1.136
retrieving revision 1.137
diff -u -r1.136 -r1.137
--- ChangeLog	17 Oct 2014 04:07:42 -0000	1.136
+++ ChangeLog	30 Oct 2014 03:56:32 -0000	1.137
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/sqlalchemy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.136 2014/10/17 04:07:42 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.137 2014/10/30 03:56:32 patrick Exp $
+
+*sqlalchemy-0.9.8 (30 Oct 2014)
+
+  30 Oct 2014; Patrick Lauer <patrick@g.o> +sqlalchemy-0.9.8.ebuild:
+  Bump
 
   17 Oct 2014; Michał Górny <mgorny@g.o> sqlalchemy-0.9.2.ebuild:
   Backport the requirement of python[sqlite] from newer versions, bug #525594.



1.1                  dev-python/sqlalchemy/sqlalchemy-0.9.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.9.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.9.8.ebuild?rev=1.1&content-type=text/plain

Index: sqlalchemy-0.9.8.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.9.8.ebuild,v 1.1 2014/10/30 03:56:32 patrick Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} pypy )
PYTHON_REQ_USE="sqlite?"

inherit distutils-r1 flag-o-matic

MY_PN="SQLAlchemy"
MY_P="${MY_PN}-${PV/_}"

DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
HOMEPAGE="http://www.sqlalchemy.org/ http://pypi.python.org/pypi/SQLAlchemy"
SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc examples +sqlite test"
REQUIRED_USE="test? ( sqlite )"

RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"

DEPEND="${RDEPEND}
	test? (	dev-python/pytest[${PYTHON_USEDEP}]
		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python{2_7,3_2} pypy)
	)"
S="${WORKDIR}/${MY_P}"

python_prepare_all() {
	# Disable tests hardcoding function call counts specific to Python versions.
	rm -r test/aaa_profiling || die
	distutils-r1_python_prepare_all
}

python_compile() {
	if ! python_is_python3; then
		local CFLAGS=${CFLAGS}
		append-cflags -fno-strict-aliasing
	fi
	distutils-r1_python_compile
}

python_test() {
	# Create copies of necessary files in BUILD_DIR.
	# https://bitbucket.org/zzzeek/sqlalchemy/issue/3144/
	cp -pR examples sqla_nose.py setup.cfg test "${BUILD_DIR}" || die
	pushd "${BUILD_DIR}" > /dev/null
	if [[ "${EPYTHON}" == "python3.2" ]]; then
		2to3 --no-diffs -w test
	fi
	# Recently upstream elected to make the testsuite also pytest capable
	# "${PYTHON}" sqla_nose.py || die "Testsuite failed under ${EPYTHON}"
	py.test test || die "Testsuite failed under ${EPYTHON}"
	popd > /dev/null
}

python_install_all() {
	use doc && HTML_DOCS=( doc/. )

	use examples && local EXAMPLES=( examples/. )

	distutils-r1_python_install_all
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]]; then
		if ! has_version dev-python/mysql-python; then
		        elog "For MySQL support, install dev-python/mysql-python"
		fi

		if ! has_version dev-python/pymssql; then
			elog "For mssql support, install dev-python/pymssql"
		fi

		if ! has_version dev-python/psycopg:2; then
			elog "For postgresql support, install dev-python/psycopg:2"
		fi
	fi
}