[gentoo-commits] repo/gentoo:master commit in: net-analyzer/labrea/

[Jeroen Roovers]

commit:     01662c892aee64170e8b344d96d279d4f70fa374
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 27 13:24:53 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Sep 27 13:30:31 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=01662c89

net-analyzer/labrea: Move INSTALL out of the way

After running autoreconf, the INSTALL file will be magically replaced by
the generic GNU version. Move it before calling eautoreconf.

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 net-analyzer/labrea/labrea-2.5_p1.ebuild | 41 ++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/net-analyzer/labrea/labrea-2.5_p1.ebuild b/net-analyzer/labrea/labrea-2.5_p1.ebuild
new file mode 100644
index 00000000000..5c375b86225
--- /dev/null
+++ b/net-analyzer/labrea/labrea-2.5_p1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="'Sticky' Honeypot and IDS"
+HOMEPAGE="http://labrea.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P/_p*}-stable-${PV/*_p}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND="
+	net-libs/libpcap
+	>=dev-libs/libdnet-1.7
+"
+RDEPEND="
+	${DEPEND}
+"
+DOCS=( AUTHORS ChangeLog README{,.first} TODO NEWS )
+PATCHES=(
+	"${FILESDIR}"/${P/_p/-stable-}-incdir.patch
+	"${FILESDIR}"/${P/_p*}-pcap_open.patch
+)
+S=${WORKDIR}/${P/_p/-stable-}
+
+src_prepare() {
+	default
+
+	# autotools will overwrite this with the generic version
+	mv INSTALL README.first || die
+
+	eautoreconf
+}
+
+pkg_postinst() {
+	ewarn "Before using this package please read the README.first and README as"
+	ewarn "the author states that it can cause serious problems on your network"
+}