[gentoo-commits] gentoo-x86 commit in net-irc/xchat: ChangeLog xchat-2.8.6-r2.ebuild xchat-2.8.4-r3.ebuild

[Raul Porcel (armin76)]

armin76     08/11/27 20:49:59

  Modified:             ChangeLog
  Added:                xchat-2.8.6-r2.ebuild
  Removed:              xchat-2.8.4-r3.ebuild
  Log:
  Don't use included libsexy, bug #246138, make shm pixmaps optional, bug #241902
  (Portage version: 2.1.6_rc2/cvs/Linux 2.6.26-gentoo-r2 i686)

Revision  Changes    Path
1.274                net-irc/xchat/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/xchat/ChangeLog?rev=1.274&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/xchat/ChangeLog?rev=1.274&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/xchat/ChangeLog?r1=1.273&r2=1.274

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/xchat/ChangeLog,v
retrieving revision 1.273
retrieving revision 1.274
diff -u -r1.273 -r1.274
--- ChangeLog	28 Sep 2008 06:29:46 -0000	1.273
+++ ChangeLog	27 Nov 2008 20:49:59 -0000	1.274
@@ -1,6 +1,15 @@
 # ChangeLog for net-irc/xchat
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/ChangeLog,v 1.273 2008/09/28 06:29:46 leio Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/ChangeLog,v 1.274 2008/11/27 20:49:59 armin76 Exp $
+
+*xchat-2.8.6-r2 (27 Nov 2008)
+
+  27 Nov 2008; Raúl Porcel <armin76@g.o>
+  -files/xc284-fix-scrollbfdleak.diff, -files/xc284-scrollbmkdir.diff,
+  +files/xchat-2.8.6-shm-pixmaps.patch, -files/xc284-improvescrollback.diff,
+  -files/xchat-fix-uk_UA-locale.diff, -xchat-2.8.4-r3.ebuild,
+  +xchat-2.8.6-r2.ebuild:
+  Don't use included libsexy, bug #246138, make shm pixmaps optional, bug #241902
 
   28 Sep 2008; Mart Raudsepp <leio@g.o> xchat-2.8.6-r1.ebuild:
   Fix compile against gtk+-2.14 by being forwards compatible, bug 234458



1.1                  net-irc/xchat/xchat-2.8.6-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/xchat/xchat-2.8.6-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/xchat/xchat-2.8.6-r2.ebuild?rev=1.1&content-type=text/plain

Index: xchat-2.8.6-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/xchat-2.8.6-r2.ebuild,v 1.1 2008/11/27 20:49:59 armin76 Exp $

inherit eutils versionator gnome2

DESCRIPTION="Graphical IRC client"
SRC_URI="http://www.xchat.org/files/source/$(get_version_component_range 1-2)/${P}.tar.bz2
	mirror://sourceforge/${PN}/${P}.tar.bz2
	xchatdccserver? ( mirror://gentoo/${PN}-dccserver-0.6.patch.bz2 )"
HOMEPAGE="http://www.xchat.org/"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="perl dbus tcl python ssl mmx ipv6 libnotify nls spell xchatnogtk xchatdccserver xft"

RDEPEND=">=dev-libs/glib-2.6.0
	!xchatnogtk? ( >=x11-libs/gtk+-2.10.0 )
	ssl? ( >=dev-libs/openssl-0.9.6d )
	perl? ( >=dev-lang/perl-5.6.1 )
	python? ( >=dev-lang/python-2.2 )
	tcl? ( dev-lang/tcl )
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	spell? ( app-text/gtkspell )
	libnotify? ( x11-libs/libnotify )
	!<net-irc/xchat-gnome-0.9"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.7
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	use xchatdccserver && epatch "${DISTDIR}"/xchat-dccserver-0.6.patch.bz2

	# use libdir/xchat/plugins as the plugin directory
	if [ $(get_libdir) != "lib" ] ; then
		sed -i -e 's:${prefix}/lib/xchat:${libdir}/xchat:' \
			"${S}"/configure{,.in} || die
	fi

	epatch "${FILESDIR}"/xc286-smallfixes.diff
	epatch "${FILESDIR}"/${P}-shm-pixmaps.patch

	# don't disable deprecated gtk+ symbols, it's not forwards compatible, bug 234458
	sed -i -e '/define GTK_DISABLE_DEPRECATED/d' src/fe-gtk/*.c
}

src_compile() {
	# Added for to fix a sparc seg fault issue by Jason Wever <weeve@g.o>
	if [[ ${ARCH} = sparc ]] ; then
		replace-flags "-O[3-9]" "-O2"
	fi

	# xchat's configure script uses sys.path to find library path
	# instead of python-config (#25943)
	unset PYTHONPATH

	econf \
		--enable-shm \
		$(use_enable ssl openssl) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable tcl) \
		$(use_enable mmx) \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use_enable dbus) \
		$(use_enable xft) \
		$(use_enable spell spell gtkspell) \
		$(use_enable !xchatnogtk gtkfe) \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	USE_DESTDIR=1 gnome2_src_install || die "make install failed"

	# install plugin development header
	insinto /usr/include/xchat
	doins src/common/xchat-plugin.h || die "doins failed"

	dodoc ChangeLog README* || die "dodoc failed"
}

pkg_postinst() {
	elog
	elog "XChat binary has been renamed from xchat-2 to xchat."
	elog

	if has_version net-irc/xchat-systray
	then
		elog "XChat now includes it's own systray icon, you may want to remove net-irc/xchat-systray."
		elog
	fi
}