[gentoo-commits] gentoo-x86 commit in sys-fs/multipath-tools: ChangeLog multipath-tools-0.4.8-r1.ebuild

[Robin H. Johnson (robbat2)]

robbat2     09/10/30 06:50:12

  Modified:             ChangeLog
  Added:                multipath-tools-0.4.8-r1.ebuild
  Log:
  Upstream is a slacker and has not made a release in 2+ years despite being active in Git. Fixes bug #235836: udev scsi_id lost the -s option a long time ago. Bug #245615: remove the 1TiB limit on kpartx.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.27                 sys-fs/multipath-tools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -p -w -b -B -u -u -r1.26 -r1.27
--- ChangeLog	19 Sep 2009 04:47:49 -0000	1.26
+++ ChangeLog	30 Oct 2009 06:50:12 -0000	1.27
@@ -1,6 +1,16 @@
 # ChangeLog for sys-fs/multipath-tools
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v 1.26 2009/09/19 04:47:49 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/ChangeLog,v 1.27 2009/10/30 06:50:12 robbat2 Exp $
+
+*multipath-tools-0.4.8-r1 (30 Oct 2009)
+
+  30 Oct 2009; Robin H. Johnson <robbat2@g.o>
+  +files/init.d-multipath-0.4.8-r1, +multipath-tools-0.4.8-r1.ebuild,
+  +files/multipath-tools-0.4.8-r1-kpartx.patch,
+  +files/multipath-tools-0.4.8-udev-scsi_id-changes.patch:
+  Upstream is a slacker and has not made a release in 2+ years despite being
+  active in Git. Fixes bug #235836: udev scsi_id lost the -s option a long
+  time ago. Bug #245615: remove the 1TiB limit on kpartx.
 
   19 Sep 2009; Robin H. Johnson <robbat2@g.o>
   multipath-tools-0.4.8.ebuild:



1.1                  sys-fs/multipath-tools/multipath-tools-0.4.8-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: multipath-tools-0.4.8-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.8-r1.ebuild,v 1.1 2009/10/30 06:50:12 robbat2 Exp $

EAPI=2
inherit eutils toolchain-funcs

DESCRIPTION="Device mapper target autoconfig"
HOMEPAGE="http://christophe.varoqui.free.fr/"
SRC_URI="http://christophe.varoqui.free.fr/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE=""

RDEPEND="|| (
		>=sys-fs/lvm2-2.02.45
		>=sys-fs/device-mapper-1.00.19-r1
	)
	>=sys-fs/udev-124
	sys-fs/sysfsutils
	dev-libs/libaio"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.4.8-build.patch
	epatch "${FILESDIR}"/${PN}-0.4.8-udev-scsi_id-changes.patch
	# Patch per upstream tree for 1GiB limit of kpartx
	epatch "${FILESDIR}"/${PN}-0.4.8-r1-kpartx.patch
}

src_compile() {
	# The -j1 is NOT a joke. The 0.4.8-era upstream code rebuilds several object
	# files with different compiler defines. The upstream git, as yet unreleased
	# moves to proper automake, but it's a large jump and is not being
	# backported to 0.4.8.
	emake -j1 CC="$(tc-getCC)" || die "emake failed"
}

src_install() {
	dodir /sbin /usr/share/man/man8
	make DESTDIR="${D}" install || die "install failed"

	insinto /etc
	newins "${S}"/multipath.conf.annotated multipath.conf
	fperms 644 /etc/udev/rules.d/65-multipath.rules
	fperms 644 /etc/udev/rules.d/66-kpartx.rules
	# This is the monitoring daemon
	newinitd "${FILESDIR}"/rc-multipathd multipathd
	# This is the init script that fires the multipath addon for baselayout2
	newinitd "${FILESDIR}"/init.d-multipath-0.4.8-r1 multipath
	# Handle early-boot startup as well as shutdown of multipath devices
	insinto /lib/rcscripts/addons
	doins "${FILESDIR}"/multipath-start.sh
	doins "${FILESDIR}"/multipath-stop.sh

	dodoc multipath.conf.*
	dodoc AUTHOR ChangeLog FAQ README TODO
	docinto kpartx; dodoc kpartx/ChangeLog kpartx/README
}

pkg_preinst() {
	# The dev.d script was previously wrong and is now removed (the udev rules
	# file does the job instead), but it won't be removed from live systems due
	# to cfgprotect.
	# This should help out a little...
	if [[ -e ${ROOT}/etc/dev.d/block/multipath.dev ]] ; then
		mkdir -p "${D}"/etc/dev.d/block
		echo "# Please delete this file. It is obsoleted by /etc/udev/rules.d/65-multipath.rules" \
			> "${D}"/etc/dev.d/block/multipath.dev
	fi
}
pkg_postinst() {
	elog "If you need multipath on your system, you should ensure that a"
	elog "'multipath' entry is present in your RC_VOLUME_ORDER variable!"
	elog "If you use baselayout2, you must add 'multipath' into"
	elog "your boot runlevel!"
}