[gentoo-commits] repo/gentoo:master commit in: net-misc/freerdp/

[Mike Gilbert]

commit:     bff155938a1fadec3f090e07b8c3134c10848dcf
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu May 21 00:34:28 2020 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Thu May 21 00:34:47 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bff15593

net-misc/freerdp: bump to 2.1.1

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 net-misc/freerdp/Manifest             |   1 +
 net-misc/freerdp/freerdp-2.1.1.ebuild | 119 ++++++++++++++++++++++++++++++++++
 2 files changed, 120 insertions(+)

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index 7d7fe20fbc5..7b37ee1e36c 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1 +1,2 @@
 DIST freerdp-2.1.0.tar.gz 21772624 BLAKE2B d3491cb9f08a34fd5b2a5b00b46494e4e0524715d73ad46e92812578fbe9843504d937dc634f1597a7f0785494fd2c68f964125b438328105e4db41191eeb166 SHA512 c0abecf3d52bf8388538f0bb60a0852b6f92c9172feda06efa96eb49a354913c7a10b9852efb0de6e545658043d0d3568cb79a54fc1d324a14e8ed2c9c9e6e3b
+DIST freerdp-2.1.1.tar.gz 6828178 BLAKE2B 9ef3664095b1d154716d181c0c124391578685845b4976255970d2ccb65fc8b21b1701fabfcd0c58387300abcabfc2cf3147ce9d31b814c7b315663e7c053192 SHA512 e3e667f9a1f954ce914e7dcd24ba4d171fd147e812883ebcb67363dde4054e2d3cbe5fe4e7104fe52f84453c67e32281b5ee62889ba68850ba762196549855ba

diff --git a/net-misc/freerdp/freerdp-2.1.1.ebuild b/net-misc/freerdp/freerdp-2.1.1.ebuild
new file mode 100644
index 00000000000..3ab0cba9b80
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.1.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 2011-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	MY_P=${P/_/-}
+	S="${WORKDIR}/FreeRDP-${PV}"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer jpeg libressl openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	usb? (
+		virtual/libudev:0=
+		sys-apps/util-linux:0=
+		dev-libs/dbus-glib:0=
+		virtual/libusb:1=
+	)
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	openh264? ( media-libs/openh264 )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+	)
+	cmake_src_configure
+}