[gentoo-commits] gentoo-x86 commit in dev-util/cola: ChangeLog cola-1.4.0.1.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    09/11/03 09:04:28

  Modified:             ChangeLog
  Added:                cola-1.4.0.1.ebuild
  Log:
  Version bump, fixed doc deps and doc installation ^Cug #291439, thanks to Man Shankar).
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  dev-util/cola/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/cola/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/cola/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/cola/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/cola/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	26 Aug 2009 08:50:14 -0000	1.4
+++ ChangeLog	3 Nov 2009 09:04:27 -0000	1.5
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/cola
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/cola/ChangeLog,v 1.4 2009/08/26 08:50:14 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/cola/ChangeLog,v 1.5 2009/11/03 09:04:27 dev-zero Exp $
+
+*cola-1.4.0.1 (03 Nov 2009)
+
+  03 Nov 2009; Tiziano Müller <dev-zero@g.o> +cola-1.4.0.1.ebuild,
+  +files/index.html:
+  Version bump, fixed doc deps and doc installation ^Cug #291439, thanks to
+  Man Shankar).
 
 *cola-1.3.9.14 (26 Aug 2009)
 



1.1                  dev-util/cola/cola-1.4.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/cola/cola-1.4.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/cola/cola-1.4.0.1.ebuild?rev=1.1&content-type=text/plain

Index: cola-1.4.0.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/cola/cola-1.4.0.1.ebuild,v 1.1 2009/11/03 09:04:27 dev-zero Exp $

EAPI="2"

inherit distutils eutils

DESCRIPTION="A sweet, carbonated git gui known for its sugary flavour and caffeine-inspired features."
HOMEPAGE="http://cola.tuxfamily.org/"
SRC_URI="http://cola.tuxfamily.org/releases/${P}-src.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"

RDEPEND="dev-python/PyQt4
	|| ( >=dev-lang/python-2.6 ( =dev-lang/python-2.5* dev-python/simplejson ) )
	>=dev-python/pyinotify-0.7.1
	dev-python/jsonpickle
	dev-util/git"
DEPEND="${RDEPEND}
	doc? ( app-text/asciidoc
		dev-python/sphinx
		app-text/xmlto )
	test? ( dev-python/nose )"

src_prepare() {
	# don't install docs into wrong location
	sed -i \
		-e '/doc/d' \
		setup.py || die "sed failed"

	sed -i \
		-e  "s|'doc', 'git-cola'|'doc', '${PF}', 'html'|" \
		-e 's|git-cola.html|index.html|' \
		cola/resources.py || die "sed failed"

	# don't prefix install path with homedir
	rm setup.cfg

	epatch "${FILESDIR}/1.3.8-disable-tests.patch"
}

src_compile() {
	distutils_src_compile

	if use doc ; then
		cd share/doc/git-cola/
		emake all || die "building docs failed"
	fi
}

src_install() {
	distutils_src_install

	# remove bundled libraries
	rm -rf "${D}"/usr/share/git-cola/lib/{jsonpickle,simplejson}

	cd share/doc/git-cola/
	dodoc *.txt

	if use doc ; then
		dohtml -r _build/html/*
		doman *.1
	else
		dohtml "${FILESDIR}/index.html"
	fi
}

src_test() {
	PYTHONPATH="$(pwd):$(pwd)/build/lib:${PYTHONPATH}" nosetests \
		--verbose --with-doctest --with-id --exclude=jsonpickle --exclude=json \
		|| die "running nosetests failed"
}

pkg_postinst() {
	python_mod_optimize /usr/share/git-cola
}

pkg_postrm() {
	python_mod_cleanup /usr/share/git-cola
}