[gentoo-commits] repo/gentoo:master commit in: kde-plasma/kwayland-integration/

[Andreas Sturmlechner]

commit:     bb62ab926640f615bb4dd4cdb57c92daab6fae16
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  7 14:12:26 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Nov 27 12:01:40 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bb62ab92

kde-plasma/kwayland-integration: Drop idletime plugin in 5.25.5 too

By raising KFMIN to 5.99.0.

>=kde-frameworks/kidletime-5.99[wayland] now contains a replacement
plugin so we can disable it here to only keep windowsystem plugin.

Bug: https://bugs.gentoo.org/790275
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kwayland-integration-5.25.5-r1.ebuild          | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/kde-plasma/kwayland-integration/kwayland-integration-5.25.5-r1.ebuild b/kde-plasma/kwayland-integration/kwayland-integration-5.25.5-r1.ebuild
new file mode 100644
index 000000000000..d854bc8c167f
--- /dev/null
+++ b/kde-plasma/kwayland-integration/kwayland-integration-5.25.5-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.99.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Provides integration plugins for various KDE frameworks for Wayland"
+HOMEPAGE="https://invent.kde.org/plasma/kwayland-integration"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+# dev-qt/qtgui: QtXkbCommonSupport is provided by either IUSE libinput or X
+# slot ops:
+# dev-qt/qtwayland: Qt::WaylandClientPrivate (private/qwayland*_p.h) stuff
+# kde-frameworks/kwindowsystem: Various private headers
+DEPEND="
+	>=dev-libs/wayland-1.15
+	|| (
+		>=dev-qt/qtgui-${QTMIN}:5[libinput]
+		>=dev-qt/qtgui-${QTMIN}:5[X]
+	)
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtwayland-${QTMIN}:5=
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5=
+	x11-libs/libxkbcommon
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-qt/qtwaylandscanner-${QTMIN}:5
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_kf_module IdleTime
+	cmake_comment_add_subdirectory autotests # only contains idletime test
+	cmake_run_in src cmake_comment_add_subdirectory idletime
+}