[gentoo-commits] repo/gentoo:master commit in: x11-misc/trayer/

[David Seifert]

commit:     b8f9aa4340cc676f691d235cd2fbf4e445898938
Author:     Harri Nieminen <moikkis <AT> gmail <DOT> com>
AuthorDate: Mon Feb 13 17:00:17 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Tue Feb 14 19:44:06 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b8f9aa43

x11-misc/trayer: EAPI bump 4 -> 6

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/3957

 x11-misc/trayer/trayer-1.0-r2.ebuild | 51 ++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/x11-misc/trayer/trayer-1.0-r2.ebuild b/x11-misc/trayer/trayer-1.0-r2.ebuild
new file mode 100644
index 0000000000..be69dd0547
--- /dev/null
+++ b/x11-misc/trayer/trayer-1.0-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit toolchain-funcs
+
+DESCRIPTION="Lightweight GTK+ based systray for UNIX desktop"
+HOMEPAGE="http://home.gna.org/fvwm-crystal/"
+SRC_URI="http://download.gna.org/fvwm-crystal/trayer/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/libX11
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	# fix for as-needed, bug #141707
+	# fix pre-stripped files, bug #252098
+	sed -i Makefile \
+		-e 's:$(LIBS) $(OBJ) $(SYSTRAYOBJ):$(OBJ) $(SYSTRAYOBJ) $(LIBS):' \
+		-e 's:strip:true:g' \
+		|| die
+	# fix underlinking, bug #369591
+	sed -i Makefile.common \
+		-e '/^LIBS/s:).*: x11):' \
+		-e '/^INC/s:).*: x11):' \
+		|| die
+}
+
+src_compile() {
+	emake -j1 CC=$(tc-getCC) CFLAGS="${CFLAGS}" CPPFLAGS="${CPPFLAGS}"
+}
+
+src_install() {
+	dobin trayer
+	doman trayer.1
+	einstalldocs
+}