[gentoo-commits] gentoo-x86 commit in app-benchmarks/ltp: ltp-20140828.ebuild ChangeLog ltp-20130109.ebuild ltp-20120903.ebuild

[Markos Chandras (hwoarang)]

hwoarang    14/09/02 19:43:00

  Modified:             ChangeLog
  Added:                ltp-20140828.ebuild
  Removed:              ltp-20130109.ebuild ltp-20120903.ebuild
  Log:
  Version bump. Remove old
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

Revision  Changes    Path
1.26                 app-benchmarks/ltp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/ltp/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/ltp/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/ltp/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-benchmarks/ltp/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	20 Jul 2013 15:35:55 -0000	1.25
+++ ChangeLog	2 Sep 2014 19:43:00 -0000	1.26
@@ -1,6 +1,12 @@
 # ChangeLog for app-benchmarks/ltp
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-benchmarks/ltp/ChangeLog,v 1.25 2013/07/20 15:35:55 jer Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-benchmarks/ltp/ChangeLog,v 1.26 2014/09/02 19:43:00 hwoarang Exp $
+
+*ltp-20140828 (02 Sep 2014)
+
+  02 Sep 2014; Markos Chandras <hwoarang@g.o> +ltp-20140828.ebuild,
+  -ltp-20120903.ebuild, -ltp-20130109.ebuild:
+  Version bump. Remove old
 
   20 Jul 2013; Jeroen Roovers <jer@g.o> ltp-20130503.ebuild:
   Marked ~hppa too.



1.1                  app-benchmarks/ltp/ltp-20140828.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/ltp/ltp-20140828.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-benchmarks/ltp/ltp-20140828.ebuild?rev=1.1&content-type=text/plain

Index: ltp-20140828.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-benchmarks/ltp/ltp-20140828.ebuild,v 1.1 2014/09/02 19:43:00 hwoarang Exp $

EAPI="4"

inherit autotools eutils readme.gentoo

MY_PN="${PN}-full"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="A testsuite for the linux kernel"
HOMEPAGE="http://ltp.sourceforge.net/"
SRC_URI="mirror://sourceforge/ltp/LTP%20Source/${P}/${MY_P}.tar.bz2 -> ${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~amd64 ~hppa ~ppc ~x86"
IUSE="expect perl pm open-posix python rt"

DEPEND="expect? ( dev-tcltk/expect )
	perl? ( dev-lang/perl )
	python? ( dev-lang/python )"

RESTRICT="test"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	# Don't create groups
	export CREATE=0

	DOC_CONTENTS="LTP requires root access to run the tests.
		The LTP root directory is located in /opt/${PN}.
		For more information please read the ltp-howto located in
		/usr/share/doc/${PF}"
}

src_prepare() {
	# regenerate
	AT_M4DIR="m4" eautoreconf
}

src_configure() {
	# FIXME: improve me
	local myconf=
	use open-posix && myconf+="--with-open-posix-testsuite "
	use pm && mytconf+="--with-power-management-testsuite "
	use rt && myconf+="--with-realtime-testsuite "
	use perl && myconf+="--with-perl "
	use python && myconf+="--with-python "
	use expect && myconf+="--with-expect "
	# Prevent any kernel stuff for now as it leads to sandbox violations
	myconf+="--without-modules --with-linux-dir=/dev/null"

	# Better put it into /opt/${PN} as everything needs to
	# be under the same directory..

	econf --prefix=/opt/${PN} ${myconf}
}

src_compile() {
	# Posix testsuite does not seem to build with -j>1
	# Is this maintained anymore?
	if use open-posix; then
		export MAKEOPTS="-j1"
	fi
	emake
}

src_install() {
	default
	dosym /usr/libexec/${PN}/runltp /usr/bin/runltp
	# install docs
	dodoc doc/MaintNotes
	for txt in doc/*.txt; do
		dodoc ${txt}
	done
	dodoc -r doc/examples doc/testcases
	dohtml -r doc/automation-*.html
	doman doc/man1/*.1
	doman doc/man3/*.3
	readme.gentoo_create_doc
}