[gentoo-commits] gentoo-x86 commit in dev-libs/gobject-introspection: ChangeLog gobject-introspection-1.34.2-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/12/29 10:35:10

  Modified:             ChangeLog
  Added:                gobject-introspection-1.34.2-r1.ebuild
  Log:
  Print the filename and line being parsed if g-ir-scanner crashes while parsing a gtk-doc annotation. Update to EAPI5 and python-single-r1.
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

Revision  Changes    Path
1.85                 dev-libs/gobject-introspection/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gobject-introspection/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gobject-introspection/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gobject-introspection/ChangeLog?r1=1.84&r2=1.85

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/gobject-introspection/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog	9 Dec 2012 18:33:49 -0000	1.84
+++ ChangeLog	29 Dec 2012 10:35:10 -0000	1.85
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/gobject-introspection
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gobject-introspection/ChangeLog,v 1.84 2012/12/09 18:33:49 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gobject-introspection/ChangeLog,v 1.85 2012/12/29 10:35:10 tetromino Exp $
+
+*gobject-introspection-1.34.2-r1 (29 Dec 2012)
+
+  29 Dec 2012; Alexandre Rostovtsev <tetromino@g.o>
+  +gobject-introspection-1.34.2-r1.ebuild,
+  +files/gobject-introspection-1.34.2-better-traceback.patch:
+  Print the filename and line being parsed if g-ir-scanner crashes while
+  parsing a gtk-doc annotation. Update to EAPI5 and python-single-r1.
 
   09 Dec 2012; Alexandre Rostovtsev <tetromino@g.o>
   gobject-introspection-1.30.0-r2.ebuild, gobject-introspection-1.32.1.ebuild,



1.1                  dev-libs/gobject-introspection/gobject-introspection-1.34.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gobject-introspection/gobject-introspection-1.34.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gobject-introspection/gobject-introspection-1.34.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gobject-introspection-1.34.2-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/gobject-introspection/gobject-introspection-1.34.2-r1.ebuild,v 1.1 2012/12/29 10:35:10 tetromino Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="xml"

inherit eutils gnome2 python-single-r1 toolchain-funcs

DESCRIPTION="Introspection infrastructure for generating gobject library bindings for various languages"
HOMEPAGE="http://live.gnome.org/GObjectIntrospection/"

LICENSE="LGPL-2+ GPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"

IUSE="doctool test"

RDEPEND="
	>=dev-libs/gobject-introspection-common-${PV}
	>=dev-libs/glib-2.34.1:2
	doctool? ( dev-python/mako )
	virtual/libffi:=
"
# Wants real bison, not virtual/yacc
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.15
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig
"
# PDEPEND to avoid circular dependencies, bug #391213
PDEPEND="x11-libs/cairo[glib]"

pkg_setup() {
	python-single-r1_pkg_setup
}

src_prepare() {
	# To prevent crosscompiling problems, bug #414105
	CC=$(tc-getCC)

	DOCS="AUTHORS CONTRIBUTORS ChangeLog NEWS README TODO"
	G2CONF="${G2CONF}
		--disable-static
		YACC=$(type -p yacc)
		$(use_enable doctool)
		$(use_enable test tests)"

	# https://bugzilla.gnome.org/show_bug.cgi?id=690850
	epatch "${FILESDIR}/${PN}-1.34.2-better-traceback.patch"

	gnome2_src_prepare

	# avoid GNU-isms
	sed -i -e 's/\(if test .* \)==/\1=/' configure || die

	gi_skip_tests=
	if ! has_version "x11-libs/cairo[glib]"; then
		# Bug #391213: enable cairo-gobject support even if it's not installed
		# We only PDEPEND on cairo to avoid circular dependencies
		export CAIRO_LIBS="-lcairo -lcairo-gobject"
		export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
		if use test; then
			G2CONF="${G2CONF} --disable-tests"
			gi_skip_tests=yes
			ewarn "Tests will be skipped because x11-libs/cairo[glib] is not present"
			ewarn "on your system. Consider installing it to get tests to run."
		fi
	fi
}

src_test() {
	[[ -z ${gi_skip_tests} ]] && default
}

src_install() {
	gnome2_src_install

	# Prevent collision with gobject-introspection-common
	rm -v "${ED}"usr/share/aclocal/introspection.m4 \
		"${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
	rmdir "${ED}"usr/share/aclocal || die
}