[gentoo-commits] repo/gentoo:master commit in: dev-libs/libappindicator/

[Pacho Ramos]

commit:     a392bc84fc0e36bd78218c3a1c691dd9c856aacc
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Wed May 26 12:23:43 2021 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Wed May 26 12:23:55 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a392bc84

dev-libs/libappindicator: Bump to latest snapshot used in Ubuntu

Bug: https://bugs.gentoo.org/569702
Closes: https://bugs.gentoo.org/621452
Closes: https://bugs.gentoo.org/706084
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-libs/libappindicator/Manifest                  |  1 +
 .../libappindicator-12.10.1_p20200706.ebuild       | 71 ++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-libs/libappindicator/Manifest b/dev-libs/libappindicator/Manifest
index 883177ca882..dd1b5ead3d1 100644
--- a/dev-libs/libappindicator/Manifest
+++ b/dev-libs/libappindicator/Manifest
@@ -1 +1,2 @@
 DIST libappindicator-12.10.0.tar.gz 535562 BLAKE2B a05dc839aaea9fb3fda118d16aac0eb5c35e6c5095a83eb5e8a2af4902bc1da14960fbd57d3cda5d4d5d874023549ce83657a515aa9ee16a54cadfa81062d993 SHA512 317a22a23c8ed84e74207b64b2e9683992d1fb7208176637a051dfe925974f966d1cfa31e650b45eaf839ab61641dee8fbebc8a07882a09b0dd766d88b8d5b9a
+DIST libappindicator_12.10.1+20.10.20200706.1.orig.tar.gz 75204 BLAKE2B ccc7909f25946413cf39275d8565afca253b3a2676272e4d3833f030a114e7be695fe958d2d99868a20d03a2b9c4a1fcd7fdfba07325b7a9f7f39879851e0366 SHA512 cc60875b1c4ab06348eece442a59a4057d7e13f25605435902242558e8dd5e66aeeee6725b9bd2662ef89052d3614dc4577ed8c233e9b84236a75e771aa67352

diff --git a/dev-libs/libappindicator/libappindicator-12.10.1_p20200706.ebuild b/dev-libs/libappindicator/libappindicator-12.10.1_p20200706.ebuild
new file mode 100644
index 00000000000..d9f65441712
--- /dev/null
+++ b/dev-libs/libappindicator/libappindicator-12.10.1_p20200706.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit autotools multilib-minimal vala
+
+DESCRIPTION="A library to allow applications to export a menu into the Unity Menu bar"
+HOMEPAGE="https://launchpad.net/libappindicator"
+
+MY_PV="${PV%_p*}"
+PATCH_VERSION="${PV#*_p}"
+SRC_URI="mirror://ubuntu/pool/main/liba/${PN}/${PN}_${MY_PV}+20.10.${PATCH_VERSION}.1.orig.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="+introspection test"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.98[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.35.4:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libdbusmenu-0.6.2[gtk3,${MULTILIB_USEDEP}]
+	>=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP},introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	introspection? ( $(vala_depend) )
+	>=dev-util/gtk-doc-am-1.14
+	virtual/pkgconfig
+	test? ( dev-util/dbus-test-runner )
+"
+
+S="${WORKDIR}"
+
+# FIXME: tests keep trying to access dirs they don't have access, feel free
+# to report a bug about how to avoid that
+RESTRICT="test"
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# Disable MONO for now because of https://bugs.gentoo.org/382491
+	sed -i -e '/^MONO_REQUIRED_VERSION/s:=.*:=9999:' configure || die
+}
+
+multilib_src_configure() {
+	if multilib_is_native_abi; then
+		local -x VALAC VALA_API_GEN VAPIGEN_VAPIDIR PKG_CONFIG_PATH
+		use introspection && vala_src_prepare && export VALA_API_GEN="${VAPIGEN}"
+	fi
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-static \
+		--with-gtk=3 \
+		$(multilib_native_use_enable introspection)
+}
+
+multilib_src_test() {
+	# Prevent tests from trying to write on /dev/fuse
+	GVFS_DISABLE_FUSE=1 dbus-run-session emake check
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}