| 1 |
dirtyepic 13/12/30 08:21:04 |
| 2 |
|
| 3 |
Added: wxwin.m4-3.0 |
| 4 |
Log: |
| 5 |
Version bump. Fixes bug #448074 (do not set profile to "none" if there are |
| 6 |
others available). Remove 2.6 suppport, add 3.0 support. |
| 7 |
|
| 8 |
Signed-off-by: Ryan Hill <dirtyepic@g.o> |
| 9 |
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 957A8463) |
| 10 |
|
| 11 |
Revision Changes Path |
| 12 |
1.1 app-admin/eselect-wxwidgets/files/wxwin.m4-3.0 |
| 13 |
|
| 14 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-wxwidgets/files/wxwin.m4-3.0?rev=1.1&view=markup |
| 15 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/eselect-wxwidgets/files/wxwin.m4-3.0?rev=1.1&content-type=text/plain |
| 16 |
|
| 17 |
Index: wxwin.m4-3.0 |
| 18 |
=================================================================== |
| 19 |
dnl --------------------------------------------------------------------------- |
| 20 |
dnl Author: wxWidgets development team, |
| 21 |
dnl Francesco Montorsi, |
| 22 |
dnl Bob McCown (Mac-testing) |
| 23 |
dnl Creation date: 24/11/2001 |
| 24 |
dnl --------------------------------------------------------------------------- |
| 25 |
|
| 26 |
dnl =========================================================================== |
| 27 |
dnl Table of Contents of this macro file: |
| 28 |
dnl ------------------------------------- |
| 29 |
dnl |
| 30 |
dnl SECTION A: wxWidgets main macros |
| 31 |
dnl - WX_CONFIG_OPTIONS |
| 32 |
dnl - WX_CONFIG_CHECK |
| 33 |
dnl - WXRC_CHECK |
| 34 |
dnl - WX_STANDARD_OPTIONS |
| 35 |
dnl - WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS |
| 36 |
dnl - WX_DETECT_STANDARD_OPTION_VALUES |
| 37 |
dnl |
| 38 |
dnl SECTION B: wxWidgets-related utilities |
| 39 |
dnl - WX_LIKE_LIBNAME |
| 40 |
dnl - WX_ARG_ENABLE_YESNOAUTO |
| 41 |
dnl - WX_ARG_WITH_YESNOAUTO |
| 42 |
dnl |
| 43 |
dnl SECTION C: messages to the user |
| 44 |
dnl - WX_STANDARD_OPTIONS_SUMMARY_MSG |
| 45 |
dnl - WX_STANDARD_OPTIONS_SUMMARY_MSG_BEGIN |
| 46 |
dnl - WX_STANDARD_OPTIONS_SUMMARY_MSG_END |
| 47 |
dnl - WX_BOOLOPT_SUMMARY |
| 48 |
dnl |
| 49 |
dnl The special "WX_DEBUG_CONFIGURE" variable can be set to 1 to enable extra |
| 50 |
dnl debug output on stdout from these macros. |
| 51 |
dnl =========================================================================== |
| 52 |
|
| 53 |
|
| 54 |
dnl --------------------------------------------------------------------------- |
| 55 |
dnl Macros for wxWidgets detection. Typically used in configure.in as: |
| 56 |
dnl |
| 57 |
dnl AC_ARG_ENABLE(...) |
| 58 |
dnl AC_ARG_WITH(...) |
| 59 |
dnl ... |
| 60 |
dnl WX_CONFIG_OPTIONS |
| 61 |
dnl ... |
| 62 |
dnl ... |
| 63 |
dnl WX_CONFIG_CHECK([2.6.0], [wxWin=1]) |
| 64 |
dnl if test "$wxWin" != 1; then |
| 65 |
dnl AC_MSG_ERROR([ |
| 66 |
dnl wxWidgets must be installed on your system |
| 67 |
dnl but wx-config script couldn't be found. |
| 68 |
dnl |
| 69 |
dnl Please check that wx-config is in path, the directory |
| 70 |
dnl where wxWidgets libraries are installed (returned by |
| 71 |
dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or |
| 72 |
dnl equivalent variable and wxWidgets version is 2.3.4 or above. |
| 73 |
dnl ]) |
| 74 |
dnl fi |
| 75 |
dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS" |
| 76 |
dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY" |
| 77 |
dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY" |
| 78 |
dnl |
| 79 |
dnl LIBS="$LIBS $WX_LIBS" |
| 80 |
dnl |
| 81 |
dnl If you want to support standard --enable-debug/unicode/shared options, you |
| 82 |
dnl may do the following: |
| 83 |
dnl |
| 84 |
dnl ... |
| 85 |
dnl AC_CANONICAL_SYSTEM |
| 86 |
dnl |
| 87 |
dnl # define configure options |
| 88 |
dnl WX_CONFIG_OPTIONS |
| 89 |
dnl WX_STANDARD_OPTIONS([debug,unicode,shared,toolkit,wxshared]) |
| 90 |
dnl |
| 91 |
dnl # basic configure checks |
| 92 |
dnl ... |
| 93 |
dnl |
| 94 |
dnl # we want to always have DEBUG==WX_DEBUG and UNICODE==WX_UNICODE |
| 95 |
dnl WX_DEBUG=$DEBUG |
| 96 |
dnl WX_UNICODE=$UNICODE |
| 97 |
dnl |
| 98 |
dnl WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS |
| 99 |
dnl WX_CONFIG_CHECK([2.8.0], [wxWin=1],,[html,core,net,base],[$WXCONFIG_FLAGS]) |
| 100 |
dnl WX_DETECT_STANDARD_OPTION_VALUES |
| 101 |
dnl |
| 102 |
dnl # write the output files |
| 103 |
dnl AC_CONFIG_FILES([Makefile ...]) |
| 104 |
dnl AC_OUTPUT |
| 105 |
dnl |
| 106 |
dnl # optional: just to show a message to the user |
| 107 |
dnl WX_STANDARD_OPTIONS_SUMMARY_MSG |
| 108 |
dnl |
| 109 |
dnl --------------------------------------------------------------------------- |
| 110 |
|
| 111 |
|
| 112 |
dnl --------------------------------------------------------------------------- |
| 113 |
dnl WX_CONFIG_OPTIONS |
| 114 |
dnl |
| 115 |
dnl adds support for --wx-prefix, --wx-exec-prefix, --with-wxdir and |
| 116 |
dnl --wx-config command line options |
| 117 |
dnl --------------------------------------------------------------------------- |
| 118 |
|
| 119 |
AC_DEFUN([WX_CONFIG_OPTIONS], |
| 120 |
[ |
| 121 |
AC_ARG_WITH(wxdir, |
| 122 |
[ --with-wxdir=PATH Use uninstalled version of wxWidgets in PATH], |
| 123 |
[ wx_config_name="$withval/wx-config" |
| 124 |
wx_config_args="--inplace"]) |
| 125 |
AC_ARG_WITH(wx-config, |
| 126 |
[ --with-wx-config=CONFIG wx-config script to use (optional)], |
| 127 |
wx_config_name="$withval" ) |
| 128 |
AC_ARG_WITH(wx-prefix, |
| 129 |
[ --with-wx-prefix=PREFIX Prefix where wxWidgets is installed (optional)], |
| 130 |
wx_config_prefix="$withval", wx_config_prefix="") |
| 131 |
AC_ARG_WITH(wx-exec-prefix, |
| 132 |
[ --with-wx-exec-prefix=PREFIX |
| 133 |
Exec prefix where wxWidgets is installed (optional)], |
| 134 |
wx_config_exec_prefix="$withval", wx_config_exec_prefix="") |
| 135 |
]) |
| 136 |
|
| 137 |
dnl Helper macro for checking if wx version is at least $1.$2.$3, set's |
| 138 |
dnl wx_ver_ok=yes if it is: |
| 139 |
AC_DEFUN([_WX_PRIVATE_CHECK_VERSION], |
| 140 |
[ |
| 141 |
wx_ver_ok="" |
| 142 |
if test "x$WX_VERSION" != x ; then |
| 143 |
if test $wx_config_major_version -gt $1; then |
| 144 |
wx_ver_ok=yes |
| 145 |
else |
| 146 |
if test $wx_config_major_version -eq $1; then |
| 147 |
if test $wx_config_minor_version -gt $2; then |
| 148 |
wx_ver_ok=yes |
| 149 |
else |
| 150 |
if test $wx_config_minor_version -eq $2; then |
| 151 |
if test $wx_config_micro_version -ge $3; then |
| 152 |
wx_ver_ok=yes |
| 153 |
fi |
| 154 |
fi |
| 155 |
fi |
| 156 |
fi |
| 157 |
fi |
| 158 |
fi |
| 159 |
]) |
| 160 |
|
| 161 |
dnl --------------------------------------------------------------------------- |
| 162 |
dnl WX_CONFIG_CHECK(VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND |
| 163 |
dnl [, WX-LIBS [, ADDITIONAL-WX-CONFIG-FLAGS]]]]) |
| 164 |
dnl |
| 165 |
dnl Test for wxWidgets, and define WX_C*FLAGS, WX_LIBS and WX_LIBS_STATIC |
| 166 |
dnl (the latter is for static linking against wxWidgets). Set WX_CONFIG_NAME |
| 167 |
dnl environment variable to override the default name of the wx-config script |
| 168 |
dnl to use. Set WX_CONFIG_PATH to specify the full path to wx-config - in this |
| 169 |
dnl case the macro won't even waste time on tests for its existence. |
| 170 |
dnl |
| 171 |
dnl Optional WX-LIBS argument contains comma- or space-separated list of |
| 172 |
dnl wxWidgets libraries to link against. If it is not specified then WX_LIBS |
| 173 |
dnl and WX_LIBS_STATIC will contain flags to link with all of the core |
| 174 |
dnl wxWidgets libraries. |
| 175 |
dnl |
| 176 |
dnl Optional ADDITIONAL-WX-CONFIG-FLAGS argument is appended to wx-config |
| 177 |
dnl invocation command in present. It can be used to fine-tune lookup of |
| 178 |
dnl best wxWidgets build available. |
| 179 |
dnl |
| 180 |
dnl Example use: |
| 181 |
dnl WX_CONFIG_CHECK([2.6.0], [wxWin=1], [wxWin=0], [html,core,net] |
| 182 |
dnl [--unicode --debug]) |
| 183 |
dnl --------------------------------------------------------------------------- |
| 184 |
|
| 185 |
dnl |
| 186 |
dnl Get the cflags and libraries from the wx-config script |
| 187 |
dnl |
| 188 |
AC_DEFUN([WX_CONFIG_CHECK], |
| 189 |
[ |
| 190 |
dnl do we have wx-config name: it can be wx-config or wxd-config or ... |
| 191 |
if test x${WX_CONFIG_NAME+set} != xset ; then |
| 192 |
WX_CONFIG_NAME=wx-config |
| 193 |
fi |
| 194 |
|
| 195 |
if test "x$wx_config_name" != x ; then |
| 196 |
WX_CONFIG_NAME="$wx_config_name" |
| 197 |
fi |
| 198 |
|
| 199 |
dnl deal with optional prefixes |
| 200 |
if test x$wx_config_exec_prefix != x ; then |
| 201 |
wx_config_args="$wx_config_args --exec-prefix=$wx_config_exec_prefix" |
| 202 |
WX_LOOKUP_PATH="$wx_config_exec_prefix/bin" |
| 203 |
fi |
| 204 |
if test x$wx_config_prefix != x ; then |
| 205 |
wx_config_args="$wx_config_args --prefix=$wx_config_prefix" |
| 206 |
WX_LOOKUP_PATH="$WX_LOOKUP_PATH:$wx_config_prefix/bin" |
| 207 |
fi |
| 208 |
if test "$cross_compiling" = "yes"; then |
| 209 |
wx_config_args="$wx_config_args --host=$host_alias" |
| 210 |
fi |
| 211 |
|
| 212 |
dnl don't search the PATH if WX_CONFIG_NAME is absolute filename |
| 213 |
if test -x "$WX_CONFIG_NAME" ; then |
| 214 |
AC_MSG_CHECKING(for wx-config) |
| 215 |
WX_CONFIG_PATH="$WX_CONFIG_NAME" |
| 216 |
AC_MSG_RESULT($WX_CONFIG_PATH) |
| 217 |
else |
| 218 |
AC_PATH_PROG(WX_CONFIG_PATH, $WX_CONFIG_NAME, no, "$WX_LOOKUP_PATH:$PATH") |
| 219 |
fi |
| 220 |
|
| 221 |
if test "$WX_CONFIG_PATH" != "no" ; then |
| 222 |
WX_VERSION="" |
| 223 |
|
| 224 |
min_wx_version=ifelse([$1], ,2.2.1,$1) |
| 225 |
if test -z "$5" ; then |
| 226 |
AC_MSG_CHECKING([for wxWidgets version >= $min_wx_version]) |
| 227 |
else |
| 228 |
AC_MSG_CHECKING([for wxWidgets version >= $min_wx_version ($5)]) |
| 229 |
fi |
| 230 |
|
| 231 |
dnl don't add the libraries ($4) to this variable as this would result in |
| 232 |
dnl an error when it's used with --version below |
| 233 |
WX_CONFIG_WITH_ARGS="$WX_CONFIG_PATH $wx_config_args $5" |
| 234 |
|
| 235 |
WX_VERSION=`$WX_CONFIG_WITH_ARGS --version 2>/dev/null` |
| 236 |
wx_config_major_version=`echo $WX_VERSION | \ |
| 237 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'` |
| 238 |
wx_config_minor_version=`echo $WX_VERSION | \ |
| 239 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'` |
| 240 |
wx_config_micro_version=`echo $WX_VERSION | \ |
| 241 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'` |
| 242 |
|
| 243 |
wx_requested_major_version=`echo $min_wx_version | \ |
| 244 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'` |
| 245 |
wx_requested_minor_version=`echo $min_wx_version | \ |
| 246 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'` |
| 247 |
wx_requested_micro_version=`echo $min_wx_version | \ |
| 248 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'` |
| 249 |
|
| 250 |
_WX_PRIVATE_CHECK_VERSION([$wx_requested_major_version], |
| 251 |
[$wx_requested_minor_version], |
| 252 |
[$wx_requested_micro_version]) |
| 253 |
|
| 254 |
if test -n "$wx_ver_ok"; then |
| 255 |
AC_MSG_RESULT(yes (version $WX_VERSION)) |
| 256 |
WX_LIBS=`$WX_CONFIG_WITH_ARGS --libs $4` |
| 257 |
|
| 258 |
dnl is this even still appropriate? --static is a real option now |
| 259 |
dnl and WX_CONFIG_WITH_ARGS is likely to contain it if that is |
| 260 |
dnl what the user actually wants, making this redundant at best. |
| 261 |
dnl For now keep it in case anyone actually used it in the past. |
| 262 |
AC_MSG_CHECKING([for wxWidgets static library]) |
| 263 |
WX_LIBS_STATIC=`$WX_CONFIG_WITH_ARGS --static --libs $4 2>/dev/null` |
| 264 |
if test "x$WX_LIBS_STATIC" = "x"; then |
| 265 |
AC_MSG_RESULT(no) |
| 266 |
else |
| 267 |
AC_MSG_RESULT(yes) |
| 268 |
fi |
| 269 |
|
| 270 |
dnl starting with version 2.2.6 wx-config has --cppflags argument |
| 271 |
wx_has_cppflags="" |
| 272 |
if test $wx_config_major_version -gt 2; then |
| 273 |
wx_has_cppflags=yes |
| 274 |
else |
| 275 |
if test $wx_config_major_version -eq 2; then |
| 276 |
if test $wx_config_minor_version -gt 2; then |
| 277 |
wx_has_cppflags=yes |
| 278 |
else |
| 279 |
if test $wx_config_minor_version -eq 2; then |
| 280 |
if test $wx_config_micro_version -ge 6; then |
| 281 |
wx_has_cppflags=yes |
| 282 |
fi |
| 283 |
fi |
| 284 |
fi |
| 285 |
fi |
| 286 |
fi |
| 287 |
|
| 288 |
dnl starting with version 2.7.0 wx-config has --rescomp option |
| 289 |
wx_has_rescomp="" |
| 290 |
if test $wx_config_major_version -gt 2; then |
| 291 |
wx_has_rescomp=yes |
| 292 |
else |
| 293 |
if test $wx_config_major_version -eq 2; then |
| 294 |
if test $wx_config_minor_version -ge 7; then |
| 295 |
wx_has_rescomp=yes |
| 296 |
fi |
| 297 |
fi |
| 298 |
fi |
| 299 |
if test "x$wx_has_rescomp" = x ; then |
| 300 |
dnl cannot give any useful info for resource compiler |
| 301 |
WX_RESCOMP= |
| 302 |
else |
| 303 |
WX_RESCOMP=`$WX_CONFIG_WITH_ARGS --rescomp` |
| 304 |
fi |
| 305 |
|
| 306 |
if test "x$wx_has_cppflags" = x ; then |
| 307 |
dnl no choice but to define all flags like CFLAGS |
| 308 |
WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags $4` |
| 309 |
WX_CPPFLAGS=$WX_CFLAGS |
| 310 |
WX_CXXFLAGS=$WX_CFLAGS |
| 311 |
|
| 312 |
WX_CFLAGS_ONLY=$WX_CFLAGS |
| 313 |
WX_CXXFLAGS_ONLY=$WX_CFLAGS |
| 314 |
else |
| 315 |
dnl we have CPPFLAGS included in CFLAGS included in CXXFLAGS |
| 316 |
WX_CPPFLAGS=`$WX_CONFIG_WITH_ARGS --cppflags $4` |
| 317 |
WX_CXXFLAGS=`$WX_CONFIG_WITH_ARGS --cxxflags $4` |
| 318 |
WX_CFLAGS=`$WX_CONFIG_WITH_ARGS --cflags $4` |
| 319 |
|
| 320 |
WX_CFLAGS_ONLY=`echo $WX_CFLAGS | sed "s@^$WX_CPPFLAGS *@@"` |
| 321 |
WX_CXXFLAGS_ONLY=`echo $WX_CXXFLAGS | sed "s@^$WX_CFLAGS *@@"` |
| 322 |
fi |
| 323 |
|
| 324 |
ifelse([$2], , :, [$2]) |
| 325 |
|
| 326 |
else |
| 327 |
|
| 328 |
if test "x$WX_VERSION" = x; then |
| 329 |
dnl no wx-config at all |
| 330 |
AC_MSG_RESULT(no) |
| 331 |
else |
| 332 |
AC_MSG_RESULT(no (version $WX_VERSION is not new enough)) |
| 333 |
fi |
| 334 |
|
| 335 |
WX_CFLAGS="" |
| 336 |
WX_CPPFLAGS="" |
| 337 |
WX_CXXFLAGS="" |
| 338 |
WX_LIBS="" |
| 339 |
WX_LIBS_STATIC="" |
| 340 |
WX_RESCOMP="" |
| 341 |
|
| 342 |
if test ! -z "$5"; then |
| 343 |
|
| 344 |
wx_error_message=" |
| 345 |
The configuration you asked for $PACKAGE_NAME requires a wxWidgets |
| 346 |
build with the following settings: |
| 347 |
$5 |
| 348 |
but such build is not available. |
| 349 |
|
| 350 |
To see the wxWidgets builds available on this system, please use |
| 351 |
'wx-config --list' command. To use the default build, returned by |
| 352 |
'wx-config --selected-config', use the options with their 'auto' |
| 353 |
default values." |
| 354 |
|
| 355 |
fi |
| 356 |
|
| 357 |
wx_error_message=" |
| 358 |
The requested wxWidgets build couldn't be found. |
| 359 |
$wx_error_message |
| 360 |
|
| 361 |
If you still get this error, then check that 'wx-config' is |
| 362 |
in path, the directory where wxWidgets libraries are installed |
| 363 |
(returned by 'wx-config --libs' command) is in LD_LIBRARY_PATH |
| 364 |
or equivalent variable and wxWidgets version is $1 or above." |
| 365 |
|
| 366 |
ifelse([$3], , AC_MSG_ERROR([$wx_error_message]), [$3]) |
| 367 |
|
| 368 |
fi |
| 369 |
else |
| 370 |
|
| 371 |
WX_CFLAGS="" |
| 372 |
WX_CPPFLAGS="" |
| 373 |
WX_CXXFLAGS="" |
| 374 |
WX_LIBS="" |
| 375 |
WX_LIBS_STATIC="" |
| 376 |
WX_RESCOMP="" |
| 377 |
|
| 378 |
ifelse([$3], , :, [$3]) |
| 379 |
|
| 380 |
fi |
| 381 |
|
| 382 |
AC_SUBST(WX_CPPFLAGS) |
| 383 |
AC_SUBST(WX_CFLAGS) |
| 384 |
AC_SUBST(WX_CXXFLAGS) |
| 385 |
AC_SUBST(WX_CFLAGS_ONLY) |
| 386 |
AC_SUBST(WX_CXXFLAGS_ONLY) |
| 387 |
AC_SUBST(WX_LIBS) |
| 388 |
AC_SUBST(WX_LIBS_STATIC) |
| 389 |
AC_SUBST(WX_VERSION) |
| 390 |
AC_SUBST(WX_RESCOMP) |
| 391 |
|
| 392 |
dnl need to export also WX_VERSION_MINOR and WX_VERSION_MAJOR symbols |
| 393 |
dnl to support wxpresets bakefiles (we export also WX_VERSION_MICRO for completeness): |
| 394 |
WX_VERSION_MAJOR="$wx_config_major_version" |
| 395 |
WX_VERSION_MINOR="$wx_config_minor_version" |
| 396 |
WX_VERSION_MICRO="$wx_config_micro_version" |
| 397 |
AC_SUBST(WX_VERSION_MAJOR) |
| 398 |
AC_SUBST(WX_VERSION_MINOR) |
| 399 |
AC_SUBST(WX_VERSION_MICRO) |
| 400 |
]) |
| 401 |
|
| 402 |
dnl --------------------------------------------------------------------------- |
| 403 |
dnl Get information on the wxrc program for making C++, Python and xrs |
| 404 |
dnl resource files. |
| 405 |
dnl |
| 406 |
dnl AC_ARG_ENABLE(...) |
| 407 |
dnl AC_ARG_WITH(...) |
| 408 |
dnl ... |
| 409 |
dnl WX_CONFIG_OPTIONS |
| 410 |
dnl ... |
| 411 |
dnl WX_CONFIG_CHECK(2.6.0, wxWin=1) |
| 412 |
dnl if test "$wxWin" != 1; then |
| 413 |
dnl AC_MSG_ERROR([ |
| 414 |
dnl wxWidgets must be installed on your system |
| 415 |
dnl but wx-config script couldn't be found. |
| 416 |
dnl |
| 417 |
dnl Please check that wx-config is in path, the directory |
| 418 |
dnl where wxWidgets libraries are installed (returned by |
| 419 |
dnl 'wx-config --libs' command) is in LD_LIBRARY_PATH or |
| 420 |
dnl equivalent variable and wxWidgets version is 2.6.0 or above. |
| 421 |
dnl ]) |
| 422 |
dnl fi |
| 423 |
dnl |
| 424 |
dnl WXRC_CHECK([HAVE_WXRC=1], [HAVE_WXRC=0]) |
| 425 |
dnl if test "x$HAVE_WXRC" != x1; then |
| 426 |
dnl AC_MSG_ERROR([ |
| 427 |
dnl The wxrc program was not installed or not found. |
| 428 |
dnl |
| 429 |
dnl Please check the wxWidgets installation. |
| 430 |
dnl ]) |
| 431 |
dnl fi |
| 432 |
dnl |
| 433 |
dnl CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS" |
| 434 |
dnl CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY" |
| 435 |
dnl CFLAGS="$CFLAGS $WX_CFLAGS_ONLY" |
| 436 |
dnl |
| 437 |
dnl LDFLAGS="$LDFLAGS $WX_LIBS" |
| 438 |
dnl --------------------------------------------------------------------------- |
| 439 |
|
| 440 |
dnl --------------------------------------------------------------------------- |
| 441 |
dnl WXRC_CHECK([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]) |
| 442 |
dnl |
| 443 |
dnl Test for wxWidgets' wxrc program for creating either C++, Python or XRS |
| 444 |
dnl resources. The variable WXRC will be set and substituted in the configure |
| 445 |
dnl script and Makefiles. |
| 446 |
dnl |
| 447 |
dnl Example use: |
| 448 |
dnl WXRC_CHECK([wxrc=1], [wxrc=0]) |
| 449 |
dnl --------------------------------------------------------------------------- |
| 450 |
|
| 451 |
dnl |
| 452 |
dnl wxrc program from the wx-config script |
| 453 |
dnl |
| 454 |
AC_DEFUN([WXRC_CHECK], |
| 455 |
[ |
| 456 |
AC_ARG_VAR([WXRC], [Path to wxWidget's wxrc resource compiler]) |
| 457 |
|
| 458 |
if test "x$WX_CONFIG_NAME" = x; then |
| 459 |
AC_MSG_ERROR([The wxrc tests must run after wxWidgets test.]) |
| 460 |
else |
| 461 |
|
| 462 |
AC_MSG_CHECKING([for wxrc]) |
| 463 |
|
| 464 |
if test "x$WXRC" = x ; then |
| 465 |
dnl wx-config --utility is a new addition to wxWidgets: |
| 466 |
_WX_PRIVATE_CHECK_VERSION(2,5,3) |
| 467 |
if test -n "$wx_ver_ok"; then |
| 468 |
WXRC=`$WX_CONFIG_WITH_ARGS --utility=wxrc` |
| 469 |
fi |
| 470 |
fi |
| 471 |
|
| 472 |
if test "x$WXRC" = x ; then |
| 473 |
AC_MSG_RESULT([not found]) |
| 474 |
ifelse([$2], , :, [$2]) |
| 475 |
else |
| 476 |
AC_MSG_RESULT([$WXRC]) |
| 477 |
ifelse([$1], , :, [$1]) |
| 478 |
fi |
| 479 |
|
| 480 |
AC_SUBST(WXRC) |
| 481 |
fi |
| 482 |
]) |
| 483 |
|
| 484 |
dnl --------------------------------------------------------------------------- |
| 485 |
dnl WX_LIKE_LIBNAME([output-var] [prefix], [name]) |
| 486 |
dnl |
| 487 |
dnl Sets the "output-var" variable to the name of a library named with same |
| 488 |
dnl wxWidgets rule. |
| 489 |
dnl E.g. for output-var=='lib', name=='test', prefix='mine', sets |
| 490 |
dnl the $lib variable to: |
| 491 |
dnl 'mine_gtk2ud_test-2.8' |
| 492 |
dnl if WX_PORT=gtk2, WX_UNICODE=1, WX_DEBUG=1 and WX_RELEASE=28 |
| 493 |
dnl --------------------------------------------------------------------------- |
| 494 |
AC_DEFUN([WX_LIKE_LIBNAME], |
| 495 |
[ |
| 496 |
wx_temp="$2""_""$WX_PORT" |
| 497 |
|
| 498 |
dnl add the [u][d] string |
| 499 |
if test "$WX_UNICODE" = "1"; then |
| 500 |
wx_temp="$wx_temp""u" |
| 501 |
fi |
| 502 |
if test "$WX_DEBUG" = "1"; then |
| 503 |
wx_temp="$wx_temp""d" |
| 504 |
fi |
| 505 |
|
| 506 |
dnl complete the name of the lib |
| 507 |
wx_temp="$wx_temp""_""$3""-$WX_VERSION_MAJOR.$WX_VERSION_MINOR" |
| 508 |
|
| 509 |
dnl save it in the user's variable |
| 510 |
$1=$wx_temp |
| 511 |
]) |
| 512 |
|
| 513 |
dnl --------------------------------------------------------------------------- |
| 514 |
dnl WX_ARG_ENABLE_YESNOAUTO/WX_ARG_WITH_YESNOAUTO |
| 515 |
dnl |
| 516 |
dnl Two little custom macros which define the ENABLE/WITH configure arguments. |
| 517 |
dnl Macro arguments: |
| 518 |
dnl $1 = the name of the --enable / --with feature |
| 519 |
dnl $2 = the name of the variable associated |
| 520 |
dnl $3 = the description of that feature |
| 521 |
dnl $4 = the default value for that feature |
| 522 |
dnl $5 = additional action to do in case option is given with "yes" value |
| 523 |
dnl --------------------------------------------------------------------------- |
| 524 |
AC_DEFUN([WX_ARG_ENABLE_YESNOAUTO], |
| 525 |
[AC_ARG_ENABLE($1, |
| 526 |
AC_HELP_STRING([--enable-$1], [$3 (default is $4)]), |
| 527 |
[], [enableval="$4"]) |
| 528 |
|
| 529 |
dnl Show a message to the user about this option |
| 530 |
AC_MSG_CHECKING([for the --enable-$1 option]) |
| 531 |
if test "$enableval" = "yes" ; then |
| 532 |
AC_MSG_RESULT([yes]) |
| 533 |
$2=1 |
| 534 |
$5 |
| 535 |
elif test "$enableval" = "no" ; then |
| 536 |
AC_MSG_RESULT([no]) |
| 537 |
$2=0 |
| 538 |
elif test "$enableval" = "auto" ; then |
| 539 |
AC_MSG_RESULT([will be automatically detected]) |
| 540 |
$2="auto" |
| 541 |
else |
| 542 |
AC_MSG_ERROR([ |
| 543 |
Unrecognized option value (allowed values: yes, no, auto) |
| 544 |
]) |
| 545 |
fi |
| 546 |
]) |
| 547 |
|
| 548 |
AC_DEFUN([WX_ARG_WITH_YESNOAUTO], |
| 549 |
[AC_ARG_WITH($1, |
| 550 |
AC_HELP_STRING([--with-$1], [$3 (default is $4)]), |
| 551 |
[], [withval="$4"]) |
| 552 |
|
| 553 |
dnl Show a message to the user about this option |
| 554 |
AC_MSG_CHECKING([for the --with-$1 option]) |
| 555 |
if test "$withval" = "yes" ; then |
| 556 |
AC_MSG_RESULT([yes]) |
| 557 |
$2=1 |
| 558 |
$5 |
| 559 |
dnl NB: by default we don't allow --with-$1=no option |
| 560 |
dnl since it does not make much sense ! |
| 561 |
elif test "$6" = "1" -a "$withval" = "no" ; then |
| 562 |
AC_MSG_RESULT([no]) |
| 563 |
$2=0 |
| 564 |
elif test "$withval" = "auto" ; then |
| 565 |
AC_MSG_RESULT([will be automatically detected]) |
| 566 |
$2="auto" |
| 567 |
else |
| 568 |
AC_MSG_ERROR([ |
| 569 |
Unrecognized option value (allowed values: yes, auto) |
| 570 |
]) |
| 571 |
fi |
| 572 |
]) |
| 573 |
|
| 574 |
|
| 575 |
dnl --------------------------------------------------------------------------- |
| 576 |
dnl WX_STANDARD_OPTIONS([options-to-add]) |
| 577 |
dnl |
| 578 |
dnl Adds to the configure script one or more of the following options: |
| 579 |
dnl --enable-[debug|unicode|shared|wxshared|wxdebug] |
| 580 |
dnl --with-[gtk|msw|motif|x11|mac|dfb] |
| 581 |
dnl --with-wxversion |
| 582 |
dnl Then checks for their presence and eventually set the DEBUG, UNICODE, SHARED, |
| 583 |
dnl PORT, WX_SHARED, WX_DEBUG, variables to one of the "yes", "no", "auto" values. |
| 584 |
dnl |
| 585 |
dnl Note that e.g. UNICODE != WX_UNICODE; the first is the value of the |
| 586 |
dnl --enable-unicode option (in boolean format) while the second indicates |
| 587 |
dnl if wxWidgets was built in Unicode mode (and still is in boolean format). |
| 588 |
dnl --------------------------------------------------------------------------- |
| 589 |
AC_DEFUN([WX_STANDARD_OPTIONS], |
| 590 |
[ |
| 591 |
|
| 592 |
dnl the following lines will expand to WX_ARG_ENABLE_YESNOAUTO calls if and only if |
| 593 |
dnl the $1 argument contains respectively the debug,unicode or shared options. |
| 594 |
|
| 595 |
dnl be careful here not to set debug flag if only "wxdebug" was specified |
| 596 |
ifelse(regexp([$1], [\bdebug]), [-1],, |
| 597 |
[WX_ARG_ENABLE_YESNOAUTO([debug], [DEBUG], [Build in debug mode], [auto])]) |
| 598 |
|
| 599 |
ifelse(index([$1], [unicode]), [-1],, |
| 600 |
[WX_ARG_ENABLE_YESNOAUTO([unicode], [UNICODE], [Build in Unicode mode], [auto])]) |
| 601 |
|
| 602 |
ifelse(regexp([$1], [\bshared]), [-1],, |
| 603 |
[WX_ARG_ENABLE_YESNOAUTO([shared], [SHARED], [Build as shared library], [auto])]) |
| 604 |
|
| 605 |
dnl WX_ARG_WITH_YESNOAUTO cannot be used for --with-toolkit since it's an option |
| 606 |
dnl which must be able to accept the auto|gtk1|gtk2|msw|... values |
| 607 |
ifelse(index([$1], [toolkit]), [-1],, |
| 608 |
[ |
| 609 |
AC_ARG_WITH([toolkit], |
| 610 |
AC_HELP_STRING([--with-toolkit], |
| 611 |
[Build against a specific wxWidgets toolkit (default is auto)]), |
| 612 |
[], [withval="auto"]) |
| 613 |
|
| 614 |
dnl Show a message to the user about this option |
| 615 |
AC_MSG_CHECKING([for the --with-toolkit option]) |
| 616 |
if test "$withval" = "auto" ; then |
| 617 |
AC_MSG_RESULT([will be automatically detected]) |
| 618 |
TOOLKIT="auto" |
| 619 |
else |
| 620 |
TOOLKIT="$withval" |
| 621 |
|
| 622 |
dnl PORT must be one of the allowed values |
| 623 |
if test "$TOOLKIT" != "gtk1" -a "$TOOLKIT" != "gtk2" -a \ |
| 624 |
"$TOOLKIT" != "msw" -a "$TOOLKIT" != "motif" -a \ |
| 625 |
"$TOOLKIT" != "osx_carbon" -a "$TOOLKIT" != "osx_cocoa" -a \ |
| 626 |
"$TOOLKIT" != "dfb" -a "$TOOLKIT" != "x11"; then |
| 627 |
AC_MSG_ERROR([ |
| 628 |
Unrecognized option value (allowed values: auto, gtk1, gtk2, msw, motif, osx_carbon, osx_cocoa, dfb, x11) |
| 629 |
]) |
| 630 |
fi |
| 631 |
|
| 632 |
AC_MSG_RESULT([$TOOLKIT]) |
| 633 |
fi |
| 634 |
]) |
| 635 |
|
| 636 |
dnl ****** IMPORTANT ******* |
| 637 |
dnl Unlike for the UNICODE setting, you can build your program in |
| 638 |
dnl shared mode against a static build of wxWidgets. Thus we have the |
| 639 |
dnl following option which allows these mixtures. E.g. |
| 640 |
dnl |
| 641 |
dnl ./configure --disable-shared --with-wxshared |
| 642 |
dnl |
| 643 |
dnl will build your library in static mode against the first available |
| 644 |
dnl shared build of wxWidgets. |
| 645 |
dnl |
| 646 |
dnl Note that's not possible to do the viceversa: |
| 647 |
dnl |
| 648 |
dnl ./configure --enable-shared --without-wxshared |
| 649 |
dnl |
| 650 |
dnl Doing so you would try to build your library in shared mode against a static |
| 651 |
dnl build of wxWidgets. This is not possible (you would mix PIC and non PIC code) ! |
| 652 |
dnl A check for this combination of options is in WX_DETECT_STANDARD_OPTION_VALUES |
| 653 |
dnl (where we know what 'auto' should be expanded to). |
| 654 |
dnl |
| 655 |
dnl If you try to build something in ANSI mode against a UNICODE build |
| 656 |
dnl of wxWidgets or in RELEASE mode against a DEBUG build of wxWidgets, |
| 657 |
dnl then at best you'll get ton of linking errors ! |
| 658 |
dnl ************************ |
| 659 |
|
| 660 |
ifelse(index([$1], [wxshared]), [-1],, |
| 661 |
[ |
| 662 |
WX_ARG_WITH_YESNOAUTO( |
| 663 |
[wxshared], [WX_SHARED], |
| 664 |
[Force building against a shared build of wxWidgets, even if --disable-shared is given], |
| 665 |
[auto], [], [1]) |
| 666 |
]) |
| 667 |
|
| 668 |
dnl Just like for SHARED and WX_SHARED it may happen that some adventurous |
| 669 |
dnl peoples will want to mix a wxWidgets release build with a debug build of |
| 670 |
dnl his app/lib. So, we have both DEBUG and WX_DEBUG variables. |
| 671 |
ifelse(index([$1], [wxdebug]), [-1],, |
| 672 |
[ |
| 673 |
WX_ARG_WITH_YESNOAUTO( |
| 674 |
[wxdebug], [WX_DEBUG], |
| 675 |
[Force building against a debug build of wxWidgets, even if --disable-debug is given], |
| 676 |
[auto], [], [1]) |
| 677 |
]) |
| 678 |
|
| 679 |
dnl WX_ARG_WITH_YESNOAUTO cannot be used for --with-wxversion since it's an option |
| 680 |
dnl which accepts the "auto|2.6|2.7|2.8|2.9|3.0" etc etc values |
| 681 |
ifelse(index([$1], [wxversion]), [-1],, |
| 682 |
[ |
| 683 |
AC_ARG_WITH([wxversion], |
| 684 |
AC_HELP_STRING([--with-wxversion], |
| 685 |
[Build against a specific version of wxWidgets (default is auto)]), |
| 686 |
[], [withval="auto"]) |
| 687 |
|
| 688 |
dnl Show a message to the user about this option |
| 689 |
AC_MSG_CHECKING([for the --with-wxversion option]) |
| 690 |
if test "$withval" = "auto" ; then |
| 691 |
AC_MSG_RESULT([will be automatically detected]) |
| 692 |
WX_RELEASE="auto" |
| 693 |
else |
| 694 |
|
| 695 |
wx_requested_major_version=`echo $withval | \ |
| 696 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).*/\1/'` |
| 697 |
wx_requested_minor_version=`echo $withval | \ |
| 698 |
sed 's/\([[0-9]]*\).\([[0-9]]*\).*/\2/'` |
| 699 |
|
| 700 |
dnl both vars above must be exactly 1 digit |
| 701 |
if test "${#wx_requested_major_version}" != "1" -o \ |
| 702 |
"${#wx_requested_minor_version}" != "1" ; then |
| 703 |
AC_MSG_ERROR([ |
| 704 |
Unrecognized option value (allowed values: auto, 2.6, 2.7, 2.8, 2.9, 3.0) |
| 705 |
]) |
| 706 |
fi |
| 707 |
|
| 708 |
WX_RELEASE="$wx_requested_major_version"".""$wx_requested_minor_version" |
| 709 |
AC_MSG_RESULT([$WX_RELEASE]) |
| 710 |
fi |
| 711 |
]) |
| 712 |
|
| 713 |
if test "$WX_DEBUG_CONFIGURE" = "1"; then |
| 714 |
echo "[[dbg]] DEBUG: $DEBUG, WX_DEBUG: $WX_DEBUG" |
| 715 |
echo "[[dbg]] UNICODE: $UNICODE, WX_UNICODE: $WX_UNICODE" |
| 716 |
echo "[[dbg]] SHARED: $SHARED, WX_SHARED: $WX_SHARED" |
| 717 |
echo "[[dbg]] TOOLKIT: $TOOLKIT, WX_TOOLKIT: $WX_TOOLKIT" |
| 718 |
echo "[[dbg]] VERSION: $VERSION, WX_RELEASE: $WX_RELEASE" |
| 719 |
fi |
| 720 |
]) |
| 721 |
|
| 722 |
|
| 723 |
dnl --------------------------------------------------------------------------- |
| 724 |
dnl WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS |
| 725 |
dnl |
| 726 |
dnl Sets the WXCONFIG_FLAGS string using the SHARED,DEBUG,UNICODE variable values |
| 727 |
dnl which are different from "auto". |
| 728 |
dnl Thus this macro needs to be called only once all options have been set. |
| 729 |
dnl --------------------------------------------------------------------------- |
| 730 |
AC_DEFUN([WX_CONVERT_STANDARD_OPTIONS_TO_WXCONFIG_FLAGS], |
| 731 |
[ |
| 732 |
if test "$WX_SHARED" = "1" ; then |
| 733 |
WXCONFIG_FLAGS="--static=no " |
| 734 |
elif test "$WX_SHARED" = "0" ; then |
| 735 |
WXCONFIG_FLAGS="--static=yes " |
| 736 |
fi |
| 737 |
|
| 738 |
if test "$WX_DEBUG" = "1" ; then |
| 739 |
WXCONFIG_FLAGS="$WXCONFIG_FLAGS""--debug=yes " |
| 740 |
elif test "$WX_DEBUG" = "0" ; then |
| 741 |
WXCONFIG_FLAGS="$WXCONFIG_FLAGS""--debug=no " |
| 742 |
fi |
| 743 |
|
| 744 |
dnl The user should have set WX_UNICODE=UNICODE |
| 745 |
if test "$WX_UNICODE" = "1" ; then |
| 746 |
WXCONFIG_FLAGS="$WXCONFIG_FLAGS""--unicode=yes " |
| 747 |
elif test "$WX_UNICODE" = "0" ; then |
| 748 |
WXCONFIG_FLAGS="$WXCONFIG_FLAGS""--unicode=no " |
| 749 |
fi |
| 750 |
|
| 751 |
if test "$TOOLKIT" != "auto" ; then |
| 752 |
WXCONFIG_FLAGS="$WXCONFIG_FLAGS""--toolkit=$TOOLKIT " |
| 753 |
fi |
| 754 |
|
| 755 |
if test "$WX_RELEASE" != "auto" ; then |
| 756 |
WXCONFIG_FLAGS="$WXCONFIG_FLAGS""--version=$WX_RELEASE " |
| 757 |
fi |
| 758 |
|
| 759 |
dnl strip out the last space of the string |
| 760 |
WXCONFIG_FLAGS=${WXCONFIG_FLAGS% } |
| 761 |
|
| 762 |
if test "$WX_DEBUG_CONFIGURE" = "1"; then |
| 763 |
echo "[[dbg]] WXCONFIG_FLAGS: $WXCONFIG_FLAGS" |
| 764 |
fi |
| 765 |
]) |
| 766 |
|
| 767 |
|
| 768 |
dnl --------------------------------------------------------------------------- |
| 769 |
dnl _WX_SELECTEDCONFIG_CHECKFOR([RESULTVAR], [STRING], [MSG] |
| 770 |
dnl [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]) |
| 771 |
dnl |
| 772 |
dnl Outputs the given MSG. Then searches the given STRING in the wxWidgets |
| 773 |
dnl additional CPP flags and put the result of the search in WX_$RESULTVAR |
| 774 |
dnl also adding the "yes" or "no" message result to MSG. |
| 775 |
dnl --------------------------------------------------------------------------- |
| 776 |
AC_DEFUN([_WX_SELECTEDCONFIG_CHECKFOR], |
| 777 |
[ |
| 778 |
if test "$$1" = "auto" ; then |
| 779 |
|
| 780 |
dnl The user does not have particular preferences for this option; |
| 781 |
dnl so we will detect the wxWidgets relative build setting and use it |
| 782 |
AC_MSG_CHECKING([$3]) |
| 783 |
|
| 784 |
dnl set WX_$1 variable to 1 if the $WX_SELECTEDCONFIG contains the $2 |
| 785 |
dnl string or to 0 otherwise. |
| 786 |
dnl NOTE: 'expr match STRING REGEXP' cannot be used since on Mac it |
| 787 |
dnl doesn't work; we use 'expr STRING : REGEXP' instead |
| 788 |
WX_$1=$(expr "$WX_SELECTEDCONFIG" : ".*$2.*") |
| 789 |
|
| 790 |
if test "$WX_$1" != "0"; then |
| 791 |
WX_$1=1 |
| 792 |
AC_MSG_RESULT([yes]) |
| 793 |
ifelse([$4], , :, [$4]) |
| 794 |
else |
| 795 |
WX_$1=0 |
| 796 |
AC_MSG_RESULT([no]) |
| 797 |
ifelse([$5], , :, [$5]) |
| 798 |
fi |
| 799 |
else |
| 800 |
|
| 801 |
dnl Use the setting given by the user |
| 802 |
WX_$1=$$1 |
| 803 |
fi |
| 804 |
]) |
| 805 |
|
| 806 |
dnl --------------------------------------------------------------------------- |
| 807 |
dnl WX_DETECT_STANDARD_OPTION_VALUES |
| 808 |
dnl |
| 809 |
dnl Detects the values of the following variables: |
| 810 |
dnl 1) WX_RELEASE |
| 811 |
dnl 2) WX_UNICODE |
| 812 |
dnl 3) WX_DEBUG |
| 813 |
dnl 4) WX_SHARED (and also WX_STATIC) |
| 814 |
dnl 5) WX_PORT |
| 815 |
dnl from the previously selected wxWidgets build; this macro in fact must be |
| 816 |
dnl called *after* calling the WX_CONFIG_CHECK macro. |
| 817 |
dnl |
| 818 |
dnl Note that the WX_VERSION_MAJOR, WX_VERSION_MINOR symbols are already set |
| 819 |
dnl by WX_CONFIG_CHECK macro |
| 820 |
dnl --------------------------------------------------------------------------- |
| 821 |
AC_DEFUN([WX_DETECT_STANDARD_OPTION_VALUES], |
| 822 |
[ |
| 823 |
dnl IMPORTANT: WX_VERSION contains all three major.minor.micro digits, |
| 824 |
dnl while WX_RELEASE only the major.minor ones. |
| 825 |
WX_RELEASE="$WX_VERSION_MAJOR""$WX_VERSION_MINOR" |
| 826 |
if test $WX_RELEASE -lt 26 ; then |
| 827 |
|
| 828 |
AC_MSG_ERROR([ |
| 829 |
Cannot detect the wxWidgets configuration for the selected wxWidgets build |
| 830 |
since its version is $WX_VERSION < 2.6.0; please install a newer |
| 831 |
version of wxWidgets. |
| 832 |
]) |
| 833 |
fi |
| 834 |
|
| 835 |
dnl The wx-config we are using understands the "--selected_config" |
| 836 |
dnl option which returns an easy-parseable string ! |
| 837 |
WX_SELECTEDCONFIG=$($WX_CONFIG_WITH_ARGS --selected_config) |
| 838 |
|
| 839 |
if test "$WX_DEBUG_CONFIGURE" = "1"; then |
| 840 |
echo "[[dbg]] Using wx-config --selected-config" |
| 841 |
echo "[[dbg]] WX_SELECTEDCONFIG: $WX_SELECTEDCONFIG" |
| 842 |
fi |
| 843 |
|
| 844 |
|
| 845 |
dnl we could test directly for WX_SHARED with a line like: |
| 846 |
dnl _WX_SELECTEDCONFIG_CHECKFOR([SHARED], [shared], |
| 847 |
dnl [if wxWidgets was built in SHARED mode]) |
| 848 |
dnl but wx-config --selected-config DOES NOT outputs the 'shared' |
| 849 |
dnl word when wx was built in shared mode; it rather outputs the |
| 850 |
dnl 'static' word when built in static mode. |
| 851 |
if test $WX_SHARED = "1"; then |
| 852 |
STATIC=0 |
| 853 |
elif test $WX_SHARED = "0"; then |
| 854 |
STATIC=1 |
| 855 |
elif test $WX_SHARED = "auto"; then |
| 856 |
STATIC="auto" |
| 857 |
fi |
| 858 |
|
| 859 |
dnl Now set the WX_UNICODE, WX_DEBUG, WX_STATIC variables |
| 860 |
_WX_SELECTEDCONFIG_CHECKFOR([UNICODE], [unicode], |
| 861 |
[if wxWidgets was built with UNICODE enabled]) |
| 862 |
_WX_SELECTEDCONFIG_CHECKFOR([DEBUG], [debug], |
| 863 |
[if wxWidgets was built in DEBUG mode]) |
| 864 |
_WX_SELECTEDCONFIG_CHECKFOR([STATIC], [static], |
| 865 |
[if wxWidgets was built in STATIC mode]) |
| 866 |
|
| 867 |
dnl init WX_SHARED from WX_STATIC |
| 868 |
if test "$WX_STATIC" != "0"; then |
| 869 |
WX_SHARED=0 |
| 870 |
else |
| 871 |
WX_SHARED=1 |
| 872 |
fi |
| 873 |
|
| 874 |
AC_SUBST(WX_UNICODE) |
| 875 |
AC_SUBST(WX_DEBUG) |
| 876 |
AC_SUBST(WX_SHARED) |
| 877 |
|
| 878 |
dnl detect the WX_PORT to use |
| 879 |
if test "$TOOLKIT" = "auto" ; then |
| 880 |
|
| 881 |
dnl The user does not have particular preferences for this option; |
| 882 |
dnl so we will detect the wxWidgets relative build setting and use it |
| 883 |
AC_MSG_CHECKING([which wxWidgets toolkit was selected]) |
| 884 |
|
| 885 |
WX_GTKPORT1=$(expr "$WX_SELECTEDCONFIG" : ".*gtk1.*") |
| 886 |
WX_GTKPORT2=$(expr "$WX_SELECTEDCONFIG" : ".*gtk2.*") |
| 887 |
WX_MSWPORT=$(expr "$WX_SELECTEDCONFIG" : ".*msw.*") |
| 888 |
WX_MOTIFPORT=$(expr "$WX_SELECTEDCONFIG" : ".*motif.*") |
| 889 |
WX_OSXCOCOAPORT=$(expr "$WX_SELECTEDCONFIG" : ".*osx_cocoa.*") |
| 890 |
WX_OSXCARBONPORT=$(expr "$WX_SELECTEDCONFIG" : ".*osx_carbon.*") |
| 891 |
WX_X11PORT=$(expr "$WX_SELECTEDCONFIG" : ".*x11.*") |
| 892 |
WX_DFBPORT=$(expr "$WX_SELECTEDCONFIG" : ".*dfb.*") |
| 893 |
|
| 894 |
WX_PORT="unknown" |
| 895 |
if test "$WX_GTKPORT1" != "0"; then WX_PORT="gtk1"; fi |
| 896 |
if test "$WX_GTKPORT2" != "0"; then WX_PORT="gtk2"; fi |
| 897 |
if test "$WX_MSWPORT" != "0"; then WX_PORT="msw"; fi |
| 898 |
if test "$WX_MOTIFPORT" != "0"; then WX_PORT="motif"; fi |
| 899 |
if test "$WX_OSXCOCOAPORT" != "0"; then WX_PORT="osx_cocoa"; fi |
| 900 |
if test "$WX_OSXCARBONPORT" != "0"; then WX_PORT="osx_carbon"; fi |
| 901 |
if test "$WX_X11PORT" != "0"; then WX_PORT="x11"; fi |
| 902 |
if test "$WX_DFBPORT" != "0"; then WX_PORT="dfb"; fi |
| 903 |
|
| 904 |
dnl NOTE: backward-compatible check for wx2.8; in wx2.9 the mac |
| 905 |
dnl ports are called 'osx_cocoa' and 'osx_carbon' (see above) |
| 906 |
WX_MACPORT=$(expr "$WX_SELECTEDCONFIG" : ".*mac.*") |
| 907 |
if test "$WX_MACPORT" != "0"; then WX_PORT="mac"; fi |
| 908 |
|
| 909 |
dnl check at least one of the WX_*PORT has been set ! |
| 910 |
|
| 911 |
if test "$WX_PORT" = "unknown" ; then |
| 912 |
AC_MSG_ERROR([ |
| 913 |
Cannot detect the currently installed wxWidgets port ! |
| 914 |
Please check your 'wx-config --cxxflags'... |
| 915 |
]) |
| 916 |
fi |
| 917 |
|
| 918 |
AC_MSG_RESULT([$WX_PORT]) |
| 919 |
else |
| 920 |
|
| 921 |
dnl Use the setting given by the user |
| 922 |
if test -z "$TOOLKIT" ; then |
| 923 |
WX_PORT=$TOOLKIT |
| 924 |
else |
| 925 |
dnl try with PORT |
| 926 |
WX_PORT=$PORT |
| 927 |
fi |
| 928 |
fi |
| 929 |
|
| 930 |
AC_SUBST(WX_PORT) |
| 931 |
|
| 932 |
if test "$WX_DEBUG_CONFIGURE" = "1"; then |
| 933 |
echo "[[dbg]] Values of all WX_* options after final detection:" |
| 934 |
echo "[[dbg]] WX_DEBUG: $WX_DEBUG" |
| 935 |
echo "[[dbg]] WX_UNICODE: $WX_UNICODE" |
| 936 |
echo "[[dbg]] WX_SHARED: $WX_SHARED" |
| 937 |
echo "[[dbg]] WX_RELEASE: $WX_RELEASE" |
| 938 |
echo "[[dbg]] WX_PORT: $WX_PORT" |
| 939 |
fi |
| 940 |
|
| 941 |
dnl Avoid problem described in the WX_STANDARD_OPTIONS which happens when |
| 942 |
dnl the user gives the options: |
| 943 |
dnl ./configure --enable-shared --without-wxshared |
| 944 |
dnl or just do |
| 945 |
dnl ./configure --enable-shared |
| 946 |
dnl but there is only a static build of wxWidgets available. |
| 947 |
if test "$WX_SHARED" = "0" -a "$SHARED" = "1"; then |
| 948 |
AC_MSG_ERROR([ |
| 949 |
Cannot build shared library against a static build of wxWidgets ! |
| 950 |
This error happens because the wxWidgets build which was selected |
| 951 |
has been detected as static while you asked to build $PACKAGE_NAME |
| 952 |
as shared library and this is not possible. |
| 953 |
Use the '--disable-shared' option to build $PACKAGE_NAME |
| 954 |
as static library or '--with-wxshared' to use wxWidgets as shared library. |
| 955 |
]) |
| 956 |
fi |
| 957 |
|
| 958 |
dnl now we can finally update the DEBUG,UNICODE,SHARED options |
| 959 |
dnl to their final values if they were set to 'auto' |
| 960 |
if test "$DEBUG" = "auto"; then |
| 961 |
DEBUG=$WX_DEBUG |
| 962 |
fi |
| 963 |
if test "$UNICODE" = "auto"; then |
| 964 |
UNICODE=$WX_UNICODE |
| 965 |
fi |
| 966 |
if test "$SHARED" = "auto"; then |
| 967 |
SHARED=$WX_SHARED |
| 968 |
fi |
| 969 |
if test "$TOOLKIT" = "auto"; then |
| 970 |
TOOLKIT=$WX_PORT |
| 971 |
fi |
| 972 |
|
| 973 |
dnl in case the user needs a BUILD=debug/release var... |
| 974 |
if test "$DEBUG" = "1"; then |
| 975 |
BUILD="debug" |
| 976 |
elif test "$DEBUG" = "0" -o "$DEBUG" = ""; then |
| 977 |
BUILD="release" |
| 978 |
fi |
| 979 |
|
| 980 |
dnl respect the DEBUG variable adding the optimize/debug flags |
| 981 |
dnl NOTE: the CXXFLAGS are merged together with the CPPFLAGS so we |
| 982 |
dnl don't need to set them, too |
| 983 |
if test "$DEBUG" = "1"; then |
| 984 |
CXXFLAGS="$CXXFLAGS -g -O0" |
| 985 |
CFLAGS="$CFLAGS -g -O0" |
| 986 |
else |
| 987 |
CXXFLAGS="$CXXFLAGS -O2" |
| 988 |
CFLAGS="$CFLAGS -O2" |
| 989 |
fi |
| 990 |
]) |
| 991 |
|
| 992 |
dnl --------------------------------------------------------------------------- |
| 993 |
dnl WX_BOOLOPT_SUMMARY([name of the boolean variable to show summary for], |
| 994 |
dnl [what to print when var is 1], |
| 995 |
dnl [what to print when var is 0]) |
| 996 |
dnl |
| 997 |
dnl Prints $2 when variable $1 == 1 and prints $3 when variable $1 == 0. |
| 998 |
dnl This macro mainly exists just to make configure.ac scripts more readable. |
| 999 |
dnl |
| 1000 |
dnl NOTE: you need to use the [" my message"] syntax for 2nd and 3rd arguments |
| 1001 |
dnl if you want that m4 avoid to throw away the spaces prefixed to the |
| 1002 |
dnl argument value. |
| 1003 |
dnl --------------------------------------------------------------------------- |
| 1004 |
AC_DEFUN([WX_BOOLOPT_SUMMARY], |
| 1005 |
[ |
| 1006 |
if test "x$$1" = "x1" ; then |
| 1007 |
echo $2 |
| 1008 |
elif test "x$$1" = "x0" ; then |
| 1009 |
echo $3 |
| 1010 |
else |
| 1011 |
echo "$1 is $$1" |
| 1012 |
fi |
| 1013 |
]) |
| 1014 |
|
| 1015 |
dnl --------------------------------------------------------------------------- |
| 1016 |
dnl WX_STANDARD_OPTIONS_SUMMARY_MSG |
| 1017 |
dnl |
| 1018 |
dnl Shows a summary message to the user about the WX_* variable contents. |
| 1019 |
dnl This macro is used typically at the end of the configure script. |
| 1020 |
dnl --------------------------------------------------------------------------- |
| 1021 |
AC_DEFUN([WX_STANDARD_OPTIONS_SUMMARY_MSG], |
| 1022 |
[ |
| 1023 |
echo |
| 1024 |
echo " The wxWidgets build which will be used by $PACKAGE_NAME $PACKAGE_VERSION" |
| 1025 |
echo " has the following settings:" |
| 1026 |
WX_BOOLOPT_SUMMARY([WX_DEBUG], [" - DEBUG build"], [" - RELEASE build"]) |
| 1027 |
WX_BOOLOPT_SUMMARY([WX_UNICODE], [" - UNICODE mode"], [" - ANSI mode"]) |
| 1028 |
WX_BOOLOPT_SUMMARY([WX_SHARED], [" - SHARED mode"], [" - STATIC mode"]) |
| 1029 |
echo " - VERSION: $WX_VERSION" |
| 1030 |
echo " - PORT: $WX_PORT" |
| 1031 |
]) |
| 1032 |
|
| 1033 |
|
| 1034 |
dnl --------------------------------------------------------------------------- |
| 1035 |
dnl WX_STANDARD_OPTIONS_SUMMARY_MSG_BEGIN, WX_STANDARD_OPTIONS_SUMMARY_MSG_END |
| 1036 |
dnl |
| 1037 |
dnl Like WX_STANDARD_OPTIONS_SUMMARY_MSG macro but these two macros also gives info |
| 1038 |
dnl about the configuration of the package which used the wxpresets. |
| 1039 |
dnl |
| 1040 |
dnl Typical usage: |
| 1041 |
dnl WX_STANDARD_OPTIONS_SUMMARY_MSG_BEGIN |
| 1042 |
dnl echo " - Package setting 1: $SETTING1" |
| 1043 |
dnl echo " - Package setting 2: $SETTING1" |
| 1044 |
dnl ... |
| 1045 |
dnl WX_STANDARD_OPTIONS_SUMMARY_MSG_END |
| 1046 |
dnl |
| 1047 |
dnl --------------------------------------------------------------------------- |
| 1048 |
AC_DEFUN([WX_STANDARD_OPTIONS_SUMMARY_MSG_BEGIN], |
| 1049 |
[ |
| 1050 |
echo |
| 1051 |
echo " ----------------------------------------------------------------" |
| 1052 |
echo " Configuration for $PACKAGE_NAME $PACKAGE_VERSION successfully completed." |
| 1053 |
echo " Summary of main configuration settings for $PACKAGE_NAME:" |
| 1054 |
WX_BOOLOPT_SUMMARY([DEBUG], [" - DEBUG build"], [" - RELEASE build"]) |
| 1055 |
WX_BOOLOPT_SUMMARY([UNICODE], [" - UNICODE mode"], [" - ANSI mode"]) |
| 1056 |
WX_BOOLOPT_SUMMARY([SHARED], [" - SHARED mode"], [" - STATIC mode"]) |
| 1057 |
]) |
| 1058 |
|
| 1059 |
AC_DEFUN([WX_STANDARD_OPTIONS_SUMMARY_MSG_END], |
| 1060 |
[ |
| 1061 |
WX_STANDARD_OPTIONS_SUMMARY_MSG |
| 1062 |
echo |
| 1063 |
echo " Now, just run make." |
| 1064 |
echo " ----------------------------------------------------------------" |
| 1065 |
echo |
| 1066 |
]) |
| 1067 |
|
| 1068 |
|
| 1069 |
dnl --------------------------------------------------------------------------- |
| 1070 |
dnl Deprecated macro wrappers |
| 1071 |
dnl --------------------------------------------------------------------------- |
| 1072 |
|
| 1073 |
AC_DEFUN([AM_OPTIONS_WXCONFIG], [WX_CONFIG_OPTIONS]) |
| 1074 |
AC_DEFUN([AM_PATH_WXCONFIG], [ |
| 1075 |
WX_CONFIG_CHECK([$1],[$2],[$3],[$4],[$5]) |
| 1076 |
]) |
| 1077 |
AC_DEFUN([AM_PATH_WXRC], [WXRC_CHECK([$1],[$2])]) |
Archives