1 |
zx2c4 14/01/03 15:07:58 |
2 |
|
3 |
Modified: ChangeLog |
4 |
Added: mpv-0.3.1.ebuild |
5 |
Removed: mpv-0.3.0.ebuild |
6 |
Log: |
7 |
Version bump for tiny bug fixes. |
8 |
|
9 |
(Portage version: 2.2.7/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key A5DE03AE) |
10 |
|
11 |
Revision Changes Path |
12 |
1.50 media-video/mpv/ChangeLog |
13 |
|
14 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mpv/ChangeLog?rev=1.50&view=markup |
15 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mpv/ChangeLog?rev=1.50&content-type=text/plain |
16 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mpv/ChangeLog?r1=1.49&r2=1.50 |
17 |
|
18 |
Index: ChangeLog |
19 |
=================================================================== |
20 |
RCS file: /var/cvsroot/gentoo-x86/media-video/mpv/ChangeLog,v |
21 |
retrieving revision 1.49 |
22 |
retrieving revision 1.50 |
23 |
diff -u -r1.49 -r1.50 |
24 |
--- ChangeLog 31 Dec 2013 11:23:39 -0000 1.49 |
25 |
+++ ChangeLog 3 Jan 2014 15:07:58 -0000 1.50 |
26 |
@@ -1,6 +1,12 @@ |
27 |
# ChangeLog for media-video/mpv |
28 |
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2 |
29 |
-# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/ChangeLog,v 1.49 2013/12/31 11:23:39 pinkbyte Exp $ |
30 |
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2 |
31 |
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/ChangeLog,v 1.50 2014/01/03 15:07:58 zx2c4 Exp $ |
32 |
+ |
33 |
+*mpv-0.3.1 (03 Jan 2014) |
34 |
+ |
35 |
+ 03 Jan 2014; Jason A. Donenfeld <zx2c4@g.o> +mpv-0.3.1.ebuild, |
36 |
+ -mpv-0.3.0.ebuild: |
37 |
+ Version bump for tiny bug fixes. |
38 |
|
39 |
31 Dec 2013; Sergey Popov <pinkbyte@g.o> mpv-0.3.0.ebuild, |
40 |
mpv-9999.ebuild: |
41 |
|
42 |
|
43 |
|
44 |
1.1 media-video/mpv/mpv-0.3.1.ebuild |
45 |
|
46 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mpv/mpv-0.3.1.ebuild?rev=1.1&view=markup |
47 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mpv/mpv-0.3.1.ebuild?rev=1.1&content-type=text/plain |
48 |
|
49 |
Index: mpv-0.3.1.ebuild |
50 |
=================================================================== |
51 |
# Copyright 1999-2014 Gentoo Foundation |
52 |
# Distributed under the terms of the GNU General Public License v2 |
53 |
# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/mpv-0.3.1.ebuild,v 1.1 2014/01/03 15:07:58 zx2c4 Exp $ |
54 |
|
55 |
EAPI=5 |
56 |
|
57 |
EGIT_REPO_URI="https://github.com/mpv-player/mpv.git" |
58 |
|
59 |
inherit base waf-utils pax-utils |
60 |
[[ ${PV} == *9999* ]] && inherit git-r3 |
61 |
|
62 |
DESCRIPTION="Video player based on MPlayer/mplayer2" |
63 |
HOMEPAGE="http://mpv.io/" |
64 |
SRC_URI="https://waf.googlecode.com/files/waf-1.7.13" |
65 |
[[ ${PV} == *9999* ]] || \ |
66 |
SRC_URI+=" https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz" |
67 |
|
68 |
LICENSE="GPL-2" |
69 |
SLOT="0" |
70 |
[[ ${PV} == *9999* ]] || \ |
71 |
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux" |
72 |
IUSE="+alsa bluray bs2b +cdio -doc-pdf dvb +dvd dvdnav +enca encode +iconv jack -joystick |
73 |
jpeg ladspa lcms +libass libcaca libguess lirc lua luajit +mpg123 -openal +opengl |
74 |
oss portaudio +postproc pulseaudio pvr +quvi -radio samba +shm v4l vaapi vcd vdpau |
75 |
vf-dlopen wayland +X xinerama +xscreensaver +xv" |
76 |
|
77 |
REQUIRED_USE=" |
78 |
dvdnav? ( dvd ) |
79 |
enca? ( iconv ) |
80 |
lcms? ( opengl ) |
81 |
libguess? ( iconv ) |
82 |
luajit? ( lua ) |
83 |
opengl? ( || ( wayland X ) ) |
84 |
pvr? ( v4l ) |
85 |
radio? ( v4l || ( alsa oss ) ) |
86 |
vaapi? ( X ) |
87 |
vdpau? ( X ) |
88 |
wayland? ( opengl ) |
89 |
xinerama? ( X ) |
90 |
xscreensaver? ( X ) |
91 |
xv? ( X ) |
92 |
" |
93 |
|
94 |
RDEPEND+=" |
95 |
|| ( |
96 |
>=media-video/libav-9:=[encode?,threads,vaapi?,vdpau?] |
97 |
>=media-video/ffmpeg-1.2:0=[encode?,threads,vaapi?,vdpau?] |
98 |
) |
99 |
sys-libs/ncurses |
100 |
sys-libs/zlib |
101 |
X? ( |
102 |
x11-libs/libXext |
103 |
x11-libs/libXxf86vm |
104 |
opengl? ( virtual/opengl ) |
105 |
lcms? ( media-libs/lcms:2 ) |
106 |
vaapi? ( >=x11-libs/libva-0.34.0[X(+)] ) |
107 |
vdpau? ( >=x11-libs/libvdpau-0.2 ) |
108 |
xinerama? ( x11-libs/libXinerama ) |
109 |
xscreensaver? ( x11-libs/libXScrnSaver ) |
110 |
xv? ( x11-libs/libXv ) |
111 |
) |
112 |
alsa? ( media-libs/alsa-lib ) |
113 |
bluray? ( >=media-libs/libbluray-0.2.1 ) |
114 |
bs2b? ( media-libs/libbs2b ) |
115 |
cdio? ( |
116 |
|| ( |
117 |
dev-libs/libcdio-paranoia |
118 |
<dev-libs/libcdio-0.90[-minimal] |
119 |
) |
120 |
) |
121 |
dvb? ( virtual/linuxtv-dvb-headers ) |
122 |
dvd? ( |
123 |
>=media-libs/libdvdread-4.1.3 |
124 |
dvdnav? ( >=media-libs/libdvdnav-4.2.0 ) |
125 |
) |
126 |
enca? ( app-i18n/enca ) |
127 |
iconv? ( virtual/libiconv ) |
128 |
jack? ( media-sound/jack-audio-connection-kit ) |
129 |
jpeg? ( virtual/jpeg ) |
130 |
ladspa? ( media-libs/ladspa-sdk ) |
131 |
libass? ( |
132 |
>=media-libs/libass-0.9.10[enca?,fontconfig] |
133 |
virtual/ttf-fonts |
134 |
) |
135 |
libcaca? ( >=media-libs/libcaca-0.99_beta18 ) |
136 |
libguess? ( >=app-i18n/libguess-1.0 ) |
137 |
lirc? ( app-misc/lirc ) |
138 |
lua? ( |
139 |
!luajit? ( >=dev-lang/lua-5.1 ) |
140 |
luajit? ( dev-lang/luajit:2 ) |
141 |
) |
142 |
mpg123? ( >=media-sound/mpg123-1.14.0 ) |
143 |
openal? ( >=media-libs/openal-1.13 ) |
144 |
portaudio? ( >=media-libs/portaudio-19_pre20111121 ) |
145 |
postproc? ( |
146 |
|| ( |
147 |
media-libs/libpostproc |
148 |
>=media-video/ffmpeg-1.2:0[encode?,threads,vaapi?,vdpau?] |
149 |
) |
150 |
) |
151 |
pulseaudio? ( media-sound/pulseaudio ) |
152 |
quvi? ( |
153 |
>=media-libs/libquvi-0.4.1:= |
154 |
|| ( |
155 |
>=media-video/libav-9[network] |
156 |
>=media-video/ffmpeg-1.2:0[network] |
157 |
) |
158 |
) |
159 |
samba? ( net-fs/samba ) |
160 |
v4l? ( media-libs/libv4l ) |
161 |
wayland? ( |
162 |
>=dev-libs/wayland-1.2.0 |
163 |
media-libs/mesa[egl,wayland] |
164 |
>=x11-libs/libxkbcommon-0.3.0 |
165 |
) |
166 |
" |
167 |
ASM_DEP="dev-lang/yasm" |
168 |
DEPEND="${RDEPEND} |
169 |
virtual/pkgconfig |
170 |
>=dev-lang/perl-5.8 |
171 |
dev-python/docutils |
172 |
doc-pdf? ( |
173 |
dev-texlive/texlive-latex |
174 |
dev-texlive/texlive-latexrecommended |
175 |
dev-texlive/texlive-latexextra |
176 |
dev-tex/xcolor |
177 |
) |
178 |
X? ( |
179 |
x11-proto/videoproto |
180 |
x11-proto/xf86vidmodeproto |
181 |
xinerama? ( x11-proto/xineramaproto ) |
182 |
xscreensaver? ( x11-proto/scrnsaverproto ) |
183 |
) |
184 |
amd64? ( ${ASM_DEP} ) |
185 |
x86? ( ${ASM_DEP} ) |
186 |
x86-fbsd? ( ${ASM_DEP} ) |
187 |
" |
188 |
DOCS=( Copyright README.md etc/example.conf etc/input.conf ) |
189 |
|
190 |
pkg_setup() { |
191 |
if use !libass; then |
192 |
ewarn |
193 |
ewarn "You've disabled the libass flag. No OSD or subtitles will be displayed." |
194 |
fi |
195 |
|
196 |
einfo "For additional format support you need to enable the support on your" |
197 |
einfo "libavcodec/libavformat provider:" |
198 |
einfo " media-video/libav or media-video/ffmpeg" |
199 |
} |
200 |
|
201 |
src_unpack() { |
202 |
if [[ ${PV} == *9999* ]]; then |
203 |
git-r3_src_unpack |
204 |
else |
205 |
default_src_unpack |
206 |
fi |
207 |
|
208 |
cp "${DISTDIR}"/waf-1.7.13 "${S}"/waf || die |
209 |
chmod 0755 "${S}"/waf || die |
210 |
} |
211 |
|
212 |
src_prepare() { |
213 |
base_src_prepare |
214 |
} |
215 |
|
216 |
src_configure() { |
217 |
# keep build reproducible |
218 |
# do not add -g to CFLAGS |
219 |
# SDL output is fallback for platforms where nothing better is available |
220 |
# media-sound/rsound is in pro-audio overlay only |
221 |
waf-utils_src_configure \ |
222 |
--disable-build-date \ |
223 |
--disable-debug-build \ |
224 |
--disable-sdl \ |
225 |
--disable-sdl2 \ |
226 |
--disable-rsound \ |
227 |
$(use_enable encode encoding) \ |
228 |
$(use_enable joystick) \ |
229 |
$(use_enable bluray libbluray) \ |
230 |
$(use_enable vcd) \ |
231 |
$(use_enable quvi libquvi) \ |
232 |
$(use_enable samba libsmbclient) \ |
233 |
$(use_enable lirc) \ |
234 |
$(use_enable lua) \ |
235 |
$(usex luajit '--lua=luajit' '') \ |
236 |
$(use_enable doc-pdf pdf-build) \ |
237 |
$(use_enable vf-dlopen vf-dlopen-filters) \ |
238 |
$(use_enable cdio cdda) \ |
239 |
$(use_enable dvd dvdread) \ |
240 |
$(use_enable dvdnav) \ |
241 |
$(use_enable enca) \ |
242 |
$(use_enable iconv) \ |
243 |
$(use_enable libass) \ |
244 |
$(use_enable libguess) \ |
245 |
$(use_enable dvb) \ |
246 |
$(use_enable pvr) \ |
247 |
$(use_enable v4l libv4l2) \ |
248 |
$(use_enable v4l tv) \ |
249 |
$(use_enable v4l tv-v4l2) \ |
250 |
$(use_enable radio) \ |
251 |
$(use_enable radio radio-capture) \ |
252 |
$(use_enable radio radio-v4l2) \ |
253 |
$(use_enable mpg123) \ |
254 |
$(use_enable jpeg) \ |
255 |
$(use_enable libcaca caca) \ |
256 |
$(use_enable postproc libpostproc) \ |
257 |
$(use_enable alsa) \ |
258 |
$(use_enable jack) \ |
259 |
$(use_enable ladspa) \ |
260 |
$(use_enable portaudio) \ |
261 |
$(use_enable bs2b libbs2b) \ |
262 |
$(use_enable openal) \ |
263 |
$(use_enable oss oss-audio) \ |
264 |
$(use_enable pulseaudio pulse) \ |
265 |
$(use_enable shm) \ |
266 |
$(use_enable X x11) \ |
267 |
$(use_enable vaapi) \ |
268 |
$(use_enable vdpau) \ |
269 |
$(use_enable wayland) \ |
270 |
$(use_enable xinerama) \ |
271 |
$(use_enable xv) \ |
272 |
$(use_enable opengl gl) \ |
273 |
$(use_enable lcms lcms2) \ |
274 |
$(use_enable xscreensaver xss) \ |
275 |
--confdir="${EPREFIX}"/etc/${PN} \ |
276 |
--mandir="${EPREFIX}"/usr/share/man \ |
277 |
--docdir="${EPREFIX}"/usr/share/doc/${PF} |
278 |
} |
279 |
|
280 |
src_install() { |
281 |
waf-utils_src_install |
282 |
|
283 |
if use luajit; then |
284 |
pax-mark -m "${ED}"usr/bin/mpv |
285 |
fi |
286 |
} |