[gentoo-commits] gentoo-x86 commit in www-client/google-chrome-beta: google-chrome-beta-34.0.1847.92_p1.ebuild ChangeLog google-chrome-beta-34.0.1847.76_p1.ebuild

[Mike Gilbert (floppym)]

floppym     14/03/27 19:49:26

  Modified:             ChangeLog
  Added:                google-chrome-beta-34.0.1847.92_p1.ebuild
  Removed:              google-chrome-beta-34.0.1847.76_p1.ebuild
  Log:
  Automated update.
  
  (Portage version: 2.2.9-r1/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.14                 www-client/google-chrome-beta/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-beta/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-beta/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-beta/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/google-chrome-beta/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	20 Mar 2014 17:37:44 -0000	1.13
+++ ChangeLog	27 Mar 2014 19:49:26 -0000	1.14
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/google-chrome-beta
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome-beta/ChangeLog,v 1.13 2014/03/20 17:37:44 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome-beta/ChangeLog,v 1.14 2014/03/27 19:49:26 floppym Exp $
+
+*google-chrome-beta-34.0.1847.92_p1 (27 Mar 2014)
+
+  27 Mar 2014; Mike Gilbert <floppym@g.o>
+  +google-chrome-beta-34.0.1847.92_p1.ebuild,
+  -google-chrome-beta-34.0.1847.76_p1.ebuild:
+  Automated update.
 
 *google-chrome-beta-34.0.1847.76_p1 (20 Mar 2014)
 



1.1                  www-client/google-chrome-beta/google-chrome-beta-34.0.1847.92_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-beta/google-chrome-beta-34.0.1847.92_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-beta/google-chrome-beta-34.0.1847.92_p1.ebuild?rev=1.1&content-type=text/plain

Index: google-chrome-beta-34.0.1847.92_p1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome-beta/google-chrome-beta-34.0.1847.92_p1.ebuild,v 1.1 2014/03/27 19:49:26 floppym Exp $

EAPI="5"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
	sv sw ta te th tr uk vi zh_CN zh_TW"

inherit readme.gentoo chromium eutils multilib pax-utils unpacker

DESCRIPTION="The web browser from Google"
HOMEPAGE="http://www.google.com/chrome"

if [[ ${PN} == google-chrome ]]; then
	MY_PN=${PN}-stable
else
	MY_PN=${PN}
fi

MY_P="${MY_PN}_${PV/_p/-}"

SRC_URI="
	amd64? (
		http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb
	)
	x86? (
		http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_i386.deb
	)
"

LICENSE="google-chrome"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="+plugins"
RESTRICT="bindist mirror strip"

RDEPEND="
	app-arch/bzip2
	app-misc/ca-certificates
	dev-libs/atk
	dev-libs/expat
	dev-libs/glib:2
	|| ( dev-libs/libgcrypt:11 dev-libs/libgcrypt:0/11 )
	dev-libs/nspr
	dev-libs/nss
	gnome-base/gconf:2
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/freetype
	net-print/cups
	sys-apps/dbus
	>=sys-devel/gcc-4.4.0[cxx]
	sys-libs/libcap
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	>=x11-libs/libX11-1.5.0
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXScrnSaver
	x11-libs/libXtst
	x11-libs/pango
	x11-misc/xdg-utils
"

if [[ ${PN} == google-chrome ]]; then
	RDEPEND+="
		!www-client/google-chrome:beta
		!www-client/google-chrome:stable
		!www-client/google-chrome:unstable
	"
fi

for x in google-chrome{,-beta,-unstable}; do
	if [[ ${PN} != ${x} ]]; then
		RDEPEND+=" !www-client/${x}"
	fi
done
unset x

QA_PREBUILT="*"
S=${WORKDIR}

DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="
Some web pages may require additional fonts to display properly.
Try installing some of the following packages if some characters
are not displayed properly:
- media-fonts/arphicfonts
- media-fonts/bitstream-cyberbit
- media-fonts/droid
- media-fonts/ipamonafont
- media-fonts/ja-ipafonts
- media-fonts/takao-fonts
- media-fonts/wqy-microhei
- media-fonts/wqy-zenhei

Depending on your desktop environment, you may need
to install additional packages to get icons on the Downloads page.

For KDE, the required package is kde-base/oxygen-icons.

For other desktop environments, try one of the following:
- x11-themes/gnome-icon-theme
- x11-themes/tango-icon-theme

Please notice the bundled flash player (PepperFlash).
You can (de)activate all flash plugins via chrome://plugins
"

pkg_nofetch() {
	eerror "Please wait 24 hours before reporting a bug for google-chrome fetch failures."
}

pkg_setup() {
	chromium_suid_sandbox_check_kernel_config
}

src_install() {
	CHROME_HOME="opt/google/chrome${PN#google-chrome}"

	rm -r usr/share/menu || die
	rmdir usr/share/doc/google-chrome || die
	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die

	pushd "${CHROME_HOME}/locales" > /dev/null || die
	chromium_remove_language_paks
	popd > /dev/null || die

	if use plugins ; then
		local plugins="--extra-plugin-dir=/usr/$(get_libdir)/nsbrowser/plugins"
		sed -e "/^exec/ i set -- \"${plugins}\" \"\$@\"" \
			-i "${CHROME_HOME}/google-chrome" || die
	fi

	local size
	for size in 16 22 24 32 48 64 128 256 ; do
		newicon -s ${size} "${CHROME_HOME}/product_logo_${size}.png" google-chrome.png
	done

	insinto /
	doins -r opt usr

	fperms 755 "/${CHROME_HOME}"/{{,google-}chrome,nacl_helper{,_bootstrap},xdg-{mime,settings}}
	fperms 4755 "/${CHROME_HOME}/chrome-sandbox"
	pax-mark m "${ED}${CHROME_HOME}/chrome"
	dosym /usr/$(get_libdir)/libudev.so "${CHROME_HOME}/libudev.so.0"

	readme.gentoo_create_doc
}

any_cpu_missing_flag() {
	local value=$1
	grep '^flags' /proc/cpuinfo | grep -qv "$value"
}

pkg_preinst() {
	chromium_pkg_preinst
	if any_cpu_missing_flag sse2; then
		ewarn "The bundled PepperFlash plugin requires a CPU that supports the"
		ewarn "SSE2 instruction set, and at least one of your CPUs does not"
		ewarn "support this feature. Disabling PepperFlash."
		sed -e "/^exec/ i set -- --disable-bundled-ppapi-flash \"\$@\"" \
			-i "${ED}${CHROME_HOME}/google-chrome" || die
	fi
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	readme.gentoo_print_elog
}