[gentoo-commits] gentoo-x86 commit in dev-java/netbeans-profiler: ChangeLog netbeans-profiler-7.1.ebuild

[Miroslav Sulc (fordfrog)]

fordfrog    12/01/06 11:37:55

  Modified:             ChangeLog
  Added:                netbeans-profiler-7.1.ebuild
  Log:
  dev-java/netbeans-profiler: version bump
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  dev-java/netbeans-profiler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-profiler/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-profiler/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-profiler/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/netbeans-profiler/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	25 Oct 2011 00:31:04 -0000	1.6
+++ ChangeLog	6 Jan 2012 11:37:55 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/netbeans-profiler
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/netbeans-profiler/ChangeLog,v 1.6 2011/10/25 00:31:04 fordfrog Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/netbeans-profiler/ChangeLog,v 1.7 2012/01/06 11:37:55 fordfrog Exp $
+
+*netbeans-profiler-7.1 (06 Jan 2012)
+
+  06 Jan 2012; Miroslav Šulc <fordfrog@g.o>
+  +netbeans-profiler-7.1.ebuild:
+  Version bump
 
   25 Oct 2011; Miroslav Šulc <fordfrog@g.o>
   netbeans-profiler-7.0.1.ebuild:



1.1                  dev-java/netbeans-profiler/netbeans-profiler-7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-profiler/netbeans-profiler-7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/netbeans-profiler/netbeans-profiler-7.1.ebuild?rev=1.1&content-type=text/plain

Index: netbeans-profiler-7.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/netbeans-profiler/netbeans-profiler-7.1.ebuild,v 1.1 2012/01/06 11:37:55 fordfrog Exp $

EAPI="4"
WANT_ANT_TASKS="ant-nodeps"
inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="Netbeans Profiler Cluster"
HOMEPAGE="http://netbeans.org/projects/profiler"
SLOT="7.1"
SOURCE_URL="http://dlc.sun.com.edgesuite.net/netbeans/7.1/final/zip/netbeans-7.1-201112071828-src.zip"
SRC_URI="${SOURCE_URL}
	http://dev.gentoo.org/~fordfrog/distfiles/netbeans-9999-r1-build.xml.patch.bz2"
LICENSE="|| ( CDDL GPL-2-with-linking-exception )"
KEYWORDS="~amd64 ~x86"
IUSE=""
S="${WORKDIR}"

CDEPEND="~dev-java/netbeans-ide-${PV}
	~dev-java/netbeans-java-${PV}
	~dev-java/netbeans-platform-${PV}"
DEPEND="virtual/jdk:1.6
	app-arch/unzip
	${CDEPEND}
	dev-java/javahelp:0"
RDEPEND=">=virtual/jdk-1.6
	${CDEPEND}"

INSTALL_DIR="/usr/share/${PN}-${SLOT}"

EANT_BUILD_XML="nbbuild/build.xml"
EANT_BUILD_TARGET="rebuild-cluster"
EANT_EXTRA_ARGS="-Drebuild.cluster.name=nb.cluster.profiler -Dext.binaries.downloaded=true"
EANT_FILTER_COMPILER="ecj-3.3 ecj-3.4 ecj-3.5 ecj-3.6 ecj-3.7"
JAVA_PKG_BSFIX="off"

src_unpack() {
	unpack $(basename ${SOURCE_URL})

	einfo "Deleting bundled jars..."
	find -name "*.jar" -type f -delete

	unpack netbeans-9999-r1-build.xml.patch.bz2
}

src_prepare() {
	einfo "Deleting bundled class files..."
	find -name "*.class" -type f | xargs rm -vf

	epatch netbeans-9999-r1-build.xml.patch

	# Support for custom patches
	if [ -n "${NETBEANS9999_PATCHES_DIR}" -a -d "${NETBEANS9999_PATCHES_DIR}" ] ; then
		local files=`find "${NETBEANS9999_PATCHES_DIR}" -type f`

		if [ -n "${files}" ] ; then
			einfo "Applying custom patches:"

			for file in ${files} ; do
				epatch "${file}"
			done
		fi
	fi

	einfo "Symlinking external libraries..."
	java-pkg_jar-from --build-only --into javahelp/external javahelp jhall.jar jhall-2.0_05.jar

	einfo "Linking in other clusters..."
	mkdir "${S}"/nbbuild/netbeans || die
	pushd "${S}"/nbbuild/netbeans >/dev/null || die

	ln -s /usr/share/netbeans-ide-${SLOT} ide || die
	cat /usr/share/netbeans-ide-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die
	touch nb.cluster.ide.built

	ln -s /usr/share/netbeans-java-${SLOT} java || die
	cat /usr/share/netbeans-java-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die
	touch nb.cluster.java.built

	ln -s /usr/share/netbeans-platform-${SLOT} platform || die
	cat /usr/share/netbeans-platform-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die
	touch nb.cluster.platform.built

	popd >/dev/null || die

	java-pkg-2_src_prepare
}

src_install() {
	pushd nbbuild/netbeans/profiler >/dev/null || die

	insinto ${INSTALL_DIR}

	grep -E "/profiler$" ../moduleCluster.properties > "${D}"/${INSTALL_DIR}/moduleCluster.properties || die

	doins -r *

	for file in lib/deployed/cvm/linux/*.so ; do
		fperms 755 ${file}
	done

	for file in lib/deployed/jdk*/linux*/*.so ; do
		fperms 755 ${file}
	done

	for file in remote-pack-defs/*.sh ; do
		fperms 755 ${file}
	done

	popd >/dev/null || die

	dosym ${INSTALL_DIR} /usr/share/netbeans-nb-${SLOT}/profiler
}